Sicherheitskopien für Excel-Dateien als Add-In

[sotaros]

Hallo liebe VBA Experten,

ich habe folgendes Problem. Ich habe ein kleines (funktionierendes) VBA Programm geschrieben, welches
Sicherheitskopien meiner jeweils gerade verwendeten Datei auf dem Laufwerk F ablegt und mit Datum und Uhrzeit versieht. So weit so gut, keine Probleme. Ich möchte aber dieses Programm als Add-In für Excel haben. So bald ich dies alles dann als Add-In installiert habe, bekomme ich als Sicherheitskopie aber nur die Kopie meiner installierten Add-In Datei. Wie muss ich den Code unten programmieren, damit ich über das Add-In für jede beliebige gerade verwendete Excel Datei die gewünschte Sicherheitskopie bekomme?

Vielen Dank im voraus für eure Bemühungen


Sub Sicherheitskopie()
On Error Resume Next
Dim myFSO As Object
Dim qFolder As String, tFolder As String

Set myFSO = CreateObject("Scripting.FileSystemObject")

ThisWorkbook.Save

'Verzeichnis anlegen falls nicht vorhanden
If Dir("F:\0000 Backup\") = "" Then MkDir ("F:\0000 Backup\")

tFolder = "F:\0000 Backup\"

qziel = Date & "-" & Replace(Time, ":", ".") & " " & ThisWorkbook.Name

myFSO.CopyFile ThisWorkbook.FullName, tFolder & qziel, True

End Sub

[Kuwer]

Hallo,

Du musst Dich auf das aktive Workbook beziehen:

Code:

Sub Sicherheitskopie()
  Dim tFolder As String
  
  On Error Resume Next
  'Verzeichnis anlegen falls nicht vorhanden
  tFolder = "F:\0000 Backup\"
  If Dir(tFolder) = "" Then MkDir tFolder
  
  ActiveWorkbook.Save
  ActiveWorkbook.SaveCopyAs tFolder & Format(Now, "dd.mm.yyyy-hh.nn.ss ") & ActiveWorkbook.Name
End Sub

Gruß Uwe

[sotaros]

Hallo Uwe,

danke für die schnelle und tolle Hilfe. Funktioniert super!!