Probleme beim Runterziehen einer Formel

[dertommy]

Hallo!

Ich will mit der Funktion "Runterziehen", dass sich bestimmte Werte ändern. Hier einmal meine Formel:

Code:

=INDEX(Auszahlungen!$P$7:$P$10000;VERGLEICH(MAX(Auszahlungen!Q7:Q10000);Auszahlungen!Q7:Q10000;0)) & "  (€ " & TEXT(MAX(Auszahlungen!Q7:Q10000);"#.##0,00") & ")"

Nun will ich, dass P7:P1000 immer gleich bleibt, aber die Buchstaben Q in der restlichen Formel sollen immer um einen Wert erhöht werden, die Zahl aber nicht. Das heißt, in der darunterliegenden Spalte sollte die Formel wie folgt aussehen:

Code:

=INDEX(Auszahlungen!$P$7:$P$10000;VERGLEICH(MAX(Auszahlungen!R7:R10000);Auszahlungen!R7:R10000;0)) & "  (€ " & TEXT(MAX(Auszahlungen!R7:R10000);"#.##0,00") & ")"

Wenn ich die Formel nach rechts rüber ziehe, funktioniert es.
Ich hoffe, dass mir jemand helfen kann.

[LCohen]

Auszahlungen!Q7:Q10000

wird zu

INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A1))

und die anderen entsprechend.

[dertommy]

Hallo!

Es soll nicht zu Q:Z werden, sondern zu R:R und in der nächsten Zeile dann zu S:S

[LCohen]

Sei nicht so aufmüpfig und mach!

[dertommy]

habe ich, die Formel liefert einen Fehler
ich habe in der gesamten Formel deinen Teil der Formel mit meiner ersetzt, funktioniert aber nicht

[Jockel]

Hallo, toll da man ja sehen kann, was du wie gemacht hast, ist das doch ganz einfach...

[dertommy]

Ich habe es so gemacht, so wie es geschrieben wurde, hier die fehlerhafte Formel:

PHP-Code:

=INDEX(Auszahlungen!$P$7:$P$10000;VERGLEICH(MAX(INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A1)));INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A1));0)) & "  (€ " & TEXT(MAX(INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A1)));"#.##0,00") & ")" 


[Jockel]

Hallo, den Wink mit dem Zaunpfahl hast du offenbar nicht verstanden... (lade doch bitte (d)eine (Beispiel)Datei hoch - keine Bilder) Welche Fehlermeldung bekommst du denn? Bei mir geht das... Aber das kann an deiner Datei - Tabelle liegen.

Arbeitsblatt mit dem Namen 'Auszahlungen'
	P	Q	R
7	1	1
8	2	2	13
9	3	3
10	4		25
11	5
12	6	10

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle2'
	A
12
13
14	6  (€ 10,00)
15	4  (€ 25,00)
16
17

Zelle	Formel
A14	=INDEX(Auszahlungen!$P$7:$P$10000;VERGLEICH(MAX(INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A1)));INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A1));0);0) & "  (€ " & TEXT(MAX(INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A1)));"#.##0,00") & ")"
A15	=INDEX(Auszahlungen!$P$7:$P$10000;VERGLEICH(MAX(INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A2)));INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A2));0)) & "  (€ " & TEXT(MAX(INDEX(Auszahlungen!$Q$7:$ZZ$10000;;ZEILE(A2)));"#.##0,00") & ")"

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[dertommy]

Danke, sehr. Ich musste den Bereich ZZ anpassen, dann hat es funktioniert.

[LCohen]

Jetzt sag nicht, IV statt ZZ ... dann solltest Du Deine Excel-Version hier als Angabe korrigieren. Oder es in der Aufgabe mitteilen. Der Synology-Krempel interessiert in diesem Forum nicht.