SVERSWEIS oder doch eine andere Funktion

[Hoshy1]

Hallo Forum,

ich habe noch ein Problem mit den Funktionen.

In der Tabelle Deckblatt möchte ich ganz gerne bei Tätigkeit im Raum die markierten Räume aus der Tabelle Raumnutzung anzeigen lassen. Und zwar nur die, die durch ein Kreuz markiert wurden. Es sind auch mehrere Räume möglich. Diese sollen auch nur in den zwölf Feldern angezeigt werden.
Siehe dazu das Beispiel:

Ich ahbe es mit dem SVERWEIS und dem WVERWEIS probiert, aber mein Problem das das Ergebnis nicht in Spalten sondern in Zeilen angezeigt werden soll und die die Daten aber in Spalten enthalten sind. Ausserdem haben ich leider kein eindeutiges Merkmal sondern nur das Kreuz.

Ich hoffe auf Euer Knowhow  

Tim Kretschmann

[BoskoBiati]

Hallo

Ich hoffe auf Euer Knowhow 

1. der Tabellenaufbau ist, gelinde gesagt, Müll!
2. verbundene Zellen machen nur Probleme!
3. Leerzeilen sind unnütz und erschweren das Auswerten.
4. Wenn ein Ausdruck auf einem bestimmten Formblatt erfolgen soll, dann wäre zu überlegen, ob das Formblatt nicht umgestaltet werden kann.

Arbeitsblatt mit dem Namen 'Deckblatt'
	G	H
12	E02
13

Zelle	Formel
G12	=WENNFEHLER(INDEX(Raumnutzung!$B:$B;AGGREGAT(15;6;ZEILE(Raumnutzung!$B:$B)/(Raumnutzung!$A:$A="x");KÜRZEN(SPALTE(A$1)/2;)+1));"")
G13	=WENNFEHLER(INDEX(Raumnutzung!$B:$B;AGGREGAT(15;6;ZEILE(Raumnutzung!$B:$B)/(Raumnutzung!$A:$A="x");KÜRZEN(SPALTE(M$1)/2;)+1));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo, sind das deine Wunschergebnisse..?

Arbeitsblatt mit dem Namen 'Deckblatt'

G

H

I

J

K

L

M

N

O

P

Q

R

33

E02

E22

O20

E44

E45

E19

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Du gibst als Version XL2010 an postest aber eine xls-Datei was darauf schließen läßt, dass diese Datei unter einer Version kleiner XL2007 benutzt wird..!!!!

[BoskoBiati]

Hi,

für 2003 würde auch das gehen:

Arbeitsblatt mit dem Namen 'Deckblatt'
	G	H
12	E02
13

Zelle	Formel
G12	{=WENN(ZÄHLENWENN(Raumnutzung!$A:$A;"x")<SPALTE(A1)/2;"";INDEX(Raumnutzung!$B:$B;KKLEINSTE(WENN(Raumnutzung!$A:$A="x";ZEILE(Raumnutzung!$A:$A));KÜRZEN(SPALTE(A1)/2;)+1)))}
G13	{=WENN(ZÄHLENWENN(Raumnutzung!$A:$A;"x")<SPALTE(M2)/2;"";INDEX(Raumnutzung!$B:$B;KKLEINSTE(WENN(Raumnutzung!$A:$A="x";ZEILE(Raumnutzung!$A:$A));KÜRZEN(SPALTE(M2)/2;)+1)))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Hoshy1]

Vielen Dank für Eure Antworten.

Excel 2010 ist das Programm was ich verwende. Habe da wohl beim Speichern den falschen Dateityp gewählt.

Danke Euch

Es klappt einwandfrei :)