Rückgabewert aus Tabelle mit unterschiedlichen Kombinationsmöglichkeiten

[Spiderzid]

Hallo zusammen,

aktuell "bastle" ich an einer Checkliste für Reinigungen und befinde mich vielleicht irgendwie auf dem Irrweg. Habt Ihr mal einen Vorschlag wie ich ohne langwierigen Aufwand mit x-unzähligen Kombinationmöglichkeiten, Werte aus einer Tabelle in meine Liste übertragen kann?

Dazu lade ich eine Beispieldatei mit hoch.


In Zelle C4 gebe ich den zu reinigend Behälter ein (Bezug aus Register "Produkte"), daraus resultiert die benötigte Temperatur.
Nun wähle ich in B6 das Vorprodukt aus einer Dropdownliste (Bezug aus Register "Produkte") aus.
Anschließend in B8 das Folgeprodukt.
Nun sollte sich hieraus die Reinigungsart (B10), Anzahl der Wasser (B12) und die benötigte Zeit (B16) ergeben.

>>><<<

Woran es aktuell scheitert ist, wie ich es eingeben muss/kann, ohne die X-unzähligen Vor- u. Folgeprodukt Kombinationen in eine Tabelle zu schreiben. In meinem Beispiel sind es 26 Produkte, wir haben aktuell um die 600.

Beispiele (siehe Register Beispieltabelle"):
Vorprodukt 1 mit  Folgeprodukt 1 = Reinigungsart 2; Anzahl Wasser 1; 1,5Std
Vorprodukt 1 mit Folgeprodukt 2 = Reinigungsart 3; Anzahl Wasser 2; 1,5 Std
Vorprodukt 1 mit Folgeprodukt 3 = Reinigungsart 3; Anzahl Wasser 1; 1,5 Std
Vorprodkt 6 mit Folgeprodukt 1 = RE; Anzahl Wasser 0; 2,0 Std
Vorprodukt 5 mit Folgeprodukt 2 = Reinigungsart 3, Anzahl Wasser 1; 2,0 Std
  Versuch_01.xlsx (Größe: 20,07 KB / Downloads: 3)
usw. usw. usw....

Nebenbei: würde für mein Vorhaben eine Tabelle reichen? Wenn ich die Dropdownliste für Vor- u. Folgeprodukt nutze?


Ich hoffe ich konnte es einigermaßen gut erklären, was ich meine.


Danke für Eure Vorschläge

[shift-del]

Moin

Arbeitsblatt mit dem Namen 'Beispieltabelle'
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q	R	S
1	Vorprodukt	Folgeprodukt	Reinigungsart	Anzahl Wasser	Zeit
2	Produkt 1	Produkt 1	2	1	1,5
3	Produkt 1	Produkt 2	3	2	1,5
4	Produkt 1	Produkt 3	3	1	1,5				zu reinigender Behälter	B-	19
5	Produkt 6	Produkt 1	RE	0	2
6	Produkt 5	Produkt 2	3	1	2				Vorprodukt im Behälter		Produkt 1		Produkt 1	Produkt 6	Produkt 5	Produkt 2	Produkt 9	Produkt 8	Produkt 7
7	Produkt 2	Produkt 6	3	2	1,5
8	Produkt 9	Produkt 3	3	1	2				Folgeprodukt im Behälter		Produkt 3		Produkt 1	Produkt 2	Produkt 3	Produkt 6	Produkt 9	Produkt 4
9	Produkt 8	Produkt 9	4	1	1,5
10	Produkt 7	Produkt 4	1	0	1,5				Reinigungsart		3
11
12									Anzahl an Wasser		1
13
14									benötigte Temperatur		120
15
16	Behälter	Art	Temperatur						Zeit		1,5
17	1	Loop	90
18	2	Rühr	120
19	3	Loop	90

Zelle	Formel
M6	=MTRANS(EINDEUTIG(tbl_Kombinationen[Vorprodukt]))
M8	=MTRANS(EINDEUTIG(tbl_Kombinationen[Folgeprodukt]))
K10	=FILTER(tbl_Kombinationen[Reinigungsart];(tbl_Kombinationen[Vorprodukt]=K6)*(tbl_Kombinationen[Folgeprodukt]=K8);"kein Trefffer")
K12	=FILTER(tbl_Kombinationen[Anzahl Wasser];(tbl_Kombinationen[Vorprodukt]=K6)*(tbl_Kombinationen[Folgeprodukt]=K8);"kein Trefffer")
K14	=XVERWEIS(K4;tbl_Behälter[Behälter];tbl_Behälter[Temperatur])
K16	=FILTER(tbl_Kombinationen[Zeit];(tbl_Kombinationen[Vorprodukt]=K6)*(tbl_Kombinationen[Folgeprodukt]=K8);"kein Trefffer")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
K4	Liste		=$A$17:$A$43
K6	Liste		=$M$6#
K8	Liste		=$M$8#

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[Spiderzid]

Hallo shift-del,

dass muss ich mir in Ruhe anschauen und durchtesten. Ich gebe bescheid! Aber Danke schon mal für deine Mühe.

Christian