Rangfolge aufsteigend sortiert

[WillWissen]

Hallo Freunde,

zu vorgerückter Stunde mache ich mich über ein kleines Problem meines Spezls her. Für eine Auswertung nach nachfolgendem Schema will er die Rangfolge in Klartext (also die entsprechenden Namen) in aufsteigender Reihenfolge sortiert haben. Natürlich automatisch ;)

Ich vermute mal, mit INDEX und KKLEINSTE. Aber ich krieg's nicht hin.

Tabelle1

	A	B	C	D
1	Name	Ergebnis	Rangfolge	gewünschtes Ergebnis
2	Name 1	14	9	1. Name 2
3	Name 2	97	1	2. Name 3
4	Name 3	96	2	3. Name 4
5	Name 4	88	3	4. Name 9
6	Name 5	16	8	5. Name 6
7	Name 6	72	5	6. Name 8
8	Name 7	33	7	7. Name 7
9	Name 8	69	6	8. Name 5
10	Name 9	80	4	9. Name 1

Formeln der Tabelle

Zelle Formel C2 =RANG(B2;$B$2:$B$10;0) C3 =RANG(B3;$B$2:$B$10;0) C4 =RANG(B4;$B$2:$B$10;0) C5 =RANG(B5;$B$2:$B$10;0) C6 =RANG(B6;$B$2:$B$10;0) C7 =RANG(B7;$B$2:$B$10;0) C8 =RANG(B8;$B$2:$B$10;0) C9 =RANG(B9;$B$2:$B$10;0) C10 =RANG(B10;$B$2:$B$10;0)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4

[Jockel]

hi Güter, meinst du so..:

PHP-Code:

=ZEILE(A1)&". "&INDEX($A$2:$A$10;VERGLEICH(ZEILE(A1);$C$2:$C$10;0)) 


[WillWissen]

Hi Jörg,

auf dich ist, wie immer, Verlass. Genau so passt es. *GleichMalDankeDaLass*

[BoskoBiati]

Hallo,

leider geht die Formel in die Hose, wenn doppelte vorhanden sind:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1	Name	Ergebnis	Rangfolge	gewünschtes Ergebnis
2	Name 1	16	8	1. Name 2
3	Name 2	97	1	2. Name 3
4	Name 3	96	2	3. Name 4
5	Name 4	88	3	4. Name 9
6	Name 5	16	8	5. Name 6
7	Name 6	72	5	#NV
8	Name 7	33	7	7. Name 7
9	Name 8	72	5	8. Name 1
10	Name 9	80	4	#NV

Zelle	Formel
C2	=RANG(B2;$B$2:$B$10)
D2	=ZEILE(A1)&". "&INDEX($A$2:$A$10;VERGLEICH(ZEILE(A1);$C$2:$C$10;0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Dann eher so:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E
1	Name	Ergebnis	Rangfolge	gewünschtes Ergebnis
2	Name 1	16	8,0001	1. Name 2
3	Name 2	97	1,0001	2. Name 3
4	Name 3	96	2,0001	3. Name 4
5	Name 4	88	3,0001	4. Name 9
6	Name 5	16	8,0002	5. Name 6
7	Name 6	72	5,0001	6. Name 8
8	Name 7	33	7,0001	7. Name 7
9	Name 8	69	6,0001	8. Name 1
10	Name 9	80	4,0001	9. Name 5

Zelle	Formel
C2	=RANG(B2;$B$2:$B$10)+ZÄHLENWENN($B$2:B2;B2)%%
D2	=ZEILE(A1)&". "&INDEX($A$2:$A$10;VERGLEICH(KKLEINSTE($C$2:$C$10;ZEILE(A1));$C$2:$C$10;0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Peter]

Hallo,

alternativ ist vielleicht auch eine Pivottabelle eine Option.

Natürlich automatisch

naja, ein Klick auf den Button Aktualisieren ist notwendig.

[Jockel]

Hallo Edgar, das war zwar nicht gefragt... ... aber das geht auch (ganz) einfach - ohne hilfsspalte (was du ja auch sicher weißt...) :100:

Arbeitsblatt mit dem Namen 'Blatt1'
	A	B	C	D
1	Name	Ergebnis	Rangfolge	gewünschtes Ergebnis
2	Name 1	16	8	1. Name 2
3	Name 2	97	1	2. Name 3
4	Name 3	96	2	3. Name 4
5	Name 4	88	3	4. Name 9
6	Name 5	16	9	5. Name 6
7	Name 6	72	5	6. Name 8
8	Name 7	33	7	7. Name 7
9	Name 8	69	6	8. Name 1
10	Name 9	80	4	9. Name 5

Zelle	Formel
C2	=RANG(B2;$B$2:$B$10)+ZÄHLENWENN($B$2:B2;B2)-1
D2	=ZEILE(A1)&". "&INDEX($A$2:$A$10;VERGLEICH(KKLEINSTE($C$2:$C$10;ZEILE(A1));$C$2:$C$10;0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Hallo,

leider geht die Formel in die Hose, wenn doppelte vorhanden sind:

...

Dann eher so:

Arbeitsblatt mit dem Namen 'Tabelle2'
	A	B	C	D	E
1	Name	Ergebnis	Rangfolge	gewünschtes Ergebnis
2	Name 1	16	8,0001	1. Name 2
3	Name 2	97	1,0001	2. Name 3
4	Name 3	96	2,0001	3. Name 4
5	Name 4	88	3,0001	4. Name 9
6	Name 5	16	8,0002	5. Name 6
7	Name 6	72	5,0001	6. Name 8
8	Name 7	33	7,0001	7. Name 7
9	Name 8	69	6,0001	8. Name 1
10	Name 9	80	4,0001	9. Name 5

Zelle	Formel
C2	=RANG(B2;$B$2:$B$10)+ZÄHLENWENN($B$2:B2;B2)%%
D2	=ZEILE(A1)&". "&INDEX($A$2:$A$10;VERGLEICH(KKLEINSTE($C$2:$C$10;ZEILE(A1));$C$2:$C$10;0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo,

alternativ ist vielleicht auch eine Pivottabelle eine Option.

Natürlich automatisch

naja, ein Klick auf den Button Aktualisieren ist notwendig.

hallo Peter, aber doch nur wenn gleiche "Ränge" erlaubt sind..., oder? aber gerade da gibt's ja verschiedene interpretationsmöglichkeiten...

Arbeitsblatt mit dem Namen 'Blatt1'
	A	B	C	D	E	F	G	H	I
1	Name	Ergebnis	Rangfolge	gewünschtes Ergebnis			Name	_Ergebnis	_Rang
2	Name 1	16	8	1. Name 2			Name 2	97	1
3	Name 2	97	1	2. Name 3			Name 3	96	2
4	Name 3	96	2	3. Name 4			Name 4	88	3
5	Name 4	88	3	4. Name 7			Name 7	80	4
6	Name 5	16	9	5. Name 9			Name 9	80	4
7	Name 6	72	6	6. Name 6			Name 6	72	5
8	Name 7	80	4	7. Name 8			Name 8	69	6
9	Name 8	69	7	8. Name 1			Name 1	16	7
10	Name 9	80	5	9. Name 5			Name 5	16	7

Zelle	Formel
C2	=RANG(B2;$B$2:$B$10)+ZÄHLENWENN($B$2:B2;B2)-1
D2	=ZEILE(A1)&". "&INDEX($A$2:$A$10;VERGLEICH(KKLEINSTE($C$2:$C$10;ZEILE(A1));$C$2:$C$10;0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hallo Jörg,

ich brauche auch keine Hilfsspalte, ich muß nur die Anzeige auf ganze Zahlen beschränken. Hat zudem den Vorteil, dass doppelte auch mit dem gleichen Rang angezeigt werden. Hier noch eine Altenative:

[html]

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Name	Ergebnis	Rangfolge	gewünschtes Ergebnis
2	Name 1	16	8	1. Name 2	1. Name 2
3	Name 2	97	1	2. Name 3	2. Name 3
4	Name 3	96	2	3. Name 4	3. Name 4
5	Name 4	88	3	4. Name 9	4. Name 9
6	Name 5	16	8	5. Name 6	5. Name 6
7	Name 6	72	5	6. Name 8	5. Name 8
8	Name 7	33	7	7. Name 7	7. Name 7
9	Name 8	72	5	8. Name 1	8. Name 1
10	Name 9	80	4	9. Name 5	8. Name 5

Zelle	Formel
C2	=RANG(B2;$B$2:$B$10)+ZÄHLENWENN($B$2:B2;B2)%%
D2	=ZEILE(A1)&". "&INDEX($A$2:$A$10;VERGLEICH(KKLEINSTE($C$2:$C$10;ZEILE(A1));$C$2:$C$10;0))
E2	=KÜRZEN(KKLEINSTE($C$2:$C$10;ZEILE(B1));)&". "&INDEX($A$2:$A$10;VERGLEICH(KKLEINSTE($C$2:$C$10;ZEILE(B1));$C$2:$C$10;0))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[/html]

[WillWissen]

Hi Edgar, hi Jörg,

danke für eure Ergänzungen. Habe allerdings auf KGRÖSSTE umgestellt, da aufsteigende Sortierung gewünscht ist.

@ Edgar

Das war's, was ich eingangs erwähnt hatte - bin allerdings nicht mehr drauf gekommen, obwohl du mir vor langer, langer Zeit das mit den %% erklärt hattest.

@Jörg

Du hast Recht, gefragt war das nicht. Aber ich hatte auch nicht daran gedacht, dass es doppelte Ergebnisse geben könnte. Da muss ich meinen Spezl noch fragen. Sollte das nicht der Fall sein, werde ich deinen ersten Vorschlag einbauen.

Ansonsten wähle ich Jörgs Lösung ohne Hilfsspalte. Ich hoffe, lieber Edgar, du haust mich nicht zu sehr - ich bin sehr sensibel. ;)

[WillWissen]

Hallo,

alternativ ist vielleicht auch eine Pivottabelle eine Option.

Natürlich automatisch

naja, ein Klick auf den Button Aktualisieren ist notwendig.

Hi Peter,

danke für den Denkanstoß. An PT hatte ich schon gedacht und meinem Spezl auch bereits vorgeschlagen. Seine Antwort: "Ach, nö, gibts da keine Formel? Das hier ist mir zu kompliziert."

Wenn er meint....