Selection

[Nora Fernandez]

Hallo liebe Experten,

ich brauch mal wieder eure Hilfe. Wenn ich auf  einem Tabellenblatt
mit der Maus ein Gebiet von Zellen ausgewählt habe, wie schaffe ich
es dann mittels VBA Code folgende Eigenschaften dieser Zellenauswahl
zu bestimmen:

1. Anzahl der ausgewählten Zeilen
2. Anzahl der ausgewählten Spalten
3. Zelladresse der linken/rechten oberen Zelle
4. Zelladresse der linken/rechten unteren Zelle


Vielen Dank schon mal für eure Hilfe im voraus.

Nora

[Kuwer]

Hallo Nora,

Sub SelectionEigenschaften()
  With Selection
    MsgBox "Zellen: " & .Cells.Count & vbNewLine & _
           "Spalten: " & .Columns.Count & vbNewLine & _
           "Adresse LO: " & .Cells(1).Address(0, 0) & vbNewLine & _
           "Adresse RO: " & Application.Intersect(.Rows(1).EntireRow, .Columns(.Columns.Count).EntireColumn).Address(0, 0) & vbNewLine & _
           "Adresse LU: " & Application.Intersect(.Rows(.Rows.Count).EntireRow, .Columns(1).EntireColumn).Address(0, 0) & vbNewLine & _
           "Adresse RU: " & .Cells(.Cells.Count).Address(0, 0)
  End With
End Sub

Gruß Uwe

[RPP63]

Hi!
Nur ergänzend:
Bei RO und LU gehts etwas kürzer.
(ist zwar eher akademisch, aber egal   )

Sub Auswahl()
With Selection
   MsgBox _
      "Zellen: " & .Cells.Count & vbNewLine & _
      "Spalten: " & .Columns.Count & vbNewLine & _
      "Adresse LO: " & .Cells(1).Address(0, 0) & vbNewLine & _
      "Adresse RO: " & .Cells(1, .Columns.Count).Address(0, 0) & vbNewLine & _
      "Adresse LU: " & .Cells(.Rows.Count, 1).Address(0, 0) & vbNewLine & _
      "Adresse RU: " & .Cells(.Cells.Count).Address(0, 0)
End With
End Sub

Gruß Ralf

[Rabe]

Hi,

ich denke, eher so:

Sub Auswahl_Zell_Adressen()            'zeigt die Anzahl der Zeilen und Spalten, sowie die 4 Eckzellen an 
 With Selection
   MsgBox "Zellen: " & .Rows.Count & vbNewLine & _
          "Spalten: " & .Columns.Count & vbNewLine & _
          "Adresse LO: " & .Cells(1).Address(0, 0) & vbNewLine & _
          "Adresse RO: " & Application.Intersect(.Rows(1).EntireRow, .Columns(.Columns.Count).EntireColumn).Address(0, 0) & vbNewLine & _
          "Adresse LU: " & Application.Intersect(.Rows(.Rows.Count).EntireRow, .Columns(1).EntireColumn).Address(0, 0) & vbNewLine & _
          "Adresse RU: " & .Cells(.Cells.Count).Address(0, 0)
 End With
End Sub

VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media
Code erstellt und getestet in Office 15 - mit VBAHTML 12.6.0

[RPP63]

Hi!
Stimmt!
Vielleicht gibt es zu Weihnachten eine neue Brille …

1. Anzahl der ausgewählten Zeilen

Aber meine Verkürzung steht.  :05:
Und Du hättest dann ruhig auch den Text der MsgBox ändern können.  :21:

Gruß Ralf

[chris-ka]

Hello,

  Also bei mir kommt immer ein LFZ wenn ich das ganze Blatt markiert habe. ;)

@Nora
Was willst du damit machen?
Ich wette mal 1 Zuckerstange und eine Christbaumkugel das dies gleich mit einem Object funktioniert ohne jetzt separat welche Zellen auszulesen.

lg
Chris

[Steffl]

Hallo Chris,

  Also bei mir kommt immer ein LFZ wenn ich das ganze Blatt markiert habe. ;)

Excel hat seit 2007 mehr als 2.147.483.647 Zellen und die Count-Eigenschaft gibt einen Typ Long zurück und somit liegt es drüber.

[Rabe]

Hi Chris,

Und Du hättest dann ruhig auch den Text der MsgBox ändern können.  :21:

hab ich auch übersehen.

[Kuwer]

Hallo Zusammen,

da stand ich aber gewaltig auf der Leitung. Nun hab ich es auch verstanden mit Zeilen und Zellen.  :19:
Nun mit allen Verbesserungen und ohne Fehler:

Sub Auswahl_Zell_Adressen()  'zeigt die Anzahl der Zeilen und Spalten, sowie die 4 Eckzellen an
 With Selection
   MsgBox "Zeilen: " & .Rows.Count & vbNewLine & _
          "Spalten: " & .Columns.Count & vbNewLine & _
          "Adresse LO: " & .Cells(1).Address(0, 0) & vbNewLine & _
          "Adresse RO: " & .Cells(1, .Columns.Count).Address(0, 0) & vbNewLine & _
          "Adresse LU: " & .Cells(.Rows.Count, 1).Address(0, 0) & vbNewLine & _
          "Adresse RU: " & .Cells(.Rows.Count, .Columns.Count).Address(0, 0)
 End With
End Sub

Gruß Uwe

[schauan]

Hallöchen,

hier mal noch, auch wenn es nicht gefragt war ,  der Ansatz zur Ermittlung der Anzahl ausgewählter Zellen

Code:

Sub Makro1()
'Variablendeklarationen
'Hinweis: rngArea nicht als Range dimensionieren!
Dim dCellCnt As Double, rngArea As Object
'Als Beispiel alle Zellen selectieren
Cells.Select
'Schleife ueber alle gewaehlten Bereiche
For Each rngArea In Selection.Areas
  'gewaehlte Zellen im Area zaehlen
   dCellCnt = dCellCnt + rngArea.Rows.Count * rngArea.Columns.Count
'Ende Schleife ueber alle gewaehlten Bereiche
Next
'Ergebnis ausgeben
MsgBox dCellCnt
End Sub