Statistik Tabelle

[vk.medemreal]

Hallo!

Ich habe folgendes Problem:

ich habe eine Main-Tabelle, die die folgenden Spalten enthält:

Personalnummer
Name
Adresse
Kostenstelle
Vollzeitäquivalent
Eintrittsdatum
Stellenbezeichnung

ich möchte jetzt in einer anderen Tabelle auf einem anderen Blatt ausgeben, wie viele Mitarbeiter einer bestimmten Kostenstelle mit einem Eintrittsdatum vor dem 01.06.2022 die Stellenbezeichnung 1, 2 und 3 hatten.
Meine Lösung war bislang folgende:

=ZÄHLENWENNS(MRC!$J:$J;"="&$F$2;MRC!$S:$S;"<"&V29;MRC!$R:$R;"Pflegefachkraft")
+ZÄHLENWENNS(MRC!$J:$J;"="&$F$2;MRC!$S:$S;"<"&V29;MRC!$R:$R;"Pflegedienstleitung")
+ZÄHLENWENNS(MRC!$J:$J;"="&$F$2;MRC!$S:$S;"<"&V29;MRC!$R:$R;"Wohnbereichsleitung")

Das Ergebnis ist 13

MRC! ist die Main-Tabelle
J:J die Spalte "Kostenstelle"
=&F2 ist dann die Kostenstelle die ich Abfragen möchte
S:S Ist die Spalte "Eintrittsdatum"
<&V29 ist das Datum 01.06.2022
R:R ist die Spalte "Stellenbezeichnung"

Nun ist das irgendwie sehr Fehleranfällig und furchtbar groß.
Gibt es eine Möglichkeit das zu verkleinern?

Ich habe die folgenden Dinge ausgeprobiert:

=ZÄHLENWENNS(MRC!$J:$J;"="&$F$2;MRC!$S:$S;"<"&V29;MRC!$R:$R;"Pflegefachkraft"*"Pflegedienstleitung"*"Wohnbereichsleitung")

Oder

=ZÄHLENWENNS(MRC!$J:$J;"="&$F$2;MRC!$S:$S;"<"&V29;MRC!$R:$R;"Pflegefachkraft"+"Pflegedienstleitung"+"Wohnbereichsleitung")

Das Ergebnis ist 0 jeweils (ist mir auch klar warum, weil keine Stellenbezeichnung alle drei Titel enthält)

=ZÄHLENWENNS(MRC!$J:$J;"="&$F$2;MRC!$S:$S;"<"&V29;MRC!$R:$R;ODER("Pflegefachkraft";"Pflegedienstleitung";"Wohnbereichsleitung")

Das Ergebnis ist auch 0. Was ich mir nicht erklären kann.

Vielleicht kann mir ja jemand weiter helfen. Danke sehr!

Mit freundlichen Grüßen

[schauan]

Hallöchen,

wenn Du das so gemacht hättest

die Stellenbezeichnung 1, 2 und 3 hatten.

hättest Du auf <4 prüfen können

---

Hier mal was prinzipielles, mit den gewünschten Begriffen in einer Liste (hier C1:C2)

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	Pudel	3	Pudel
2	Wohl		Wohl
3	Pudel
4	Nass

Zelle	Formel
B1	=SUMME(ZÄHLENWENN(A1:A4;C1:C2))

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 365

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

[vk.medemreal]

Ne die Tabellen sind nicht entsprechend durchnummeriert, deswegen geht das so leider nicht :(

[steve1da]

Hola,
Das Ergebnis ist auch 0. Was ich mir nicht erklären kann.
die Syntax ist schlicht falsch.

Code:

=SUMME(ZÄHLENWENNS(MRC!$J:$J;$F$2;MRC!$S:$S;"<"&V29;MRC!$R:$R;{"Pflegefachkraft"."Pflegedienstleitung"."Wohnbereichsleitung"}))

Oder halt wie von André gezeigt die Suchbegriffe in eine Liste schreiben und das in der Formel dann abfragen.
Gruß,
steve1da