PLZ-Leerzeichen-ORT in zwei Spalten

[MichaelH]

Hallo Leute,

wie kann ich denn PLZ-Leerzeichen-ORT aus einer Zelle in zwei nebeneinander liegende Zellen trennen?

So das der Aufbau des Ortes erhalten bleibt und die führende Null bei den PLZ erhalten bleibt?

06502 Thale OT Stecklenberg
32545 Bad Oeynhausen
39291 Möser OT Lostau
24800 Elsdorf - Westermühlen
39291 Neu Külzau/Möser

Danke und Gruss

Michael

[steve1da]

Hola,

Code:

=LINKS(A1;5)

und

Code:

=TEIL(A1;FINDEN(" ";A1)+1;99)

Gruß,
steve1da

[RPP63]

Moin!
Da die PLZs immer fünfstellig sind, reicht LINKS() und TEIL()

Gruß Ralf

[LCohen]

Für Dynamiker (das klappt nicht mit XMLFILTERN - und es klappt auch nicht mit GOOGLE-SPLIT in einer Formel):

=GLÄTTEN(TEIL(WECHSELN(A1:A5;" ";WIEDERHOLEN(" ";99);1);{1.100};99))

Bitte das 4. WECHSELN-Argument (1) beachten!

(geht so dynamisch nur in XL 2021, XL 365 und XL Web - nicht in XL 2013 / XL 2017)

[snb]

@LC

Was ist 'nicht dynamisch' an

PHP-Code:

=left(A1;5)


Code:

= mid(A1;7;100)

[LCohen]

Sorry, Google; ... 

=arrayformula(split(SUBSTITUTE(A1:A5;" ";"#";1)&"";"#")) 

tut es auch (zumindest dynamisch, nur noch nicht 5stellig).

=arrayformula(split(SUBSTITUTE(SUBSTITUTE("@"&A1:A5;"@";" ");" ";"#";1);"#")) finde ich reichlich widerlich! Google flext gnadenlos Leading-Zeros wech.

snb: Nicht-Dynamisch ist alles das, was nicht in einer Formel das gewünschte Endprodukt ergibt. Hast Du schon XL365? Oder hast Du einen MS-Account für XLWeb?

[snb]

Oder bedeutet das etwas einfaches aufwändig darstellen ?

PHP-Code:

=CHOOSE(COLUMN()-1;LEFT(A1;5);MID(A1;7;100))


oder

PHP-Code:

=MID($A1;INDEX({1;7};COLUMN(A:B));INDEX({5;100};COLUMN(A:B)))


[LCohen]

Mit 

=CHOOSE(COLUMN()-1;LEFT(A1:A1;5);MID(A1:A5;7;100)) 

wäre es "quasi-dynamisch" (es ist keine Arrayformel, sondern ein Formelarray). Da abzuschließende Arrays jedoch "höchst-statisch" sind, wird die Formel erst ab XL2021 dynamisch.

Statt SPALTE()-1 würde ich {1.2} oder SEQUENZ(;2) verwenden, damit die Formel ortsunabhängig ist.

"Einfach oder aufwändig": Die SPLIT- oder GLÄWEXWDH-Formel ist nur einmal nötig, keine verschiedenen CHOOSE-Ausgänge. Es gibt schon viele, die die Logik dahinter begriffen haben. Außerdem verwendet sie nur einmal A1:A5.