Postleitzahlen Bereich aufschlüsseln

[Kuwer]

Hallo Dietmar,

das kannst du evtl.über Text in Spalte lösen.

was soll das bringen?

Gruß Uwe

[DietmarD]

Hallo,
ich glaube das es Fabi in erster Linie darum geht die Postleitzahlen aus einer Spalte einzeln zu bekommen. Dann kann er sie immer noch untereinander kopieren und zu einer Spalte zusammen fassen.
Aber vieleicht Irre ich mich ja

[No3Fx]

So PQ ist nun druff :)

Kenne mich damit aber überhaupt nicht aus, kann man das knackig und kurz erklären, oder ist das höhere Kunst?

Gruß

Fabi

[shift-del]

Der Code könnte so aussehen.

Code:

let
    Source = Excel.CurrentWorkbook(){[Name="Tabelle1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Spalte1", type text}}),
    #"Split Column by Delimiter" = Table.SplitColumn(#"Changed Type", "Spalte1", Splitter.SplitTextByDelimiter(";", QuoteStyle.Csv), {"Beginn", "Ende", "Spalte1.3"}),
    #"Changed Type1" = Table.TransformColumnTypes(#"Split Column by Delimiter",{{"Beginn", Int64.Type}, {"Ende", Int64.Type}, {"Spalte1.3", type text}}),
    #"Removed Columns" = Table.RemoveColumns(#"Changed Type1",{"Spalte1.3"}),
    #"Added Custom" = Table.AddColumn(#"Removed Columns", "Einzelwerte", each List.Numbers([Beginn], [Ende])),
    #"Expanded {0}" = Table.ExpandListColumn(#"Added Custom", "Einzelwerte"),
    #"Removed Columns1" = Table.RemoveColumns(#"Expanded {0}",{"Beginn", "Ende"})
in
    #"Removed Columns1"

[No3Fx]

So,

habe das jetzt mal umgesetzt.

Passt soweit, aber er zählt leider durch, D.h wenn vorgabe ist 1-10 zählt er trotzdem 11 , 12 usw. auf

[Jockel]

Ja, so habe ich das auch, aber der TE wollte offenbar die Bereiche nebeneinander...

[No3Fx]

Nein untereinander ist völlig ok, aber wie man bei mir sehen kann (Siehe Beispielbild oben) zählt er einfach durch.

Sprich 6449 <<< sollte ende sein aber er zählt munter und fröhlich weiter ?

[shift-del]

Fehler behoben.

Code:

let
    Source = Excel.CurrentWorkbook(){[Name="Tabelle1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Spalte1", type text}}),
    #"Split Column by Delimiter" = Table.SplitColumn(#"Changed Type", "Spalte1", Splitter.SplitTextByDelimiter(";", QuoteStyle.Csv), {"Beginn", "Ende", "Spalte1.3"}),
    #"Changed Type1" = Table.TransformColumnTypes(#"Split Column by Delimiter",{{"Beginn", Int64.Type}, {"Ende", Int64.Type}, {"Spalte1.3", type text}}),
    #"Removed Columns" = Table.RemoveColumns(#"Changed Type1",{"Spalte1.3"}),
    #"Added Custom" = Table.AddColumn(#"Removed Columns", "Anzahl", each [Ende]-[Beginn]+1),
    #"Changed Type2" = Table.TransformColumnTypes(#"Added Custom",{{"Anzahl", Int64.Type}}),
    #"Added Custom1" = Table.AddColumn(#"Changed Type2", "Einzelwerte", each List.Numbers([Beginn],[Anzahl])),
    #"Expanded {0}" = Table.ExpandListColumn(#"Added Custom1", "Einzelwerte"),
    #"Removed Columns1" = Table.RemoveColumns(#"Expanded {0}",{"Beginn", "Ende", "Anzahl"})
in
    #"Removed Columns1"

[Jockel]

Hallo, bei mir nicht..: (aber da hatte ich wohl einen anderen m-code)

Code:

let
   Quelle = Excel.CurrentWorkbook(){[Name="Tabelle1"]}[Content],
   #"Geänderter Typ" = Table.TransformColumnTypes(Quelle,{{"Spalte1", type text}}),
   #"Der Text vor dem Trennzeichen wurde extrahiert." = Table.TransformColumns(#"Geänderter Typ", {{"Spalte1", each Text.BeforeDelimiter(_, ";D"), type text}}),
   #"Spalte nach Trennzeichen teilen" = Table.SplitColumn(#"Der Text vor dem Trennzeichen wurde extrahiert.", "Spalte1", Splitter.SplitTextByEachDelimiter({";"}, QuoteStyle.Csv, false), {"Spalte1.1", "Spalte1.2"}),
   #"Geänderter Typ1" = Table.TransformColumnTypes(#"Spalte nach Trennzeichen teilen",{{"Spalte1.1", Int64.Type}, {"Spalte1.2", Int64.Type}}),
   #"Hinzugefügte benutzerdefinierte Spalte" = Table.AddColumn(#"Geänderter Typ1", "Benutzerdefiniert", each {[Spalte1.1]..[Spalte1.2]}),
   #"Erweiterte Benutzerdefiniert" = Table.ExpandListColumn(#"Hinzugefügte benutzerdefinierte Spalte", "Benutzerdefiniert"),
   #"Entfernte Spalten" = Table.RemoveColumns(#"Erweiterte Benutzerdefiniert",{"Spalte1.1", "Spalte1.2"}),
   #"Umbenannte Spalten" = Table.RenameColumns(#"Entfernte Spalten",{{"Benutzerdefiniert", "PLZ"}})
in
   #"Umbenannte Spalten"

Arbeitsblatt mit dem Namen 'Tabelle1'
	H
1	PLZ
2	06440
3	06441
4	06442
5	06443
6	06444
7	06445
8	06446
9	06447
10	06448
11	06449
12	06458
13	06459
14	06460
15	06461
16	06462

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[No3Fx]

Ok habe das "Dilemma" jetzt mal als Gesamtkonzept in den Anhang gepackt, dann versteht man vlt. eher worum es geht ;)