SVERWEIS oder andere Idee

[DruPa]

Hallo liebe Excel Nutzer,

ich stoße gerade mit einem Problem an meine Grenzen.

Ich habe eine Tabelle mit den folgenden Daten im Blatt1:


[
Bild bitte so als Datei hochladen: Klick mich!
]


In einem zweiten Blatt möchte ich nun eine Abfrage erstellen, die mir den Inhalt aus Spalte G ermittelt
Wenn Spalte A vom Blatt 1 das Fragment "0815" enthält und Spalte B=0 C=0 D=0 F=0 und Spalte E=1 dann gebe mit das Ergebnis der Spalte G aus. In dem Fall 20
Wenn Spalte A vom Blatt 1 das Fragment "0815" enthält und Spalte C=0 D=0 E=0 F=0 und Spalte B=1 dann gebe mit das Ergebnis der Spalte G aus. In dem Fall 10

In Blatt2 A1 steht das Fragment und in B2 erwarte ich das Ergebnis

[
Bild bitte so als Datei hochladen: Klick mich!
]

Ich habe das nun anfänglich mit dieser Formel lösen wollen:
=WENN(ISTNV(SVERWEIS(A1;Blatt1!A:G;7;0));"Name " &A1 & " nicht in Spalte A vorhanden";SVERWEIS(A1;Blatt1!A:G;7;0))

Aber ich bekomme die erweiterte Abfrage der Spalten BCDEF nicht berücksichtigt. 

Vielleicht kann mir hier jemand weiterhelfen. 

Vielen Dank Frank

[DruPa]

Hab nun nach etlichen Versuchen die Lösung gefunden und möchte diese nicht vorenthalten.

[
Bild bitte so als Datei hochladen: Klick mich!
]

Die Basis stammt von hier:
https://www.tabstr.de/datenanalyse/sverweis/

Viele Grüße
Frank

[BoskoBiati]

Hi,

wenn ich Deine mageren Ausführungen richtig verstanden habe, dann geht das viel einfacher:


  Patronen.xlsx (Größe: 11,88 KB / Downloads: 2)

[DruPa]

Hallo und danke für deine Mühen.

Es ist nicht immer ganz einfach ein Anliegen verständlich für jemanden zu schildern, der nicht gerade in der Materie drin steckt. 

Ich habe etwa 1000 Zeilen zu durchsuchen.
In denen müssen die Spalte B:F nach einer Kombination durchsucht werden
Beispiel: Spalte B=0 C=0 D=0 F=0 und Spalte E=1
Ich weiß aber nicht in welcher der 1000 Zeilen diese Kombination steht. 
Dazu kommt dann die Abfrage der Spalte A nach einem beliebigen Fragment
Wenn beides übereinstimmt, die Kombination aus B:F und dem Fragment, dann möchte ich den Wert aus Spalte G und der entsprechenden Zeile.

Deswegen hatte ich die Lösung mit dem Verweis ausgebaut, welche glücklicherweise perfekt funktioniert. 

Die Lösung wird mit deiner Formel leider nicht erreicht. 

Vielen Dank Frank

[BoskoBiati]

Hi,

Es ist nicht immer ganz einfach ein Anliegen verständlich für jemanden zu schildern

Du hast es doch fast geschafft!

Dann hilft Dir das eher:

Code:

=AGGREGAT(15;6;Blatt1!G:G/(Blatt1!B:B=0)/(Blatt1!C:C=0)/(Blatt1!D:D=0)/(Blatt1!E:E=1)/(Blatt1!F:F=0)/(ISTZAHL(SUCHEN(B4;Blatt1!A:A)));1)

Ich würde allerdings mit keiner der vorhandenen Formeln ganze Spalten abgrasen. Zudem würde ich die Kombinationen B:F in Zellen schreiben und diese Zellen abfragen, vereinfacht die Formel:


  Patronen.xlsx (Größe: 11,14 KB / Downloads: 6)

Eines der ganz üblen Dinge in Excel ist es, ganze Spalten als Text zu formatieren. Das bringt nur Probleme!!!

[DruPa]

Hallo Edgar,


vielen Dank. Ich bin immer wieder beeindruckt, welche Möglichkeiten Excel so hergibt. Deine Formel funktioniert perfekt. Chapeau!
Die Kombinationen sind nun in die Spalten eingetragen.
Darf ich deine Hilfe noch mal in Anspruch nehmen? Ich hatte gerade noch eine Idee, die Formel für mich zu erweitern.

Ich würde gern noch die Abfrage eines weiteren Feldes vornehmen.
Wenn C2 mit "BK" gefüllt ist, dann würde ich gern die Formel von Dir nehmen:

Code:

=AGGREGAT(15;6;Export!U:U/(Export!C:C=1)/(Export!D:D=0)/(Export!E:E=0)/(Export!F:F=0)/(ISTZAHL(SUCHEN(D2;Export!A:A)));1)

steht in C2 aber "C" dann würde ich gern diese Formel nehmen.

Code:

=AGGREGAT(15;6;Export!U:U/(Export!C:C=0)/(Export!D:D=1)/(Export!E:E=0)/(Export!F:F=0)/(ISTZAHL(SUCHEN(D2;Export!A:A)));1)

und wenn in C2 ein "M" steht, dann würde ich gern diese Formel nehmen. 

Code:

=AGGREGAT(15;6;Export!U:U/(Export!C:C=0)/(Export!D:D=0)/(Export!E:E=1)/(Export!F:F=0)/(ISTZAHL(SUCHEN(D2;Export!A:A)));1)

Ich bekomme das leider nicht verschachtelt.
Wenn keines zutrifft, möchte ich einfach das Wort "FEHLER" ausgeben.
Vielen Dank Frank

[BoskoBiati]

Hi,

da ich keine Tabellen nachbaue hier mal ein ungetester Ansatz:

Code:

=WENNFEHLER(AGGREGAT(15;6;Export!U:U/(Export!C:C=0+($C$2="BK"))/(Export!D:D=0+($C$2="C"))/(Export!E:E=0+($C$2="M"))/(Export!F:F=0)/(ISTZAHL(SUCHEN(D2;Export!A:A)));1);"")

[DruPa]

Hallo Edgar,

vielen Dank für deinen äußerst hilfreichen Ansatz. Wie sich zeigt ist es hilfreich, wenn mal jemand anderes drauf schaut. Auf diesen einfachen Ansatzpunkt bin ich einfach nicht gekommen. Man sieht den Wald vor lauter Bäumen nicht. DANKE

Deine Formel hat mir den richtigen Ansatz geliefert, auch wenn Sie so nicht funktionierte. Abgewandelt geht sie nun aber und bringt mir einiges an Stunden an Arbeitserleichterung. Super Danke

Code:

=AGGREGAT(15;6;Export!U:U/(Export!C:C=0+(WENN(C2="BK";1;0)))/(Export!D:D=0+(WENN(C2="PBK";1;0)))/(Export!E:E=0+(WENN(C2="C";1;0)))/(Export!F:F=0+(WENN(C2="M";1;0)))/(Export!G:G=0+(WENN(C2="Y";1;0)))/(Export!H:H=0+(WENN(C2="PC";1;0)))/(Export!I:I=0+(WENN(C2="PM";1;0)))/(Export!J:J=0+(WENN(C2="GY";1;0)))/(Export!K:K=0+(WENN(C2="PB";1;0)))/(ISTZAHL(SUCHEN(D2;Export!A:A)));1)

 
Viele Grüße Frank

[BoskoBiati]

Hallo,

wenn die Formel nicht funktioniert hat, dann hast Du was falsch gemacht!

Code:

=WENNFEHLER(AGGREGAT(15;6;Export!U:U/(Export!C:C=0+($C$2="BK"))/(Export!D:D=0+($C$2="PBK"))/(Export!E:E=0+($C$2="C"))/(Export!F:F=0+($C$2="M"))/(Export!G:G=0+($C$2="Y"))/(Export!H:H=0+($C$2="PC"))/(Export!I:I=0+($C$2="PM"))/(Export!J:J=0+($C$2="GY"))/(Export!K:K=0+($C$2="PB"))/(ISTZAHL(SUCHEN($D$2;Export!A:A)));1);"")

Nur als Info: 0+(C2="BK") ergibt 1, wenn in C2 BK steht!

Nochmal als ernst gemeinten Rat: Benutze diese Formel nicht mit ganzen Spalten! Das geht massiv auf die Performance. Versuche mal mit der Formelauswertung diese Formel zu untersuchen. Dein Excel wird lahmgelegt.


  Patronen.xlsx (Größe: 11,95 KB / Downloads: 5)