SVerweis mit Link auf Ursprungstabelle

[Skilla]

Hallo zusammen, 

wie kann ich nicht nur per SVERWEIS die Daten aus der Tabelle rechts in die Tabelle links (siehe Spalte B) einspielen, sondern die Zahlen (z.B. "5" oder "8") in der Tabelle links mit einem Link versehen, damit man per Klick direkt in der Zelle der Ursprungstabelle rechts auf dem Wert (z.B. "5" oder "8") landet?

siehe Datei im Anhang.

Vielen Dank vorab!!

[Frogger1986]

Mit der Formel für den Hyperlink lässt sich das realisieren. Du erstellt eine Zelladresse und benennst den Link mit dem Sverweis.

In B8

Code:

=HYPERLINK("#Tabelle1!H"&VERGLEICH([@Bezeichnung];G:G;0);WENNFEHLER(SVERWEIS(A8;$G$8:$H$9;2;FALSCH);""))

[Skilla]

Super, vielen Dank!! Du hast mir echt enorm weitergeholfen!
Das "H" in der Formel direkt zu Beginn hinter "#Tabelle1!" stellt den Bezug zur zweiten Tabelle und deren Spalte "H" her und muss deshalb angefügt werden, richtig?

[Jockel]

Hallo, wenn du auf dem selben Tabellenblatt bleibst, brauchst du "Tabelle1!" nicht eingeben. Dann reicht..:

PHP-Code:

=WENNFEHLER(HYPERLINK("#H"&VERGLEICH(A8;G:G;0);SVERWEIS(A9;$G$8:$H$9;2;0));"") 


---

...

Code:

=HYPERLINK("#Tabelle1!H"&VERGLEICH([@Bezeichnung];G:G;0);WENNFEHLER(SVERWEIS(A8;$G$8:$H$9;2;FALSCH);""))

Hallo, die Platzierung der Fehlerabfrage ist hier ungünstig gewählt...

[Frogger1986]

@skilla
Ja das siehst du richtig! 

@Jockel
Du hast recht so wird nur der Fehler im Verweis abgefangen, jedoch nicht im Link.

[Skilla]

Danke für eure Diskussion. Leider verstehe ich noch nicht ganz, wie ich die Formel umschreiben muss, wenn sich die Tabellen auf zwei unterschiedlichen Tabellenblättern befinden. Ich habe meine Ursprungsdatei im Anhang dafür nochmal angepasst und meine Frage darin umformuliert, wie die genannte Formel bei zwei Tabellenblättern umgeschrieben werden muss.

Vielen Dank für eure Hilfe!

[Jockel]

Hallo, so..:

PHP-Code:

=WENNFEHLER(HYPERLINK("#Tabelle2!B"&VERGLEICH(A8;Tabelle2!A:A;0);SVERWEIS(A8;Tabelle2!$A$5:$B$7;2;0));"") 


Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
7	Bezeichnung	Wert
8	A	5
9	B
10	C	8

Zelle	Formel
B8	=WENNFEHLER(HYPERLINK("#Tabelle2!B"&VERGLEICH(A8;Tabelle2!A:A;0);SVERWEIS(A8;Tabelle2!$A$5:$B$7;2;0));"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg