Schichtplanung

[SastaMa]

Guten Tag zusammen.

Ich habe ein Problem mit einer EXCEL - Tabelle.
Ich würde gerne in einer Tabelle nach 3 Kriterien suchen und das Ergebnis dann anzeigen lassen.
Die 3 Suchkriterien ( Schichtfarbe, KW, Jahr) werden in den Feldern M3 bis O3 eingegeben. In dem Feld Q7 soll dann angezeigt werden welchen Dienst man an den Tagen der KW am besten sogar mit Datumsanzeige hat.
Ich hoffe das mir bei diesem Problem jemand helfen kann.

Dies ist mein Versuch, der leider nicht funktioniert.

=WENN(M3="Gelb";(VERWEIS(UND(N3;O3);UND(N8:N22;O8:O22);D8:D22));"Bitte Auswahl treffen")

Vielen Dank schonmal im voraus.

[shift-del]

Hallo

Leider hast du nicht dazu geschrieben wie das Wunschergebnis aussehen soll denn es gibt mehrere Treffer.

Code:

=INDEX($D$8:$L$29;AGGREGAT(15;6;ZEILE($A$8:$A$29)/($N$8:$N$29=N3)/($O$8:$O$29=O3);1);VERGLEICH($M$3;$C$7:$K$7;0))

[Jockel]

Hallo Detlef, hast du dir die Datei angesehen..? In O stehen Datumswerte..!!! In N stimmen die KW's nicht und zudem stehen sie (die falschen KW's in verbundenen Zellen..)

Ich würde so tun..:

Aber +++ 8-ung +++ Version 2007 deswegen kein Vorschlag für den TE...

Arbeitsblatt mit dem Namen 'Tabelle1'
	O	P	Q	R
2		Suche
3		Grün	1	2017
4
5
6	Jahr		Ausgabe
7
8	2017	52		Spät
9	2017	1		Spät
10	2017	1		Spät
11	2017	1		Nacht
12	2017	1		Nacht
13	2017	1		Nacht
14	2017	1		Nacht
15	2017	1
16	2017	2
17	2017	2
18	2017	2
19	2017	2
20	2017	2
21	2017	2
22	2017	2
23	2017	3
24	2017	3
25	2017	3
26	2017	3
27	2017	3
28	2017	3
29	2017	3

Zelle	Format	Wert
O8	JJJJ	01.01.2017

Zelle	Formel
P8	=KALENDERWOCHE(A8;21)
R8	=WENNFEHLER(INDEX($C$8:$L$29;AGGREGAT(15;6;ZEILE($A$8:$A$29)-7/($P$8:$P$29=$Q$3)/(JAHR($O$8:$O$29)=$R$3);ZEILE(A1));VERGLEICH($P$3;$C$7:$L$7;0)+1);"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo, für 2007 dann so..:

Arbeitsblatt mit dem Namen 'Tabelle1 (2)'
	O	P	Q	R
3		Blau	3	2017
4
5
6	Jahr		Ausgabe
7
8	2017	52		Spät
9	2017	1		Spät
10	2017	1		Spät
11	2017	1		Nacht
12	2017	1		Nacht
13	2017	1		Nacht
14	2017	1		Nacht
15	2017	1
16	2017	2
17	2017	2
18	2017	2
19	2017	2
20	2017	2
21	2017	2
22	2017	2
23	2017	3
24	2017	3
25	2017	3
26	2017	3
27	2017	3
28	2017	3
29	2017	3

Zelle	Format	Wert
O8	JJJJ	01.01.2017

Zelle	Formel
P8	=KÜRZEN((A8-DATUM(JAHR(A8+3-REST(A8-2;7));1;REST(A8-2;7)-9))/7)
R8	{=WENNFEHLER(INDEX($C$8:$L$29;KKLEINSTE(WENN((JAHR($O$8:$O$29)=$R$3)*($P$8:$P$29=$Q$3);ZEILE($A$8:$A$29)-7);ZEILE(A1));VERGLEICH($P$3;$C$7:$L$7;0)+1);"")}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[shift-del]

Danke für den Hinweis, Jörg.
Ich habe mal wieder vergessen darauf hinzuweisen dass ich die Daten "verbessert" habe.
Keine verbundenen Zellen.
Kalenderwoche wird mit ISOKALENDERWOCHE(Datum) für jede Zeile ermittelt.
Jahr wird mit JAHR(Datum) für jede Zeile ermittelt und nicht mit Zahlenformat JJJJ dargestellt.

Und die Excel-Version 2007 habe ich auch wieder übersehen.

[SastaMa]

Hallo,
vielen Dank für eure Antworten, aber leider funktioniert es nicht.
Bei dem Versuch von Shift-del passiert leider garnichts.
Bei Jockel seiner Formel schreibt er mir zwar Schichten dahin, aber leider nicht die richtigen.

[Jockel]

Hallo, das würde ich gern sehen... warum das bei shift-del's Vorschlag nicht stimmt haben wir beide ja geschrieben, aber meiner sollte klappen...

[SastaMa]

Hallo,
hier sende ich nochmals meine Datei.
Vielleicht habe ich auch nur eine Formatierung oder etwas anderes falsch gemacht.
Gruß Marco

[BoskoBiati]

Hi,

ich würde das so angehen:

Arbeitsblatt mit dem Namen 'Tabelle1'
	P	Q	R
1
2	Suche
3	Blau	3	2017
4
5
6		Ausgabe
7
8	16.01.17		Spät
9	17.01.17		Spät
10	18.01.17		Spät
11	19.01.17		Nacht
12	20.01.17		Nacht
13	21.01.17		Nacht
14	22.01.17		Nacht

Zelle	Formel
P8	=7*KÜRZEN((2&-1&-$R$3)/7+$Q$3)-6+ZEILE(A1)
R8	=SVERWEIS(P8;$A:$L;VERGLEICH($P$3;$A$7:$L$7;0)+1;0)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[SastaMa]

Hallo Bosko Biati,

genau das habe ich gesucht. 
Vielen Dank