Ranking mit doppelten Werten

[Excelmonsta]

Guten Morgen zusammen,

anbei habe ich eine Datei hochgeladen. Es geht um ein Ranking, ich finde da
zur Zeit keine vernünftige Lösung.

Ich war schon ganz zufrieden mit dem Ergebnis, habe dann jedoch gemerkt,
dass die Formel bei doppelten %-Werten nicht mehr funktionieren kann - da
der erste Wert zurückgegeben wird und ich somit kein direkten Bezug zu dem
exakten Standort habe.

Ich möchte gerne ein variabel gestaltetes Top 3 und Flop 3 Ranking aus den
Prozentwerten generieren und natürlich dazu den Standort neben den %-Wert
stellen. Die Werte ändern sich natürlich regelmäßig.

Den bisherigen Versuch mit KGrösste und INDEX + Vergleich seht ihr ja in der
Matrix C20:E29.

Vielen Dank schon einmal für Vorschläge oder Ideen was ich besser machen kann
oder wie eine Lösung aussehen könnte.

Ganz freundliche Grüße von mir
Excelmonsta

[steve1da]

Hola,

Code:

=INDEX($B$6:$B$15;AGGREGAT(15;6;ZEILE($A$6:$A$15)-5/($F$6:$F$15=D20);ZÄHLENWENN($D$20:D20;D20)))

Gruß,
steve1da

[Excelmonsta]

Hallo steve1da,

vielen Dank für die schnelle Lösung, ich bin gerade dabei die Formel
zu verstehen...beim einfügen im Feld E20 bekomme ich jedoch die
Meldung #Name...

oder habe ich die Formel falsch eingefügt?

Habe das noch einmal in der Anlage...

Vielen Dank schon einmal!!

Viele Grüße.

[steve1da]

Hola,

hast du evtl. kein Excel 2010?

Gruß,
steve1da

[Excelmonsta]

Hallo - du hast recht...ich habe Excel 2007.
Ist in der Formel eine bestimmte Funktion drinnen, die 2007 noch nicht beherrscht?

Viele Grüße

[steve1da]

Hola,

ja, Aggregat() gibts erst ab 2010.

Code:

=INDEX($B$6:$B$15;KKLEINSTE(WENN($F$6:$F$15=D20;ZEILE($A$6:$A$15)-5);ZÄHLENWENN($D$20:D20;D20)))

Diese Formel mit Strg-Shift-Enter abschließen.

Gruß,
steve1da

[LCohen]

G6: Top
H6:H8: =(1-REST(KGRÖSSTE(INDEX(RUNDEN(F$6:F$15/1%%;)-ZEILE(F$6:F$15)%%;);ZEILE(H1));1))/1%%
I6:M12: =INDEX($A:$F;$H6;SPALTE(B6)) und Zeile 9 in I:M leer überkopieren
G10: Flop
H10:H12: =REST(KKLEINSTE(INDEX(RUNDEN(F$6:F$15/1%%;)+ZEILE(F$6:F$15)%%;);ZEILE(H1));1)/1%%

[Excelmonsta]

Vielen Dank!!

Beide Lösungen sind super, danke an euch beide.

@steve1da - verstehe ich es richtig, dass hier: ZEILE($A$6:$A$15)-5)
in der Zeile von Spalte A durch das -5 die fünfte Spalte also Spalte F gemeint ist?

Ich habe die Datei im Original ein wenig anders aufgebaut, da stehen meine Werte
(Filiale In Spalte C, Name in Spalte D) und Prozentwert in Spalte H. Da funktioniert die
Formel noch nicht richtig, hatte die angepasst aber mit dem -5 scheint es noch nicht zu
funktionieren, da hab ich noch einen Fehler drinnen.

Viele Grüße und schon einmal ein schönes Wochenende.
Ihr seid super!

[steve1da]

Hola,

nein, das verstehst du falsch. Der Bereich in dem die Formel arbeitet geht von A6 bis A15, das sind 10 Zeilen. Das muss der Formel gesagt werden, entweder so:

Code:

...zeile(A6:A15)-1

oder

Code:

.....zeile(A1:A10)

"Funktioniert nicht so richtig" hilft beim Helfen nicht. Wenn die Daten nicht in A6 anfangen, musst du das anpassen. Ansonsten wäre eine Beispieldatei sinnvoll, die dem Aufbau des Originals entspricth.

Gruß,
steve1da