SVerweis mit mehreren Ergebnissen

[loserand]

Hallo zusammen,

Vielleicht kann mir einer da helfen, da wäre ich froh darüber.

Es geht um folgendes:
Die SVERWEIS-Funktion liefert bekanntermaßen zu einem Suchkriterium in der einen Tabelle den ersten gefundenen Treffer aus einer anderen Tabelle zurück. Was macht man aber, wenn der gesuchte Wert mehrmals vorkommt und man gerne alle Ergebnisse angezeigt bekommen möchte? Ausserdem möchte ich die Ergebnisse zusammen gezählt bekommen sowie mit einer WENN Funktion verknüpfen.



Beispiel im Anhang!



Es soll mir nun für das Suchkiterium A alle Werte der Spalte C zusammen addieren, jedoch nur wenn der Wert der Spalte B kleiner als 6 ist.

Das entspricht demnach: 10 + 25 = 35


Vielen Dank im Voraus!

[LCohen]

Die diesbezüglichen Klimmzüge in alten Excels sind beendet.

Auflistung: =FILTER(A1:C6;(A1:A6="A")*(B1:B6<6))

Summe: =SUMME(INDEX(FILTER(A1:C6;(A1:A6="A")*(B1:B6<6));;3))

[Raoul21]

Wenn Du alle zutreffenden Zeilen sehen möchstest, kannst Du mit Filter bestimmte Kriterien erstellen.

Zuerst eine Kopfzeile mit Spaltenbeschriftungen oben einfügen, dann daraus mit Strg+T eine  "intelligente Tabelle" machen. Damit sind die Filterfunktionen aktiv.

Anders geht es auch mit "Erweitert Filtern" im Daten-Menü.

Zur direkten Berechnung der Summe kannst Du die Funktion SUMMENPRODUKT verwenden. Sie berechnet, wie der Name vermuten läßt, eine Produktsumme, also wie der Name sagt, die Summe von Produkten.

Die Formel lautet:
=SUMMENPRODUKT(C1:C6*(A1:A6="A")*(B1:B6<6))

Die Produkte werden zeilenweise gebildet und bestehen aus den drei Faktoren:

1. Zahl in Spalte C,
   
2. 1 für zutreffendes Kriterium "A" in Spalte A, oder 0 wenn nicht.
   
3. 1 für zutreffendes Kriterium <6 in Spalte B, oder 0 wenn nicht.
   

Nur wenn keiner dieser Faktor 0 ist, wird der Wert aus Spalte C zum Summanden seiner Zeile.

Raoul

[loserand]

Vielen Dank für Eure schnelle Antworten. Ihr habt mir sehr geholfen!
Immer wieder schön, wenn jemanden so schnell geholfen wird.

Wünsche Euch noch ein sonniges Wochenende!


Grüsse

[LCohen]

Die gefilterte oder ungefilterte Summe zu Raoul21s intelligenter Tabelle:

=TEILERGEBNIS(9;Tabelle1[[#Kopfzeilen];[#Daten];[Spalte3]])

Dann kann man den händisch eingestellten Filter nutzen, statt ihn ein zweites Mal zu formulieren.

Das geht übrigens auch zu meiner Lösung (dynamische Auflistung), die bspw. in Zelle E1 beginnt:

G7: =SUMME(INDEX(E1#;;3))

[Raoul21]

Freut mich, dass ich helfen konnte. Danke für die Rückmeldung.
Alles Gute, Raoul