Produkt, wenn Zellinhalt = 0

[AnnetteB]

Hallo, 

für eine nummerologische Auswertung brauche ich eine Berechnung aus Geburtsdatum und Geburtszeit. Es ist sicher eine ungewöhnliche Berechnung. Ich habe weder hier noch auf Excel-Hilfsseiten etwas passendes gefunden. Und würde mich daher riesig freuen, wenn mich jemand unterstützen könnte.

Hier ein Auszug aus der Datei zum besseren Verständnis.

  Nummerologische Berechnung_Test.xlsx (Größe: 14,37 KB / Downloads: 10)

Das Problem, für das ich eine Lösung suche ist in Spalte J.
Hier soll berechnet werden: Tag*Monat*(1.Zahl vom Jahr)*(2.Zahl vom Jahr)*(3.Zahl vom Jahr)*(4.Zahlvom Jahr)*(1.Zahl Stunde)*(2.Zahl Stunde)*(1.Zahl min)*(2.Zahl min)
also zB: 24.1.2022 18:30 --> 24*1*2*(0)*2*2*1*8*3*(0). Jede Null ist zu ignorieren. Das korrekte Ergebnis wäre hier: 4608

Meine Formel funktioniert, wenn weder im Jahr noch in Stunde oder Minute eine Null vorkommt. Sobald eine dabei ist nicht.  
Wo liegt der Fehler? Bzw. wie lautet die korrekte Formel?  

Vielen Dank schon mal im Vorraus.

[{Boris}]

Hi,

z.B.:

J3:
=B3*C3*LINKS(D3)*MAX(1;TEIL(D3;2;1))*MAX(1;TEIL(D3;3;1))*MAX(1;RECHTS(D3))*MAX(1;LINKS(E3))*MAX(1;RECHTS(E3))*MAX(1;LINKS(F3))*MAX(1;RECHTS(F3))

und runterkopieren.

[Kl@us-M.]

gelöscht

[shift-del]

Moin

Alternativ.

Code:

=PRODUKT(B3;C3;WENNFEHLER(1/(1/TEIL(D3;{1;2;3;4};1));1);WENNFEHLER(1/(1/TEIL(TEXT(ZEIT(E3;F3;0);"hhmm");{1;2;3;4};1));1))

[rate mit]

Hallo,

hier noch eine Alternative...

Code:

=PRODUKT(B3;C3;TEIL(WECHSELN(TEXTVERKETTEN("";WAHR;D3:F3);"0";1);ZEILE(INDIREKT("1:"&8));1)*1)

[rate mit]

Code:

=PRODUKT(B3;C3;TEIL(WECHSELN(TEXTVERKETTEN("";WAHR;D3:F3);0;1);ZEILE(INDIREKT("1:8"));1)*1)

[{Boris}]

Hi,

wenn schon verkürzen, dann richtig: 

=PRODUKT(B3;C3;TEIL(WECHSELN(TEXTKETTE(D3:F3);0;1);ZEILE($1:$8);1)*1)

[AnnetteB]

Herzlichen Dank euch Spezialisten!

Das führt mich wieder zu meiner ursprünglichen Intension, das Datum in einer Zelle zu erfassen (TT.MM.JJJJ) und die Uhrzeit in der nächsten Spalte im Format hh:mm. Das würde so viel vereinfachen!

Ich bin "Formelanfänger" und würde gerne mit eurer Hilfe dazu lernen. 8 Berechnungen sind auszuführen. Könntet ihr mir helfen? 

Daten:
Spalte D: Datum (TT.MM.JJJJ)
Spalte E: Uhrzeit (hh:mm)

Berechnungen:
Spalte G =TT*MM*JJJJ*(h+h+m+m) 
Spalte H =TT*MM*JJJJ*hh*mm 
Spalte I =TT*MM*J*J*J*J*h*h*m*m 
Spalte J =TT+MM+JJJJ+hh+mm 
Spalte K=TT*MM*JJJJ-(h+h+m+m) 
Spalte L =TT*MM*JJJJ
Spalte M =TT*MM*JJJJ-JJJJ 
Spalte N =TT*MM*JJJJ+JJJJ

Wenn es einfacher ist, gerne auch in die Test-Tabelle schreiben.
  Nummerologische Berechnung_Test_1.xlsx (Größe: 19,97 KB / Downloads: 5)

Danke.

[BoskoBiati]

Hi,

mit einfachsten Excel-Funktionen:

Code:

=TAG(D4)*MONAT(D4)*JAHR(D4)*(KÜRZEN(STUNDE(E4)/10;0)+REST(STUNDE(E4);10)+KÜRZEN(MINUTE(E4)/10;0)+REST(MINUTE(E4);10))

den Rest kannst Du wohl selbst zusammenbauen.

[AnnetteB]

Vielen Dank BoskoBiati, das hat mir sehr geholfen!
Und ich habe eine neue Formel verstanden, super 

Und allen anderen auch vielen Dank für eure Unterstützung