Nicht vorhandenen Wert aus Matrix unter Bedingung auslesen

[BoskoBiati]

Hallo,

wie wäre es mit einer simplen Formellösung:

Arbeitsblatt mit dem Namen 'Perzentilberechnung'
	A	B	C	D	E	F
1	Alter	BMI	Oberer BMI	Unterer BMI	Oberes Perzentil	Unteres Perzentil
2	1	14,3	15,53	14,81	25	10
3	0	12,8	11,75	10,99	25	10
4	2	16,4	15,05	14,33	25	10
5	1,5	14,8	15,32	14,59	25	10

Zelle	Formel
C2	=INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH(Perzentilberechnung!$A2;Referenztabelle!$A$3:$A$7;0);VERGLEICH(Perzentilberechnung!$B2;Referenztabelle!$D$2:$J$2;1)+1)
D2	=INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH(Perzentilberechnung!$A2;Referenztabelle!$A$3:$A$7;0);VERGLEICH(Perzentilberechnung!$B2;Referenztabelle!$D$2:$J$2;1))
E2	=INDEX(Referenztabelle!$D$2:$J$2;VERGLEICH($B2;Referenztabelle!$D$2:$J$2;1)+1)
F2	=INDEX(Referenztabelle!$D$2:$J$2;VERGLEICH($B2;Referenztabelle!$D$2:$J$2;1))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[atilla]

Hallo Edgar,


das sind meine Ergebnisse:

[
Bild bitte so als Datei hochladen: Klick mich!
]

Leider klappt das Einstellen von Ausschnitten bei mir im Moment nicht, deswegen ein Bild.

Formel in C2: =INDEX(Referenztabelle!$A$2:$J$7;VERGLEICH($A2;Referenztabelle!$A$2:$A$7;0);VERGLEICH($B2;INDEX(Referenztabelle!$A$2:$J$7;VERGLEICH($A2;Referenztabelle!$A$2:$A$7;0);0);1)+1)

In D2: =INDEX(Referenztabelle!$A$2:$J$7;VERGLEICH($A2;Referenztabelle!$A$2:$A$7;0);VERGLEICH($B2;INDEX(Referenztabelle!$A$2:$J$7;VERGLEICH($A2;Referenztabelle!$A$2:$A$7;0);0);1))

In E2: =INDEX(Referenztabelle!$A$2:$J$7;1;VERGLEICH($B2;INDEX(Referenztabelle!$A$2:$J$7;VERGLEICH($A2;Referenztabelle!$A$2:$A$7;0);0);1)+1)

in F2: =INDEX(Referenztabelle!$A$2:$J$7;1;VERGLEICH($B2;INDEX(Referenztabelle!$A$2:$J$7;VERGLEICH($A2;Referenztabelle!$A$2:$A$7;0);0);1))

[BoskoBiati]

Hallo atilla,


wenn ich davon ausgehe, dass das Perzentil die Spaltenüberschrift zum BMI ist, dann sind Deine Ergebnisse falsch!

[atilla]

Hallo Edgar,

ich sage Dein Ergebnis ist falsch und gebe zwei virtuelle Biere aus, wenn ich falsch liege.

[BoskoBiati]

Hallo atilla,

Du hast recht.

Arbeitsblatt mit dem Namen 'Perzentilberechnung'
	A	B	C	D	E	F
1	Alter	BMI	Oberer BMI	Unterer BMI	Oberes Perzentil	Unteres Perzentil
2	1	14,3	14,81	14,14	10	3
3	0	12,8	13,4	12,58	75	50
4	2	16,4	16,93	15,93	75	50
5	1,5	14,8	15,32	14,59	25	10

Zelle	Formel
C2	=INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH($A2;Referenztabelle!$A$3:$A$7;0);VERGLEICH($B2;INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH($A2;Referenztabelle!$A$3:$A$7;0););1)+1)
D2	=INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH($A2;Referenztabelle!$A$3:$A$7;0);VERGLEICH($B2;INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH($A2;Referenztabelle!$A$3:$A$7;0););1))
E2	=INDEX(Referenztabelle!$D$2:$J$2;VERGLEICH($C2;INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH($A2;Referenztabelle!$A$3:$A$7;0););1))
F2	=INDEX(Referenztabelle!$D$2:$J$2;VERGLEICH($C2;INDEX(Referenztabelle!$D$3:$J$7;VERGLEICH($A2;Referenztabelle!$A$3:$A$7;0););1)-1)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Rabe]

Hi,

hier atillas Lösung mit Formeln für beliebig viele Kinder und die Makro-Lösung für einzelne Kinder in einer Datei:

  Perzentile.xlsb (Größe: 19,85 KB / Downloads: 6)

[Fenia]

Danke, ihr habt mir unglaublich geholfen. Keine 306 Werte per Hand berechnen... puh...