Schwierigkeiten bei der Zählenwenns-Funktion²

[Al Swearengen]

Hallo erstmal!

Da bin ich wieder mit meiner Fußballliste.

Ich stoße wieder einmal auf Schwierigkeiten mit der Zählenwenns-Funktion. Diesesmal möchte ich, daß mir Excel anzeigt, wie oft an einem bestimmten Datum Bayer 04 Leverkusen zuhause (oder auch auswärts) gewonnen, unentschieden oder verloren hat. Und das mit der bestimmte Funktion.
Jedoch bekomme ich das mit dem Datum nicht hin. Wichtig ist nur der Tag und der Monat. Dafür das Tabellenblatt "Kalender²". Ich versuchte schon die Formel

=ZÄHLENWENNS('alle Spiele'!$B$3:$B$1366;"12.01.";'alle Spiele'!$H$3:$H$1366;"s") ("s" für Heimsieg)

und als Variation das Datum ohne Anführungsstriche, aber entweder bekomme ich eine Fehlermeldung oder aber eine 0 als Ergebnis angezeigt. Ich habe zur Kontrolle, weil ich anhand der Eingaben sehen kann, daß sie halt an dem Tag verloren haben, das "s" gegen ein "v" ausgetauscht, aber auch da kam nur die 0 als Ergebnis.

Ich gehe davon aus, daß ich das Datum irgendwie anders eingeben muß, bin aber jetzt erstmal überfragt.

Kann mir da jemand einen Hinweis geben, wie ich das Datum richtig einzugeben habe?

[WillWissen]

Hallo Al,

etwas gedankenlos heute?

1. deine Beispieltabelle verweist auf eine andere Tabelle, die nicht vorliegt
2. was soll das geschützte Arbeitsblatt?
3. was soll eine Beispieltabelle mit weit über 1000 Datensätzen?
4. kann ich anhand deiner "Beispiel"tabelle nicht erkennen, wo du was warum geschrieben haben willst

[Steffl]

Hallo Günter,

der TE will wissen, wie oft Bayer Leverkusen an einem 12.01 (unabhängig vom Jahr) gewonnen, verloren und unentschieden gespielt hat.

[Cadmus]

Nimm Summenprodukt. Für die erste Zeile:

Arbeitsblatt mit dem Namen 'Kalender²'
	B	C	D	E	F	G	H
2	Januar
3		H			A
4		g	u	v	g	u	v
5	1	0	0	0

Zelle	Formel
C5	=SUMMENPRODUKT((MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="s"))
D5	=SUMMENPRODUKT((MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="u"))
E5	=SUMMENPRODUKT((MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="n"))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[LCohen]

Kristallkugel-Statistik ;)

[Al Swearengen]

Vielen Dank für die Formeln, Cadmus!

Ich habe sie eingesetzt in meine Tabelle und - natürlich - funktioniert sie einwandfrei.

Dann habe ich sie auch für die Auswärtsspiele benutzt...und da funktioniert sie nicht. Da zeigt sie das gleiche an wie für die Heimspiele. 
Dann habe ich es mit

=WENN('alle Spiele'!$G$3:$G$1346="Bayer 04 Leverkusen";SUMMENPRODUKT((MONAT('alle Spiele'!$B$3:$B$1346)=1)*(TAG('alle Spiele'!$B$3:$B$1346)=$B5)*('alle Spiele'!$H$3:$H$1346="S")))

versucht, allerdings schmeißt mir dann Excel in jeder 2. Zeile ab F4 eine Fehlermeldung raus. Hast du eine Idee, wie ich das geregelt bekomme?

[Cadmus]

Einfach das Summenprodukt erweitern.
Der erste Teil muss auch noch um die Heimspiele erweitert werden.

Arbeitsblatt mit dem Namen 'Kalender²'
	B	C	D	E	F	G	H
2	Januar
3		H			A
4		g	u	v	g	u	v
5	1	0	0	0	0	0	0

Zelle	Formel
C5	=SUMMENPRODUKT(('alle Spiele'!$C$3:$C$1400="Bayer 04 Leverkusen")*(MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="s"))
D5	=SUMMENPRODUKT(('alle Spiele'!$C$3:$C$1400="Bayer 04 Leverkusen")*(MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="u"))
E5	=SUMMENPRODUKT(('alle Spiele'!$C$3:$C$1400="Bayer 04 Leverkusen")*(MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="n"))
F5	=SUMMENPRODUKT(('alle Spiele'!$G$3:$G$1400="Bayer 04 Leverkusen")*(MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="s"))
G5	=SUMMENPRODUKT(('alle Spiele'!$G$3:$G$1400="Bayer 04 Leverkusen")*(MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="u"))
H5	=SUMMENPRODUKT(('alle Spiele'!$G$3:$G$1400="Bayer 04 Leverkusen")*(MONAT('alle Spiele'!$B$3:$B$1400)=1)*(TAG('alle Spiele'!$B$3:$B$1400)=$B5)*('alle Spiele'!$H$3:$H$1400="n"))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Al Swearengen]

Lieber Cadmus!

Super! Vielen Dank für die Formeln, die hauen wunderbar hin!

Schön' Sonntag noch!