SVERWEIS mit INDIREKT kombinieren?

[cocodile]

Hallo zusammen,

ich arbeite mit folgender Formel um Daten zweier Datenblätter zu vergleichen:
=WENNFEHLER(WENN(SVERWEIS(A76;'2021_Nov_15'!A:AA;2;FALSCH)=SVERWEIS(A76;'2021_Dez_15'!A:AA;2;FALSCH);"unverändert";"bearbeitet");"neu")

nun möchte ich gerne die Namen der Datenblätter dynamisch hinterlegen, da in Zukunft weitere Blätter mit anderen Namen hinzukommen und ich diese dann nicht in der Formel anpassen möchte.
Also anstelle von 2021_Nov_15 und 2021_Dez_15 möchte ich, dass hier die Werte genommen werden, die ich in der Zelle M3 und M4 hinterlegt habe. (dort steht 2021_Nov_15 und 2021_Dez_15)

Ich bin der Meinung, dass dies mit der INDIREKT Funktion irgendwie realisierbar sein sollte, bin dazu aber noch nicht versiert genug in Excel und hoffe auf eure Hilfe.

Besten Dank!
coco

[schauan]

Hallöchen,

bei INDIREKT erzeugst Du den Bezug als Text

=INDIREKT("Tabelle2!" & A1)

wobei in A1 die Zelle steht wo Du hin willst

oder

=INDIREKR("'" & B1 & "'!C1")

hier wäre der Name vom Tabellenblatt der Inhalt von B1 ...

[Cadmus]

Ich würde mich erst einmal von den vielen Tabellenblättern verabschieden und die Datenstruktur überdenken. Gleichartige Daten gehören auf ein Tabellenblatt.

[cocodile]

Hallo zusammen,

vielen Dank für eure Antworten, die helfen mir aber leider beide nicht weiter.

Ich will in meiner Formel 
=WENNFEHLER(WENN(SVERWEIS(A76;'2021_Nov_15'!A:AA;2;FALSCH)=SVERWEIS(A76;'2021_Dez_15'!A:AA;2;FALSCH);"unverändert";"bearbeitet");"neu")

die fett markierten Einträge so anpassen, dass sie automatisch durch den Inhalt einer anderen Zelle (in meinem Fall M3 und M4) ersetzt werden.

Ob ich hier mit INDIREKT überhaupt auf der richtigen Spur bin weiß ich leider nicht. Ggf. ist das ja auch viel simpler und ich komm einfach nur nicht drauf
Ich möchte also in den Zellen M3 und M4 eintragen können, welche Datenblätter mein SVERWEIS durchsuchen soll

[schauan]

Hallöchen,

das wäre mein zweites Beispiel.

[cocodile]

Hallo schauan, wärst du bitte so nett und kannst es in meine Formel einsetzen? Egal wie ich es drehe und wende funktioniert es nicht

[steve1da]

Ungestest:

Code:

=WENNFEHLER(WENN(SVERWEIS(A76;INDIREKT("'"&M3&"'!A:AA");2;FALSCH)=SVERWEIS(A76;INDIREKT("'"&M4&"'!A:AA");2;FALSCH);"unverändert";"bearbeitet");"neu")

[cocodile]

vielen Dank, hat funktioniert! :)