Standard in Datum formatieren

[Kaeffi]

Hallo zusammen,

ich hoffe ihr könnt mir helfen. In einer in Excel importierten Datei wurde das Datum leider als "Standard" eingefügt und wenn ich dies in "Datum" um wandle dann schmeißt er mir ein völlig falsches Ergebnis aus.

Leider sind die Tage u manchmal einstellig dargestellt, da Excel beim Import die erste 0 automatisch eingekürzt hat. Der Monat ist immer 2-stellig und das Jahr wird immer 4 stellig angezeigt.

Mit welcher Formel bekomme ich dieses Ergebnis?

2112012     = 21.12.2012
4032015     = 04.03.2015
10082012   = 10.08.2012

Vielen Dank im Voraus!
Kaeffi

[Sigi.21]

Hallo,

warum ist   2112012 = 21.12.2012 ???
Bei mir wäre es nach deiner Def. (Monat ist stets 2-stellig) nach  2.11.2012!?

Gruß
Sigi

[Lutz Fricke]

Kaeffi,

probier mal:

Code:

=WENN(LÄNGE(A1)=7;DATUM(RECHTS(A1;4);TEIL(A1;2;2);LINKS(A1;1));DATUM(RECHTS(A1;4);TEIL(A1;3;2);LINKS(A1;2)))

Und natürlich hat Sigi recht...

Gruß,
Lutz

[steve1da]

Hola,

Code:

=DATUM(RECHTS(A1;4);TEIL(A1;WENN(LÄNGE(A1)=8;3;2);2);LINKS(A1;WENN(LÄNGE(A1)=7;1;2)))

Gruß,
steve1da

[bug99]

Code:

=DATUM(RECHTS($A1;4);TEIL($A1;LÄNGE($A1)-5;2);LINKS($A1;LÄNGE($A1)-6))

[Kaeffi]

Vielen Dank für eure schnelle Unterstützung!

Ich habe mein Problem gelöst, und sogar die Formel verstanden 

[Kuwer]

Hallo,

ich hätte auch noch eine:

=DATWERT(TEXT(0&A1;"00-00-0000"))

Gruß Uwe