Suche Formel

[cuba]

Hallo Forum

Folgende Situation:

A1 = 255
B1 = -321
C1 = 22.5%

A2 ist leer
B2 ist leer
C2 ist leer

Ziel: Wenn nur eines der Felder einen Eintrag hat, soll in E1 eine 1 erscheinen, ansonsten soll keine 1 erscheinen.

Mit der Wenn(und... Formel komme ich da nicht ans Ziel.

LG
cuba

[shift-del]

Hallo cuba

Code:

=ZÄHLENWENN(A1:C2;"<>")>0

[cuba]

Hallo

Ich vermute, ich habe mich falsch ausgedrückt.... SORRY

Ich habe eine Beispieldatei angefügt.

Der gelbe Teil stammt aus einer Berechnung und der grüne Teil ist die Auswertung davon. Die beiden Listen sind in zwei verschiedenen Tabelllenblättern.

Ich will über einen Filter dann nur noch diejenigen anzeigen, die mit einer 1 berechnet wurden.

Mit der Zählenwenn-Formel komme ich nicht zum gewünschten Ziel.

Lg
cuba

[shift-del]

Dann rate ich noch mal.

Code:

=ZÄHLENWENN(A3:C3;">0")>0

[WillWissen]

Hi cuba,

so?

Tabelle1

	A	B	C	D
3	10	-50	15%	1
4	0	0	0%
5	2	0	0%	1
6	0	0	0%
7	0	0	0%
8	0	2	0%	1
9	0	0	0%
10	0	0	0%
11	0	0	8%	1
12	0	0	0%

Formeln der Tabelle

Zelle Formel A3 =H3 B3 =I3 C3 =J3 D3 =WENN(ZÄHLENWENN(A3:C3;">0")>0;1;"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[BoskoBiati]

Hallo,

da reicht das:

Code:

=(ZÄHLENWENN(A3:C3;">0")>0)*1

Nullen ausblenden.

[radagast]

heje excelfreunde,

meines erachtens versagen die obigen lösungsbeispiele , wenn in den spalten a,b,c nur negative zahlen stehen. siehe zeile A3-C3, wenn
nur die -50 vorhanden wären. in der vorliegenden beispieltabelle wäre auch diese ein denkbare zahlenkonstellation.
mein lösungsansatz:

=WENN(--ODER(ABS(A3)>0;ABS(B3)>0;ABS(C3)>0)=0;"";--ODER(ABS(A3)>0;ABS(B3)>0;ABS(C3)>0))

liefert auch im falle der negativen zahlen einen 1 und entspricht seiner einleitenden ausführung.

[WillWissen]

Hi Janosch,

mit den Negativzahlen hattest du Recht. Aber dann reicht das:

Tabelle1

	A	B	C	D
3	10	-50	15%	1
4	-10	-20	-30%	1

Formeln der Tabelle

Zelle Formel A3 =H3 B3 =I3 C3 =J3 D3 =WENN(ZÄHLENWENN(A3:C3;"<>0")<>0;1;"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Oder auf Edgars Vorschlag angewandt:  

Code:

=(ZÄHLENWENN(A3:C3;"<>0")<>0)*1

[radagast]

heje excelfreunde,

klar, die elegandere formel  ist die von "willwissen"... hatte die selbe lösung parat, aber mit meiner formel wollte ich zeigen, dass man sein augenmerk auf alle zahlenarten und darstellungen richtet. bsp: so könnte auch 15% oder 0% nur noch eine reine textzeile sein, die den inhalt einer zelle durch eine formel interpretiert. lag hier nicht vor, aber dennoch...obacht geben...

[BoskoBiati]

Hallo,


1. wenn es nur um Einträge geht, dann reicht das:

Code:

=(ZÄHLENWENN($A3:$C3;"<>0")>0)*1

2. Wenn nur Zahlen gelten sollen, dann wäre das sinnvoll:

Code:

=(ANZAHL($A3:$C3)>0)*1

Hier mal die unterschiedlichen Formeln im Vergleich (Man beachte die Leerzeichen in B6!!!!):

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
3	553	125	-100	1	1	1	1
4	x				1	1
5	-1				1	1	1
6					1	1

Zelle	Formel
D3	=(ZÄHLENWENN($A3:$C3;">0")>0)*1
E3	=(ZÄHLENWENN($A3:$C3;"<>0")>0)*1
F3	=(ZÄHLENWENN($A3:$C3;"<>")>0)*1
G3	=(ANZAHL($A3:$C3)>0)*1
B6	=WENN(T6="";"";T6)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
3	553	125	-100	1	1	1	1
4	x				1	1
5	-1				1	1	1
6					1	1

Zelle	Formel
D3	=(ZÄHLENWENN($A3:$C3;">0")>0)*1
E3	=(ZÄHLENWENN($A3:$C3;"<>0")>0)*1
F3	=(ZÄHLENWENN($A3:$C3;"<>")>0)*1
G3	=(ANZAHL($A3:$C3)>0)*1
B6	=WENN(T6="";"";T6)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg