Nummer aus Zelle extrahieren

[Fab8888]

Guten Tage,

ich habe folgendes in der Zelle stehen:

Gemischte SKUs
10003734-1013
Menge 12 P1 - B1

Die Artikelnummer (10003734-1013) würde ich gerne extrahieren aus der Zelle?
Jemand eine Idee für eine Formal, danke! :)

Gruß

[ws-53]

Geht bestimmt auch kürzer, aber funktioniert:

Code:

=TEIL(A1;FINDEN(ZEICHEN(10);$A1)+1;FINDEN(ZEICHEN(10);$A1;FINDEN(ZEICHEN(10);$A1)+1)-FINDEN(ZEICHEN(10);$A1)-1)

In einem neueren Excel geht es mit LET kürzer:

Code:

=LET(
a;TEIL(A1;FINDEN(ZEICHEN(10);A1)+1;99);
b;TEIL(a;1;FINDEN(ZEICHEN(10);a)-1);
b)

[BoskoBiati]

Hi,

wenn die Artikelnummer immer gleich aufgebaut ist:

Code:

=TEIL(A1;SUCHEN("-";A1)-8;13))
=TEIL(A1;SUCHEN(ZEICHEN(10);A1)+1;13)

[ws-53]

wenn die Artikelnummer immer gleich aufgebaut ist:

Bei uns gab es über Jahrzehnte eine einheitliche Logik, bis diese dann durch Firmenaufkäufe ihre Gültigkeit verlor.

[Fab8888]

Leider ist de Artikelnummer nicht immer gleich aufgebaut.

[BoskoBiati]

Hallo,

Dann stelle mal ein paar unterschiedliche Beispiele vor.

[Gast 123]

Hallo

bei dieser Beispieldatei spielt die Länge deiner Artikel Nummer keine Rolle, sie muss nur immer an 2. Stelle stehen.
Statt nur die Artikel Nummer auswerten wäre es m.E. sinnvoller den ganzen String auf drei Spalten zu splitten.
Bitte einfach mal anschauen was ich mir dazu ausgedacht habe.

Leider eine alte Excel 2003 Datei. das Makro kannst du aber problemlos ins Original koieren.

mfg Gast 123

[BoskoBiati]

Hi,

bei den Formeln von ws-53 ist die Länge der Artikelnummern egal.

[RPP63]

In einem neueren Excel geht es mit LET kürzer …

Moin!
Da geht dann noch einiges ohne LET.

	A	B	C	D
1	Gemischte SKUs 10003734-1013 Menge 12 P1 - B1	10003734-1013	10003734-1013	10003734-1013
2		85	37	49

Zelle	Formel
B1	=LET( a;TEIL(A1;FINDEN(ZEICHEN(10);A1)+1;99); b;TEIL(a;1;FINDEN(ZEICHEN(10);a)-1); b)
C1	=INDEX(TEXTTEILEN(A1;;ZEICHEN(10));2)
D1	=TEXTVOR(TEXTNACH(A1;ZEICHEN(10));ZEICHEN(10);-1)
B2	=LÄNGE(FORMELTEXT(B1))

Gruß Ralf

[ws-53]

Die INDEX-Variante ist besonders schick.