Problem mit Zellenbezügen beim automatischen Ausfüllen von Formeln

[DaKarl]

Guten Tag, liebe Excel-Experten!
Ich beschäftige mich jetzt schon seit 2 Tagen mit einem Problem, das ich trotz intensiver Recherche noch nicht lösen konnte:

Ich habe eine fortlaufende Liste mit Textbausteinen, die in der Tabelle untereinander stehen (im Screenshot Spalte "D" mit Name1, Name2 usw. benannt)
In eine andere Excel Tabelle sollen diese Namen übernommen werden, aber immer mit einer freien Zeile dazwischen.
Habe das im Screenshot mal vereinfacht dargestellt in einer Tabelle, hier sollen also die Namen aus Spalte D in Spalte A übernommen werden, aber in Spalte A soll jede zweite Zeile frei bleiben.
Name1 soll also von D1 in A1 übernommen werden, Name2 von D2 in A3, Name3 von D3 in A5 usw.

Wenn ich das für die ersten 2 Namen so mache und dann mit dem automatischen Ausfüllen alles nach unten ziehe, erhalte ich folgendes Ergebnis (siehe Screenshot).
Er überspringt also hier jeden zweiten Namen und übernimmt z. B. in A5 den "Name5" aus D5, anstatt "Name3" aus D3.

Excel scheint also nicht zu verstehen, dass ich immer eine Freizeile dazwischen haben möchte. 
Aber ich kann mir nicht vorstellen, dass es wirklich keine Möglichkeit geben soll, das so zu lösen, wie ich es haben möchte. Mir scheint das doch eine Situation zu sein, die häufiger vorkommen müsste, sodass es dafür irgend eine einfache Lösung geben müsste? Leider hab ich bisher keine gefunden.

Wie gesagt, ich habe das im Screenshot mal sehr vereinfacht dargestellt. Tatsächlich ist die Situation wesentlich komplexer, es ist eine längere Formel in der Textbausteine aus mehreren Zellen verknüpft werden usw. Ein "einfacher" Trick, wie z. B. auch in der Ausgangsliste einfach Leerzeilen einzufügen, hilft also nicht.

Vielen Dank im Voraus für die Vorschläge!

[Klaus-Dieter]

Hallo,

da Excel mit leeren Zeilen in einer Liste nicht umgehen kann, gibt es da eher keine Standardfunktion, die so etwas unterstüzt.

[BoskoBiati]

Hi,

bei Excel365 geht das so:

Code:

=WECHSELN(TEXTTEILEN(TEXTVERKETTEN(";#;";1;A1:A4);;";";0);"#";"")

# ist das von mir gewählte Trennzeichen, Du solltest eins wählen, was definitiv nicht in Deinen Texten vorkommt.

[EA1950]

Hallo,

in Zelle A1 folgende Formel eingeben:
=LET(tb;D1:E22; tbn; ZUSPALTE(tb; 0;0); WENN(tbn=0;"";tbn))
Spalte E muss leer sein.

Vorausgesetzt wird ein Excel365.

[UweD]

Hallo

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Name 1			Name 1
2				Name 2
3	Name 2			Name 3
4				Name 4
5	Name 3			Name 5
6				Name 6
7	Name 4			Name 7
8				Name 8
9	Name 5			Name 9
10				Name 10
11	Name 6			Name 11
12				Name 12
13	Name 7			Name 13
14				Name 14
15	Name 8			Name 15
16				Name 16
17	Name 9			Name 17
18				Name 18
19	Name 10			Name 19
20				Name 20
21	Name 11			Name 21
22				Name 22

Zelle	Formel
A1	=WENN(ISTGERADE(ZEILE());"";INDEX(D:D;GANZZAHL(ZEILE()/2)+1))

LG UweD

[BoskoBiati]

Hi Anton,

  der Trick ist gut, funktioniert aber nur, wenn die Spalte E leer ist!

[EA1950]

Hallo Edgar,

ich habe eine 2. Version zur Verfügung, die ohne Leerspalte E auskommt:
=WENNFEHLER(ZUSPALTE(ERWEITERN(D1:D22;;2);0;0);"")

[RPP63]

Prima! 
Allerdings wundere ich mich immer, warum pad so beharrlich ignoriert wird …
Dann kann man sich das WENNFEHLER-Gedöns sparen:
=ZUSPALTE(ERWEITERN(D1:D22;;2;""))

Gruß Ralf