Spalte mit Text nach Schlagworten durchsuchen

[Seenu]

Hallo zusammen,

ich möchte eine Spalte mit Texteinträgen (Verwendungszweck Kontoabbuchungen) nach bestimmten Schlagworten durchsuchen und im Falle eines Treffers einer Kategorie zuweisen. Bislang muss ich jedem Texteintrag manuell eine Kategorie zuweisen. Dies soll künftig automatisch geschehen, wenn ein bestimmtes Schlagwort in der Zelle mit dem Text gefunden wird. 

Meine konkrete Vorstellung:

1. In Tabelle 1, Spalte A habe ich die Texteinträge stehen. Da steht zum Beispiel "Vielen Dank für Ihren Einkauf bei REWE" oder "Fressnapf sagt Danke."
   
2. In Tabelle 2, Spalte A lege ich die Schlagworte an und weise ihnen in Tabelle 2, Spalte B eine Kategorie zu. Beispiele: REWE -> Lebensmittel, Aldi -> Lebensmittel, Fressnapf -> Tiernahrung, Obi -> Baumarkt
   
3. Excel soll nun prüfen, ob in den Texteinträgen von Tabelle 1, Spalte A eines der Schlagworte vorkommt. Wenn ja, dann soll in Tabelle 1 Spalte B die entsprechende Kategorie aufgeführt werden. Beispiel: Im Text  "Vielen Dank für Ihren Einkauf bei REWE" wird das Schlagwort "REWE" gefunden, weshalb die Kategorie Lebensmittel zugeordnet wird.
   

Anbei auch ein Screenshot zur Verdeutlichung.

Kann das mit möglichst einfachen Formeln ohne VBA umgesetzt werden?

Vielen Dank schon mal für eure Hilfe.

[Elex]

Hallo

https://www.clever-excel-forum.de/Thread...ht=verweis
oder
https://www.clever-excel-forum.de/Thread...ht=verweis

Gruß Elex

[Rabe]

Hi,

dasselbe habe ich auch.

Ich habe in meiner Übersichtsliste in Spalte D die "Auftraggeber/Empfänger" und in Spalte F die IBAN stehen.
In einem anderen Blatt habe ich die intelligente Tabelle "Kategorie mit den drei Spalten: Empfänger (IBAN), Auftraggeber und Kategorie.

Mit folgender Formel wird in Kategorie/Empfänger nach dem Begriff aus Spalte F gesucht und nach dem Begriff aus Spalte D in Kategorie/Auftraggeber und dann in der Zielzelle der Begriff aus Spalte Kategorie/Kategorie eingetragen, wenn nichts gefunden wurde wird "unklar" eingetragen.

Hier meine Formel:
=WENNFEHLER(VERWEIS(42;1/SUCHEN(Kategorie[Empfänger];F9)/SUCHEN(Kategorie[Auftraggeber];D9);Kategorie[Kategorie]);"unklar")


Meiner Meinung nach funktioniert es auch mit Teilbegriffen aus Spalte D.

Gruß Ralf

[Fred11]

... mit XVEREWIS geht's auch (bei passender Excel-Version - Excel 2021, Excel 365)

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D
1		VERWEIS-Spezial	XVERWEIS	INDEX/VERGLEICH
2	Verwendungszweck	Kategorie	Kategorie	Kategorie
3	Vielen Dank für ihren Einkauf bei Aldi	Kategorie A	Kategorie A	Kategorie A
4	Vielen Dank für ihren Einkauf bei Lidl	Kategorie D	Kategorie D	Kategorie D
5	Vielen Dank für ihren Einkauf bei Netto	#NV	#NV	#NV
6	Vielen Dank für ihren Einkauf bei Lidl	Kategorie D	Kategorie D	Kategorie D
7	Vielen Dank für ihren Einkauf bei Edeka	Kategorie B	Kategorie B	Kategorie B
8
9
10
11	Schlagwort	Kategorie
12	Ald	Kategorie A
13	Edeka	Kategorie B
14	Atu	Kategorie C
15	Lidl	Kategorie D
16	Penny	Kategorie E

Zelle	Formel
B3	=VERWEIS(2;1/ISTZAHL(SUCHEN($A$12:$A$16;A3));$B$12:$B$16)
C3	=XVERWEIS(WAHR;ISTZAHL(SUCHEN($A$12:$A$16;A3));$B$12:$B$16)
D3	=INDEX($B$12:$B$16;VERGLEICH(WAHR;ISTZAHL(SUCHEN($A$12:$A$16;A3));0))

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Gruß
Fred

[{Boris}]

Hi Ralf,

=WENNFEHLER(VERWEIS(42;1/SUCHEN(Kategorie[Empfänger];F9)/SUCHEN(Kategorie[Auftraggeber];D9);Kategorie[Kategorie]);"unklar")

Bin ganz Deiner Meinung

=TEXTKETTE(ZEICHEN({122;119;101;105;117;110;100;118;105;101;114;122;105;103}))

Muss das hier auch mal in meine Signatur einbinden

[Seenu]

Vielen lieben Dank an euch @Fredd11, Rabe und Elex. 
Das sind richtig gute Lösungen für mein Anliegen. 
Ich setze diese Thema damit auf erledigt.

Viele Grüße
Seenu