Personalnummer nach Vor und Nachname eintragen

[dragonxxl]

Guten Morgen liebe Helfer,

gerne würde ich auf meinem Blatt Liste Personalnummern automatisch eintragen lassen.

Auf dem Blatt Personalnummern habe ich eine Tabelle mit der Personalnummer Name und Vorname. 
Wenn ich jetzt im Blatt Liste einen Namen und Vornamen  in die Liste eintrage soll die Personalnummer in der Spalte H neben dem Namen erscheinen. Auch wenn die Reihenfolge der Namen im Blatt Liste anders ist
als im Blatt Personalnummern.

Bin kein erfahrener Excel Nutzer.

Daher würde ich mich über Hilfe freuen.

Kann es sein das man das mit einem SVERWEIS machen kann ?

Ich hoffe alles gut beschrieben zu haben.

Meine Musterdatei habe ich dazu getan.



Grüße dragonxxl

[UweD]

Hallo

Sverweis() ??
nee, weil die Rückgabespalte Vor der Suchspalte steht.

Aber so...

	H	I	J	K
3	Personalnummer		Name	Vorname
4
5	50030886		Name XY 1	Vorname XY 1
6	50030939		Name XY 2	Vorname XY 2
7	50030808		Name XY 3	Vorname XY 3
8	50030361		Name XY 4	Vorname XY 4
9	50091503		Name XY 5	Vorname XY 5
10	50030462		Name XY 6	Vorname XY 6
11	50091218		Name XY 7	Vorname XY 7
12	50030466		Name XY 8	Vorname XY 8
13	50030842		Name XY 9	Vorname XY 9
14	50091631		Name XY 10	Vorname XY 10
15	unbekannt		Name XXXX	Vorname XY 11
16	50091469		Name XY 12	Vorname XY 12
17	50091455		Name XY 13	Vorname XY 13
18	50091652		Name XY 14	Vorname XY 14
19	50091662		Name XY 15	Vorname XY 15
20	50030560		Name XY 16	Vorname XY 16
21	50090691		Name XY 17	Vorname XY 17
22	50091611		Name XY 18	Vorname XY 18
23	50030894		Name XY 19	Vorname XY 19
24	50090942		Name XY 20	Vorname XY 20
25	50030561		Name XY 21	Vorname XY 21
26	50091130		Name XY 22	Vorname XY 22
27	50030216		Name XY 23	Vorname XY 23
28	50030537		Name XY 24	Vorname XY 24
29	50090939		Name XY 25	Vorname XY 25

Zelle	Formel
H5	=XVERWEIS(J5&K5;Personalnummern!B:B&Personalnummern!C:C;Personalnummern!A:A;"unbekannt";0)

LG UweD

[WillWissen]

Moin,

die Lösung ist gut; allerdings dürfen keine zwei MA mit den selben Vor- und Zunamen vorkommen. So selten ist es nicht - wir hatten vor einigen Jahren zwei Mayr, Andreas in einem 30-Mann-Betrieb.

[dragonxxl]

Moin,

danke für die Hilfe UweD,

Die Formel ist klasse.

Kann man das mit den Doppelten Namen abfangen ?

Kann ja sein das es mal vorkommt.

Gruß dragonxxl

[HKindler]

Hi,

Code:

=FILTER(Personalnummern!A:A;(Personalnummern!B:B=J5)+(Personalnummern!C:C=K5);"unbekannt")

würde dann einfach alle betreffenden Personalnummern ausspucken. Allerdings müssen die Zellen unterhalb der Formel leer sein. Ansonsten muss man mit MTRANS oder TEXTVERKETTEN arbeiten.

Aber wahrscheinlich wäre es am besten, einfach hinter dem Vornamen irgendwas wie (jun.) oder (sen.) oder einfach einen Zähler zu ergänzen.

[UweD]

So?

	H	I	J	K
3	Personalnummer		Name	Vorname
4
5	50030886		Name XY 1	Vorname XY 1
6	50030939		Name XY 2	Vorname XY 2
7	50030808		Name XY 3	Vorname XY 3
8	50030361		Name XY 4	Vorname XY 4
9	50091503		Name XY 5	Vorname XY 5
10	50030462		Name XY 6	Vorname XY 6
11	50091218		Name XY 7	Vorname XY 7
12	50030466		Name XY 8	Vorname XY 8
13	50030842		Name XY 9	Vorname XY 9
14	50091631		Name XY 10	Vorname XY 10
15	2 x		Name DO	Vorname DO
16	50091469		Name XY 12	Vorname XY 12
17	50091455		Name XY 13	Vorname XY 13
18	50091652		Name XY 14	Vorname XY 14
19	50091662		Name XY 15	Vorname XY 15
20	50030560		Name XY 16	Vorname XY 16
21	50090691		Name XY 17	Vorname XY 17
22	unbekannt		Name Nicht Da	Vorname XY 18
23	50030894		Name XY 19	Vorname XY 19
24	50090942		Name XY 20	Vorname XY 20
25	50030561		Name XY 21	Vorname XY 21
26	50091130		Name XY 22	Vorname XY 22
27	50030216		Name XY 23	Vorname XY 23
28	50030537		Name XY 24	Vorname XY 24
29	50090939		Name XY 25	Vorname XY 25

Zelle	Formel
H5	=WENN(SUMMENPRODUKT(((Personalnummern!B1:B1000&Personalnummern!C1:C1000=J5&K5)*1))>1;SUMMENPRODUKT(((Personalnummern!B1:B1000&Personalnummern!C1:C1000=J5&K5)*1))&" x";XVERWEIS(J5&K5;Personalnummern!B:B&Personalnummern!C:C;Personalnummern!A:A;"unbekannt";0))

Eine weitere Fehlermöglichkeit wäre:

	B	C
29	Micha	Elradi
30	Michael	Radi

Das wäre dann so zu lösen

	H
5	50030886

Zelle	Formel
H5	=WENN(SUMMENPRODUKT(((Personalnummern!B1:B1000&"|"&Personalnummern!C1:C1000=J5&"|"&K5)*1))>1;SUMMENPRODUKT(((Personalnummern!B1:B1000&"|"&Personalnummern!C1:C1000=J5&"|"&K5)*1))&" x";XVERWEIS(J5&"|"&K5;Personalnummern!B:B&"|"&Personalnummern!C:C;Personalnummern!A:A;"unbekannt";0))

LG UweD

[dragonxxl]

Hallo ,

ja das geht auch. Die Nummern kommen von HR dann sind die sicher nicht ganz auf der Höhe.

Wenn ich die Formel runter ziehe steht in der Formelzelle ohne Namen in den anderen Zellen 594x usw. , kann man das unterdrücken ?


Gruß dragonxxl

[schauan]

Hallöchen,

im Prinzip =WENN(J...<>"";lange formel;"")

Wo kommt denn das x her?

[UweD]

Hallo

@ schauan

&" x";XVERWEIS(J5&"|"&K5;Personalnummern!B:B&"

ist in der Formel so angegeben.

@ dragonxxl
Klar, der zählt dann auch die Leeren Zellen mehrfach


LG UweD