Seriennummer ergänzen

[schachi85]

Hallo zusammen,

Ich wollte hier etwas nach fragen und hoffe hier sind Experten die mir eventuell helfen können!
Und zwar bekomme ich folgendes nicht hin:

Die Serien Nr. soll wie folgt erstellt werden:

z.B. Auftrag B2 (8001166) Teile-Nr. (nur der Zahlenwert) E2 (280) Typ (nur der Zahlenwert) F2 (400) Baujahr (nur die letzten beiden Ziffern) H2 (17).
Seriennummer => 800116628040017
Aber, die Formel sollte berücksichtigen, das wenn zwei gleiche Auftragsnummer, gleichzeitig aber auch Teile-Nr. und der Typ gleich sind noch eine -1,-2 usw. (siehe Bild) einfügt.

Ich bin für alle Vorschläge offen und hoffe auf ein positives Feedback eurer seits.

Liebe Grüße 
schachi85

[Zwergel]

Hi,
schau mal ob es so paßt bei dir:


Tabelle1

	A	B	C	D	E	F	G	H	I	J
1	Pos	Auftrag	Kunde	Kundennummer	Teile-Nr	Typ	Gewicht	Baujahr	Seriennummer	Seriennummer
2	1	8001166			KSM-280	KSM-AV400 RD	75 kg	2017	800116628040017	800116628040017-1
3	2	8001166			KSM-280	KSM-AV400 RD	75 kg	2017	800116628040017	800116628040017-2
4	3	5165465			KSM-280	KSM-AV400 RD	75 kg	2017	516546528040017	516546528040017-1
5	4	5465214			KSM-280	KSM-AV400 RD	75 kg	2017	546521428040017	546521428040017-1
6	5	5465214			KSM-280	KSM-AV400 RD	75 kg	2017	546521428040017	546521428040017-2
7	6	1546554			KSM-280	KSM-AV400 RD	75 kg	2017	154655428040017	154655428040017-1
8	7	2588416			KSM-280	KSM-AV400 RD	75 kg	2017	258841628040017	258841628040017-1

verwendete Formeln
Zelle	Formel	Bereich	N/A
I2:I8	=B2&RECHTS(E2;3)&TEIL(F2;7;3)&RECHTS(H2;2)
J2:J8	=I2&"-"&ZÄHLENWENN(I$2:I2;I2)

Excel-Inn.deHajo-Excel.deXHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 Add-In-Version 22.01 einschl. 64 Bit


Hilfsspalte I kann ausgeblendet werden.

Sollten die Teile-Nr oder Typ auch anders aussehen, dann müßte die Formel geändert werden. Geht sicher auch einfacher, aber dazui fehlt mir leider das Wissen.

[Jockel]

Hallo, für I2 evtl. ..:

Code:

=B2&RECHTS(E2;3)&TEIL(F2;7;3)&RECHTS(H2;2)&"-"&ZÄHLENWENNS($B$2:B2;B2;$E$2:E2;E2;$F$2:F2;F2;$G$2:G2;G2;$H$2:H2;H2)

[Zwergel]

Hi Jörg,

auch netter Ansatz, aber was mir beim nochmaligen Lesen der Fragestellung auffiel: Die Ergänzung mit - und lfd. Nummer soll nur bei mehrmaligem Auftreten angefügt werden. Also bei den Positionen 3, 6 und 7 dürfte nix angefügt werden. Da fällt mir grad nix zu ein.

[schachi85]

Hallo zusammen,

vielen dank für eure mühe.
Wie Michael schon schrieb, soll Excel nur die Erweiterung (Aufzählung) schreiben wenn die Auftragsnummern gleich sind.

Kann mann da was machen?

vielen dank

[Palomino]

Wenn ichs richtig verstanden habe dann ergänze die Formel in J2 um

=WENN(ZÄHLENWENN(B:B;B2)>1;I2&"-"&ZÄHLENWENN(I$2:I2;I2);I2)

Damit sollte nur bei den Werten die Unterteilung erfolgen deren Seriennummer doppelt sind

[schachi85]

bekomme ich leider nicht damit hin

[RPP63]

Moin!
I2:J2 nach unten ziehen:

	A	B	C	D	E	F	G	H	I	J
1	A	B	C	D	E	F	G	H	Hilfsspalte	J
2	1	8001166			KSM-280	KSM-AV400 RD	75 kg	2017	800116628040017	800116628040017-1
3	2	8001166			KSM-280	KSM-AV400 RD	75 kg	2017	800116628040017	800116628040017-2
4	3	5165465			KSM-280	KSM-AV400 RD	75 kg	2017	516546528040017	516546528040017
5	4	5465214			KSM-280	KSM-AV400 RD	75 kg	2017	546521428040017	546521428040017-1
6	5	5465214			KSM-280	KSM-AV400 RD	75 kg	2017	546521428040017	546521428040017-2
7	6	1546554			KSM-280	KSM-AV400 RD	75 kg	2017	154655428040017	154655428040017
8	7	2588416			KSM-280	KSM-AV400 RD	75 kg	2017	258841628040017	258841628040017

Formeln der Tabelle

Zelle Formel I2 =B2&RECHTS(E2;3)&TEIL(F2;7;3)&RECHTS(H2;2) J2 =I2&WENN(ZÄHLENWENN(I:I;I2)>1;"-"&ZÄHLENWENN(I$2:I2;I2);"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Ralf

[Zwergel]

Auch die Formel von Palomino funktioniert, ist eben nur anders aufgebaut als die von RPP63


Tabelle1

	A	B	C	D	E	F	G	H	I	J
1	Pos	Auftrag	Kunde	Kundennummer	Teile-Nr	Typ	Gewicht	Baujahr	Seriennummer	Seriennummer
2	1	8001166			KSM-280	KSM-AV400 RD	75 kg	2017	800116628040017	800116628040017-1
3	2	8001166			KSM-280	KSM-AV400 RD	75 kg	2017	800116628040017	800116628040017-2
4	3	5165465			KSM-280	KSM-AV400 RD	75 kg	2017	516546528040017	516546528040017
5	4	5465214			KSM-280	KSM-AV400 RD	75 kg	2017	546521428040017	546521428040017-1
6	5	5465214			KSM-280	KSM-AV400 RD	75 kg	2017	546521428040017	546521428040017-2
7	6	1546554			KSM-280	KSM-AV400 RD	75 kg	2017	154655428040017	154655428040017
8	7	2588416			KSM-280	KSM-AV400 RD	75 kg	2017	258841628040017	258841628040017

verwendete Formeln
Zelle	Formel	Bereich	N/A
I2:I8	=B2&RECHTS(E2;3)&TEIL(F2;7;3)&RECHTS(H2;2)
J2:J8	=WENN(ZÄHLENWENN(B:B;B2)>1;I2&"-"&ZÄHLENWENN(I$2:I2;I2);I2)

Excel-Inn.deHajo-Excel.deXHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007 Add-In-Version 22.01 einschl. 64 Bit

[RPP63]

Hi Michael!
Aus der Threaderöffnung:

Aber, die Formel sollte berücksichtigen, das wenn zwei gleiche Auftragsnummer, gleichzeitig aber auch Teile-Nr. und der Typ gleich sind

Daher sollte schon auf I:I und nicht auf B:B geprüft werden.
Allgemeiner Hinweis:
Ich weiß nicht, wie groß die Tabelle ist.
Da die Formeln aber sehr rechenintensiv sind, würde ich Spalte J kopieren, als Wert einfügen und danach die Hilfsspalte löschen.

Gruß Ralf