Sortierproblem

[EA1950]

Hallo,

in der beiliegenden Datei habe ich in Zelle 'Tabelle1(2)'!E1 folgende Sortierformel eingebaut.
Sie sortiert die Spalte A zusammen mit Spalte B nach dem korrekten Von-Datum, ausgehend vom jeweiligen Bis-Datum.

Code:

=LET(
    daten; $A$1:$B$178;
    intv; SPALTENWAHL(daten; 1);
    txtv; TEXTVOR(intv; "-");
    datb; --TEXTNACH(intv; "-");
    datjb; JAHR(datb);
    dat1v; --(txtv & datjb);
    dat2v; --(txtv & (datjb - 1));
    datv; WENN(dat1v > datb; dat2v; dat1v);
    SORTIERENNACH(daten; datv; 1; datb; 1)
)

[theTroother]

Hi!

folgendes wurde an die - laut Impresum  verantwortliche Person per PN gesandt!
_______________

Hallo!

nur als ein Beispiel, von unzählig möglichen...

https://www.clever-excel-forum.de/Thread-Sortierproblem--41296

Wenn ich der Threaderstelle wäre, käme ich mir "verars..." vor...
Das geht freundicher und vor allem zielorientierter...!

Es sind - leider - immer - dieselben,  egal ob bereits nicht mehr vorhandene Foren betreffend "Excel",  dieses oder Andere, die noch aktiv sind.

Ich hatte mich - hier - angemeldet, da mir in diversen Foren viel geholfen wurde  und ich damit versuche da & dort - FREUNDLICH - zu helfen, mit meinen bescheidenen Kenntnissen.

Diese Art & Weise die ich viel zu oft - hier -  lese, die manche/etliche Forenteilnehmer leben stinkt, stinkt bis zum Himmel... -> und das ist enttäuschend!

*sorry*

NS: ich poste diese Nachricht mit der Info, dass ich dies an die zuständigen/verantwortlichen Person(en) geschrieben habe.
-> sollte ich damit Forenregeln damit verletzen, dann kann - ich(!) - damit leben.

[BoskoBiati]

Hi,

da würde auch das reichen:

Code:

=--(LINKS(A2;6)&RECHTS(A2;2))
=--RECHTS(A2;10)

@Anton,
weißt Du, ob der TE 365 hat? Ich sehe das nirgendwo.
Wenn ja, dann hätte ich auch noch was:

Code:

=LET(xa;A2:A179;
        xb;--(LINKS(xa;6)&RECHTS(xa;2));
          xc;--RECHTS(xa;10);
            SORTIERENNACH(HSTAPELN(xb;xc;B2:B179);xb;1))

[EA1950]

Hallo Edgar,

das Problem dabei ist natürlich, dass gewährleistet sein muss, dass das Von-Datum kleiner sein muss als das Bis-Datum.
z.B. Fall: 28.12.-02.01.2025
das muss der 28.12.2024-02.01.2025 sein und nicht 28.12.2025-02.01.2025

[Klaus-Dieter]

@ theTroother,

Hi!

folgendes wurde an die - laut Impresum  verantwortliche Person per PN gesandt!

den Rest des Zitats erspare ich mir und uns. Ergibt sich für mich die Frage: was ist dein Problem, bzw. was hast du denn geraucht?

[BoskoBiati]

Hi Anton,

ok, habe ich völlig übersehen.

Dann so:

Code:

=LET(xa;A2:A179;ya;RECHTS(xa;4);xb;--(TEXTVOR(xa;"-")&ya);xc;--TEXTNACH(xa;"-");xd;EDATUM(xb;0-12*(xb>xc));SORTIERENNACH(HSTAPELN(xd;xc;B2:B179);xb;1))

Allerdings funktioniert das Alles nur, wenn die Differenz zweier Datumswerte grundsätzlich <1Jahr ist.

[snb]

Verwende

=TEXT(--LEFT(A1;5);"yyyy-mm-dd") & " - " & TEXT(--RIGHT(A1;10);"yyyy-mm-dd")

für Deutschland:

=TEXT(--LEFT(A1;5);"JJJJ-MM-TT") & " - " & TEXT(--RIGHT(A1;10);"JJJJ-MM-TT")

Kannst du problemlos sortieren.

[EA1950]

Hallo @snb,

das ergibt aber auch wieder ein Problem:
z.B. 28.12.-07.01.2024 
ergibt bei dir: 2024-12-28 - 2024-01-07

[ws-53]

Hi Edgar,

bei deiner 2. Let werden zwar 04.05.23 - 15.04.24 und 28.12.23 - 07.01.24 richtig umgesetzt, aber falsch sortiert. Ebenso wird die Spalte B nicht passen zu Spalte A sortiert.

[ws-53]

Hallo Edgar,

bei der Sortierung nach "xd" anstatt nach "xb" stimmt das Ergebnis.

Aber ich habe nun auch verstanden, warum ich es viel zu umständlich angegangen bin! Wobei ich trotz allem nicht auf "EDATUM(xb;0-12*(xb>xc))" gekommen wäre.))"