Suche in Spalte, kopiere Zeile

[Brennpunkt]

Hallo zusammen,

ich komme gerade nicht weiter.

Ich gebe in Tabelle 1 in A1 z.B. Hund ein.

Nun möchte ich, dass in Tabelle 2 in Spalte a nach Hund gesucht wird,
die gesamte Zeile 1 Kopiert wird und in Tabelle 3 / 1. Zeile eingefügt wird.
Das am besten per Makro ( VBA )

Vielen Dank vorab

[UweD]

Hallo

so?

- Rechtsclick auf den Tabellenblattreiter von Tabelle1
- Code anzeigen
- reinkopieren

Code:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Suchwort As String, TB1 As Worksheet, TB2 As Worksheet, TB3 As Worksheet
    Dim Zeile As Long, Sp As Integer
       
    Set TB1 = Sheets("Tabelle1")
    Set TB2 = Sheets("Tabelle2")
    Set TB3 = Sheets("Tabelle3")
   
    Sp = 1 'suchen in Spalte A
   
    If Not Intersect(Target, Range("A1")) Is Nothing Then 'nur bei Änderungen in A1 reagieren
        Suchwort = Target.Value
       
        If WorksheetFunction.CountIf(TB2.Columns(Sp), Suchwort) > 0 Then 'Ist vorhanden?
            Zeile = WorksheetFunction.Match(Suchwort, TB2.Columns(Sp), 0) ' in welcher Zeile?
           
            TB2.Rows(Zeile).Copy
            TB3.Rows(1).Insert Shift:=xlDown
            Application.CutCopyMode = False
           
            MsgBox Suchwort & ": kopiert"
        Else
            MsgBox Suchwort & ": nicht gefunden"
        End If
           
    End If
   
End Sub

Gruß UweD

[Brennpunkt]

Vielen lieben Dank

Klappt prima