Nächstes Datum suchen und Wert anzeigen

[Blacky1980]

Hallo zusammen und einen guten Abend

Ich komme da schon zu meinem nächsten Problem.

In Spalte E1:E200 steht ein Datum und in A1:A200 der benötigte Wert (kann Zahl oder Text sein)


Nun möchte ich folgendes haben.

           A                    B                      C              D                       E
1      1732               -                       -               -                     17.12.2024
2      1733               -                       -               -                     17.11.2024
3      1734               -                       -               -                     17.11.2025
4      1735               -                       -               -                     17.10.2024

Nun soll in G1 = 1733 stehen und in H1 = 17.11.2024

Wie bekomme ich das nur hin.

Mit dieser Formel bekomme ich zumindest schonmal das nächste Datum raus.

Code:

=MIN(WENN($E$2:$E$25000>HEUTE();$E$2:$E$25000))

und mehr habe ich bis jetzt auch mit suchen nicht hin bekommen.

Gruß Michael

[BoskoBiati]

Hi,

Nun soll in G1 = 1733 stehen und in H1 = 17.11.2024

warum?

[Blacky1980]

Hallo Edgar

Am 17.11.2024 wäre der nächste Termin mit 1732 (Laufendenummer) so sehe ich wann der nächste Termin ist und wo.

Es werden noch mehr Daten über ein SVERWEIS durch die Lfd.Nr. gezogen.

Gruß Michael

[BoskoBiati]

Hi,

z.B. so:

Code:

=SPALTENWAHL(FILTER(A1:E4;E1:E4=MIN(WENN(E1:E4>HEUTE();E1:E4)));1;5)
=LET(xa;E1:E4;SPALTENWAHL(FILTER(A1:E4;xa=MIN(xa));1;5))

[shift-del]

Moin

Code:

=INDEX(SPALTENWAHL(SORTIEREN(FILTER(A1:E4;E1:E4>HEUTE());5;1);1;5);1)

[Blacky1980]

Hallo Edgar und Detlef

ersteinmal Danke euch beiden für die schnelle Antwort.


@Edgar
Der erste Code funktioniert und macht es so wie ich es mir vorgestellt habe. Der zweite Code leider nicht ganz
dass was ich mir vorgestellt haben dort wird mir leider das Datum des letzten vergangenen Termin angezeigt.


@Detlef
Dein Code macht auch dass wie ich es mir vorgestellt haben.


Vielen Dank euch beiden für die großartige Hilfe.

Schönen Abend noch und ein schönen und ruhigen Sonntag.



Gruß Michael

[BoskoBiati]

Hi,

stimmt, war falsch:

Code:

=LET(xa;E1:E4;SPALTENWAHL(FILTER(A1:E4;xa=MIN(WENN(xa>HEUTE();xa)));1;5))

[Blacky1980]

Nun habe ich doch ein kleines Problem gefunden auf das ich erst beim testen gekommen bin.

Wenn jetzt noch kein neuer Termin fest steht, machen beide codes von Edgar die spalten unterhalb des codes  alles voll mit 0

Beim Code von Detlef steht nur der Wert aus der 1 Zeile die als Überschrift dient. Also Nr.


@Edgar

Danke nun funktioniert dieser bis auf den Fehler oben.


Gruß Michael

[BoskoBiati]

Hi,

Code:

=WENN(SUMMEWENN(E1:E4;">="&HEUTE())=0;"";SPALTENWAHL(FILTER(A1:E4;(E1:E4=MIN(WENN(E1:E4>HEUTE();E1:E4))*(E1:E4<>0)));1;5))
=LET(xa;E1:E4;WENN(SUMMEWENN(xa;">"&HEUTE())>0;SPALTENWAHL(FILTER(A1:E4;xa=MIN(WENN(xa>HEUTE();xa)));1;5);""))

[Blacky1980]

Hallo Edgar

Danke für die hilfe soweit klappt es nun aber wenn bei der ersten Formel etwas gefunden wurde werden alle Zeilen darunter nun mit 0 gefült.
Wenn es keinen Termin gibt ist alles leer.


vielen Dank für Deine Mühe die Du da machst.

Gruß Michael