Scrollbare Tabelle o. Spalten einfügen und WENN

[DerBeny]

Hallo Leute, 
 
Ich habe 2 Sachen und stehe völlig auf dem Schlauch:
Erste Sache: MAPPE 1
 
Ich möchte entweder im orangenen Bereich eine scrollbare Liste mit bis zu 100 Positionen haben in der ich auch Daten eintragen kann und mit dem scrollen verschoben werden.
Mit bereich.verschieben klappt das nur bedingt, eingetragene Werte im scrollbereich bleiben einfach stehen.
ODER
nach der #10 möchte ich per Button eine weitere Spalte mit denselben Formatierungen/Regeln erscheinen lassen und zwar dann so viele wie benötigt werden.
 
 
Zweite Sache: MAPPE 2
 
Ich möchte eine WENN Funktion.
Und zwar, wenn in der Zelle das Plus-Minus Symbol steht, soll der Wert mit dem Toleranzwert in einer Zelle Addiert, in der anderen Subtrahiert werden.
Befindet sich in der Zelle aber kein Plus-Minus Zeichen, sondern nur ein Plus Zeichen, dann soll der Wert mit dem Toleranzwert in einer Zelle addiert werden, in der anderen Zelle nichts, also "0" addiert werden.
Spiegelbildlich soll es dann passieren, mit einem Minus Zeichen.
 
Habe ich mich verständlich genug ausgedrückt?
 
Ich hoffe, ihr könnt mir helfen!
 
Danke!!!

[MisterBurns]

Ad Zweite Mappe:

Code:

E6: =B6+D6*(ODER(C6="+";C6="±"))
F6: =B6-D6*(ODER(C6="-";C6="±"))

[DerBeny]

Ja super, das mit der Formel bezüglich der Vorzeichen funktioniert super!

Jetzt nur noch sie Sache mit der Scrollbaren Tabelle ofer der Erweiterung :)

[Fred11]

Hallo DerBeny,

zu deinem Punkt 1:

Also dass man auf einem Tabellenblatt zusätzlich zu den beiden Standard- Scroll-Leisten rechts am Rand und unten nochmal einen Teilbereich des Tabellenblattes scrollen kann, ist in Excel so eigentlich nicht vorgesehen.

Mit ein wenig Bastelei läßt sich das aber mit Formeln realisieren
Siehe hier:
https://trumpexcel.com/create-a-scroll-bar-in-excel/

In der "Scroll-Liste" kannst du aber nicht direkt was eintragen, da sind ja überall Formeln drin, die ist nur zum anschauen/visualisieren der Werte.
Die eigentlichen (Roh-) Daten müssen in einer separaten Tabelle abgelegt sein…
Ist es das was du möchtest ?

Ansonsten:
Fesnster fixieren
Zelle G6 selektieren und dann  ==> Ansicht ==> Fenster einfrieren


Oder
Fenster Teilen
==> Ansicht ==> Fenster teilen

Da kannst du dann gleichzeitig/parallel auf verschiedene (weit auseinanderliegende) Bereiche deines Tabellenblattes schauen und separat scrollen
(Ich persönlich finde das aber etwas fummelig und benutze das eher selten...)


Und mit ein bisschen VBA z.B. per Klick auf einen Button eine gewsse Anzahl an Spalte einfügen, geht natürlich auch…..

Zum Beispiel so:

PHP-Code:

Sub Spalten_einfügen()

    Dim AnzahlSpalten As Integer
    
    'Abfrage, wieviel Spalten eingefügt werden sollen
    AnzahlSpalten = Application.InputBox("wieviel Spalten sollen eingefügt werden ?", "Spalten einfügen", Type:=1)
    If AnzahlSpalten = 0 Then Exit Sub
    
    'Spalten einfügen rechts von Spalte P
    Range(Columns(17), Columns(17 + AnzahlSpalten - 1)).Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove

End Sub 


Gruß
Fred

[DerBeny]

Hallo Fred,

das mit der Scroll Liste ist dann doch nichts mehr für mich. Schade.

Mit dem fixieren auch nicht.

ABER 

Das mit dem VBA finde ich super!

2 Anmerkungen:
Ist es möglich, dass nach drücken des Buttons eine Anzahl von X Spalten eingefügt wird, wie in H2 manuell eingetragen wird?
Und dass die Nummerierung #11......automatisch weitergeführt wird? Dann ist das genau das, was ich suche!


DANKE!

[Fred11]

Halle DerBeny,

Ich habe in deiner Tabelle („MAPPE 1“) ganz oben eine zusätzliche Zeile eingefügt.
In Zelle H1 steht die Anzahl der einzufügenden Spalten - siehe angehängte Datei

Der VBA-Code ermittelt die letzte benutzte Spalte in Zeile 7 und fügt dahinter die in Zelle H1 angegebene Anzahl an Spalten hinzu.

Code:

Sub Spalten_einfügen()
   
    Const ZeileNummerierung As Integer = 7  'Zeilennummer der Kopfzeile mit der fortlaufenden Nummerierung
   
    Dim i As Integer
    Dim AnzahlSpalten As Integer
    Dim abSpalte As Integer
   
    On Error GoTo Fehler
   
    AnzahlSpalten = Range("H1").Value
    If AnzahlSpalten = 0 Then Exit Sub
   
    abSpalte = Cells(ZeileNummerierung, Columns.Count).End(xlToLeft).Column 'letzte ausgefüllte Spalte in Zeile 7 ermitteln
   
    'Spalten einfügen rechts von der angegebenen Spalte
    Range(Columns(abSpalte + 1), Columns(abSpalte + AnzahlSpalten)).Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove
   
    'in der Kopfzeile Nummerierung eintragen und Format anpassen
    For i = 1 To AnzahlSpalten
        Cells(ZeileNummerierung, abSpalte + i).Value = Cells(ZeileNummerierung, abSpalte + i - 1).Value + 1
       
        Cells(ZeileNummerierung, abSpalte + i - 1).Copy
        Cells(ZeileNummerierung, abSpalte + i).PasteSpecial Paste:=xlPasteFormats
        Application.CutCopyMode = False
    Next i
   
   
    Exit Sub
   
Fehler:
    MsgBox "Spalten einfügen nicht möglich"

End Sub

Dieses Makro kannst du jetzt noch einem Button zuweisen.

Gruß
Fred

[DerBeny]

Ja Krass, das isses! TAUSEND DANK!

Jetzt fehlt nur noch eine kleine Spielerei, dafür öffne ich aber einen neuen Thread.

Dieses Thema markiere ich als erledigt. TOP!