SUMMENPRODUKT mit vielen Bedingungen

[steve1da]

Hola,

ok, ich hatte nicht genau genug getestet. Es wird falsch gerechnet wenn mehrere ODER-Bereiche in der Formel in {} stehen.
Entweder:

Code:

=SUMME(SUMMEWENNS(D2:D15;A2:A15;{4001.4003};B2:B15;"<=199999";C2:C15;">=2018";C2:C15;"<=2020"))

Oder:

Code:

=SUMMENPRODUKT(((A2:A15=4001)+(A2:A15=4003))*((C2:C15=2018)+(C2:C15=2019)+(C2:C15=2020))*(B2:B15<=199999)*(D2:D15))

Gruß,
steve1da

[Tiffy93]

Jaaa!!! 

Vielen vielen Dank für dir Mühe! 

Hat geklappt. Merke also: Mehr als ein ODER-Bereich bekommt die Formel irgendwie nicht hin.... 

Einen entspannten Abend noch!

[Ego]

Hallo T...,

wie du am Anfang aufgezeigt hast, darf eine oder-Bedingung als Vergleich mit einer Liste geschrieben werden (kannte ich noch nicht). Es reicht also aus die kürzere Liste in eine Summe von Vergleichen umzuwandeln:

Code:

=SUMMENPRODUKT(((A2:A15=4001)+(A2:A15=4003))*(C2:C15={2018.2019.2020})*(B2:B15<=199999)*(D2:D15))

Falls die kürzere Liste auch lang ist, ist folgende Formel kürzer:

Code:

=SUMMENPRODUKT(MMULT(--(A2:A15={4001.4003});{1;1})*(B2:B15<=199999)*(C2:C15={2018.2019.2020})*(D2:D15))

[Tiffy93]

Moin Moin zusammen,

bis jetzt hat die Formel so für mich ausgereicht. Das hat mir sehr weitergeholfen.

Nun habe ich ähnliche Anforderungen, jedoch mit mehreren "Landkreisen". Folgende Formel liegt mir vor:

=SUMMEWENNS(Daten!$N:$N;Daten!$H:$H;Tabelle!$AH$1;Daten!$W:$W;Tabelle!$AJ$4;Daten!$AM:$AM;Tabelle!$B8)/1000

Ich möchte nun ein weiteres Kriterium hinzufügen, und zwar Landkreise. Ich möchte allerdings für die Formel bis zu 20 Landkreise auswählen. Dies würde ja wie folgt funktionieren:

=Summe(Summewenns([...];Daten!B:B;{"NF"."IZ"."NWM".[...]};[...])

Das ist sehr mühselig, da, falls sich mal ein Landkreis ändert, was vorkommen wird, ich manuell in jede Formel den entsprechenden Teil löschen muss. Ich hätte also gerne lieber eine Tabelle, aus der jede Formel die Daten zieht.

Leider funktioniert das mit den geschweiften Klammern nicht. Dort kann man nichts markieren, nur einzeln eingeben. Hat da jemand eine Idee? Ich möchte die Formal auch nicht unnötig verkomplizieren.

Vielen Dank für eure Mühe und Hilfe!!

Grüße
Tiffy

[Klaus-Dieter]

Hallo,

mal aus dem hohlen Bauch: sieh dir mal die Funktion MTRANS an. Damit könnte das gehen.

[Tiffy93]

Moin Klaus-Dieter,

danke für deine Nachricht.

Wie würdest du das implementieren? Damit wird ja nur die Ausgangstabelle transponiert aber noch nicht innerhalb der geschweiften Klammern gezählt.

Grüße
Tiffy

[Klaus-Dieter]

Hallo,

habe dir mal ein Beispiel mit deiner Formel erstellt:

Tabelle1

	F	G	H
2	10		2018
3			2019
4			2020

Formeln der Tabelle

Zelle Formel F2 =SUMME(SUMMEWENNS(D2:D15;A2:A15;{4001.4003};B2:B15;"<=199999";C2:C15;MTRANS(H2:H4)))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[Tiffy93]

Vielen Vielen Dank!

Hat funktioniert.

Gibt es noch eine Möglichkeit, mehrere Tabellen in einer MTRANS Formel zu markieren, die dann als Kriterium für die SUMMEWENNS gelten?

In meiner Ausgangstabelle stehen nicht alle Landkreise, die ich brauche, direkt untereinander, da ich immer nur spezifische Landkreise benötige. Ich habe jetzt einfach 2 Formeln hintereinandergereiht:

=SUMME(SUMMEWENNS(Daten!$N$2:$N$80000;Daten!$H$2:$H$80000;Tabelle!$Z$1;Daten!$W$2:$W$80000;Tabelle!$AA$4;Daten!$B$2:$B$80000;MTRANS('Zuordnung Landkreise'!$A$9:$A$11)))/1000+SUMME(SUMMEWENNS(Daten!$N$2:$N$80000;Daten!$H$2:$H$80000;Tabelle!$Z$1;Daten!$W$2:$W$80000;Tabelle!$AA$4;Daten!$B$2:$B$80000;MTRANS('Zuordnung Landkreise'!$A$16:$A$22)))/1000