Nur bestimmt Wochentage in Spalte A ausgeben (evtl. Feiertage markieren)

[Marcus0711]

Hallo zusammen, 

meine Freundin studiert Lehramt und benötigt für das Protokoll des Schuljahres in Excel 2003 eine Datumsliste in Spalte A. 
In drei Tabellen sollen die nachfolgenden Varianten ausgegeben werden: 
Montag und Donnerstag               Vorschlag: =MIN(A1+7-REST(A1+5;7);A1+7-REST(A1+2;7))
Montag, Dienstag, Donnerstag       Vorschlag: =MIN(A1+7-REST(A1+5;7);A1+7-REST(A1+2;7);A1+7-REST(A1+4;7))
Mittwoch und Freitag                     Keine Ahnung
In A1 habe ich 07.09.2017 eingetragen
Beginn fürs Protokoll: 11.09. - Ende 28.02.2018

Durch stupides rumprobieren habe ich die Zahlen konfiguriert. Kann mir bitte jemand die Mittwoch / Freitag Variante erklären. Ich bekomme es nicht hin. Ich verstehe die Formeln einfach nicht. 
Zusatzfrage: Kann ich die Feiertage automatisch markieren?

Wäre wirklich toll wenn ihr uns helfen würdet.

Danke 

Marcus

[schauan]

Hallöchen,

die Wochentage haben in Excel die Zahlen 1 bis 7, die Tage sind fortlaufende Zahlen. Wenn Du nun eine Fortlaufende Zahl, z.B. 42357 durhc 7 Teilst, erhälst DU einen Rest und kannst damit den Wochentag ermitteln.

[Marcus0711]

Hallöchen,

die Wochentage haben in Excel die Zahlen 1 bis 7, die Tage sind fortlaufende Zahlen.  Wenn Du nun eine Fortlaufende Zahl, z.B. 42357 durhc 7 Teilst, erhälst DU einen Rest und kannst damit den Wochentag ermitteln.

Guten Abend Wie kann ich denn die fortlaufende Zahl ermitteln bzw auslesen?
Ich verstehe das nicht. Angenommen ich teile die 42357 / 7 = 6051 - wie kann ich so einen Wochentag ermitteln  :22:

Die Variante mit Mittwoch und Freitag bekomme ich einfach nicht. Ich verstehe den Aufbau der Formel nicht richtig.

[BoskoBiati]

Hi,

für Mittwoch/Freitag muß Dein Startdatum auch ein Freitag sein!

Hier mal ein Beispiel:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	07.09.17	07.09.17	08.09.17
2	11.09.17	11.09.17	13.09.17
3	14.09.17	12.09.17	15.09.17
4	18.09.17	14.09.17	20.09.17
5	21.09.17	18.09.17	22.09.17
6	25.09.17	19.09.17	27.09.17
7	28.09.17	21.09.17	29.09.17

Zelle	Formel
A2	=A1+(REST(A1;7)=5)*4+(REST(A1;7)=2)*3
B2	=B1+(REST(B1;7)=5)*4+(REST(B1;7)=2)+(REST(B1;7)=3)*2
C2	=C1+(REST(C1;7)=6)*5+(REST(C1;7)=4)*2

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[schauan]

Hallöchen,
Wenn Du die Zahl eines Datumsermitteln willst dann schreibe z.b. In A1 ein Datum, in B1 =A1 und formatiere B1 als Zahl. In C1 nimmst Du mal die Funktion WOCHENTAG und spielst mal mit dem Parameter.

[lupo1]

Lösung 1: für alle Excel-Versionen

__|____A___|____B___|____C___|________D_______|CODETab von lupo1
 1|    1,00|    3,00|    2,00|Wochentag1      |
 2|    2,00|    4,00|    5,00|Wochentag2      |
 3|    4,00|        |        |Wochentag3      |
 4|    3,00|    2,00|    2,00|Anzahl          |
 5|MoDiDo  |MoDo    |MiFr    |                |
 6|04.09.17|04.09.17|06.09.17|Starttag manuell|
 7|05.09.17|07.09.17|08.09.17|ab hier Formel  |
 8|07.09.17|11.09.17|13.09.17|                |
 9|11.09.17|14.09.17|15.09.17|                |
10|12.09.17|18.09.17|20.09.17|                |

Zellformeln:
A7: =A6+INDEX(A:A;REST(ZEILE(A1)-1;A$4)+1)

Erläuterung: In den Zeilen 1-3 ergibt sich jeweils pro Spalte die Summe 7 für eine Woche, egal, ob 1, 2, oder 3 Wochentage. In Zeile 4 wird die Anzahl Tage pro Woche ausgegeben. Über diese standardisierte Information "der Abstände der einzelnen beteiligten WT zueinander" kommt man dann mit einer einzelnen Formel aus, statt sich mit individuellen REST-Formeln die Beine auszureißen. Einzig das Startdatum musst Du in Zeile 6 korrekt bzw. "ins Schema passend" vorgeben. Dies habe ich mit Mo und Mi getan.

Hintergrundwissen: Der erste Tag in Excel ist "Samstag, die Null" (=31.12.1899). Die 6 (Fr) ist der 6.1.1900. Dann kommt wieder die 0. Denn am 7. Tag bleibt nach Teilen durch 7 wieder nur 0. Und so läuft das ewig weiter.

Kleine Warnung: Bitte niemals die ersten 61 Tage (=0-60) in Excel ernsthaft verwenden, da Microsoft hier aus Kompatibilitätsgründen einen Fehler von vorherigen TK (Lotus oder VisiCalc) übernommen hat: Es kennt nämlich einen nicht existierenden 29.2.1900! Somit war der 31.12.1899 in Wirklichkeit gar kein Sa Tag 0, sondern ein So Tag 1. - Für die Wochentagsermittlung jedoch reicht es. Ab Tag 61, dem Donnerstag 1.3.1900, stimmt dann alles, bis ca. zum 28.2.4793. Dann muss erstmals seit der Gregorianischen Reform, wirksam ab 15.10.1582, der Kalender um einen Tag korrigiert werden.

Lösung 2: für neuere Excels (ab 2007?):

__|____A___|____B___|____C___|____________D____________|CODETab von lupo1
 1|0010111 |0110111 |1101011 |ARBEITSTAG.INTL-Steuerung|
 2|MoDiDo  |MoDo    |MiFr    |                         |
 3|04.09.17|04.09.17|06.09.17|Starttag manuell         |
 4|05.09.17|07.09.17|08.09.17|ab hier Formel           |
 5|07.09.17|11.09.17|13.09.17|                         |
 6|11.09.17|14.09.17|15.09.17|                         |
 7|12.09.17|18.09.17|20.09.17|                         |

Zellformeln:
A4:=ARBEITSTAG.INTL(A3;1;A$1)

Vorteile dieser Formel:
1. Du kannst in Zeile 3 in allen drei Spalten schamlos So, 3.9.2017, als Starttag verwenden, ohne etwas zu ermitteln! Ich habe es nicht getan.
2. Lies Dir die Hilfe zu ARBEITSTAG.INTL durch. Dann hast Du auch die Feiertage mit drin (bzw. raus).

[Elex]

Hallo

Hier eine Variante für uns Einsteiger.

 

Code:

      A        B
1  07.09.2017    Do    in A1   Start Datum    
2  11.09.2017    Mo    =A1+4    Formel in A2
3  12.09.2017    Di    =A1+5    Formel in A3
4  14.09.2017    Do    =A1+7    Formel in A4

A2 bis A4 Markieren und dann runterkopieren.

[Marcus0711]

Ich danke euch allen. Vielen lieben Dank für die Erläuterungen. Ich bin begeistert  :18: