Prüfen ob Wert in anderen Tab vorhanden

[omron2003]

Hallo Forum,

in Tabelle1 , Tabelle2, Tabelle3 werden im Spalte A3:A100 Zahlen eingegeben,
eine Zahl darf aber egal in welcher Tabelle sie eingegeben wir nur ein mal
vorkommen. Nun suche ich eine Möglichkeit unter VBA das wenn eine Zahl eingegeben wird
die bereits in einer der Tabellen vorhanden ist eine Warnmeldung erscheid.

Besten Dank im Voraus
omron2003

[Kuwer]

Hallo,

' **************************************************************
'  Modul:  DieseArbeitsmappe  Typ = Element der Mappe(Sheet, Workbook, ...)
' **************************************************************

Option Explicit

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
  Dim i As Long
  Dim lngZ As Long
  Dim varT As Variant
  
  varT = Array("Tabelle1", "Tabelle2", "Tabelle3")
  
  If Not IsError(Application.Match(Sh.Name, varT, 0)) Then
    If Not Application.Intersect(Target.Cells(1), Sh.Range("A3:A100")) Is Nothing Then
      With Target.Cells(1)
        If IsNumeric(.Value) Then
          For i = LBound(varT) To UBound(varT)
            lngZ = lngZ + Application.CountIf(Worksheets(varT(i)).Range("A3:A100"), .Value)
          Next i
          If lngZ > 1 Then
            .Select
            MsgBox .Value & " gibt es schon " & lngZ - 1 & " mal!", vbInformation
          End If
        End If
      End With
    End If
  End If
End Sub

Gruß Uwe

[omron2003]

Hallo,

Super Danke nochmals für die schnelle Hilfe,
funktioniert bestens.

LG
omron2003