Suchen in Matrix mit 3 Suchkriterien

[ExcelBoomer]

Moin, ich habe ein Problem und zwar möchte ich aus einer Matrix suchen mit 3 Suchkriterien aber die Ausgabe erfolgt aus einer Matrix. 


Land    Wert   2019   2020  2021  2022
DEU     Einw       5        6      7         8 
FRA      GDP       4         5      6         8   

Meine Formel zum  Suchen von Einwohner in Deutschland 2020 ist 
=Sverweis("DEU"&"Einw";WAHL({1.2};AA:BB;E:F);2;Falsch)    

Mein Profblem ist das ich bei "Wahl" ja nur sagen kann Ausgabe aus dem "WERT2" (E:F) aber ich kann da keine Spalte mehr auswählen. Ich wollte eigentlich über einen Vergleich noch das passende Jahr auswählen aber das geht nicht weil du die Eingabe 1/2 durch Wahl erlaubt ist. 

Ich hoffe jemand versteht meine Erklärungen und hat vllt einen Ansatz dafür.
LG

[steve1da]

Hola,

Code:

=summenprodukt((A2:A10="deu")*(B2:B10="einw")*(C1:F1=2020)*(C2:F10))

Gruß,
steve1da

[ExcelBoomer]

Ok wow das hat direkt funktioniert! Und so eine schnelle Antwort 

Vielen lieben Dank!

---

Ok da bin ich wieder. Das hat in meiner Testdatei gut geklappt. Neues Problem:
Die Datei ist so groß das die Formel nicht funktioniert. Dann mal andersrum. Ich möchte gerne aus folgender Datei beliebig auslesen können z.B. 

Germany       -     Gross domestic product, deflator      -       2022

Die Datei ist angehängt. Ist die Veröffentlichung des IMF vom Oktober... 
Wie würdet ihr da vorgehen?

[echo]

Wie würdet ihr da vorgehen?

Hallo 
ich würde als erstes die Datei nicht mehr als *.xls speichern. 
XLS ist mit Start Excel2007 veraltet. Neue Datei-Version *.xlsx

Danach würde ich die komplette Liste zu einer Tabelle formatieren 
> irgendwo in der Liste eine Zelle markieren > [STRG]+[T] >Einstellung und Größe überprüfen > OK
Du bekommst jetzt in jeder Überschrift ein PullDown und kannst deine Liste nach belieben Filtern oder Sortieren, ganz schnelle und ohne jede Formel

zB in der Überschrift Spalte D 
[ ] alles auswählen >>  abwählen, danach 
[x] Gross domestic product, deflator 

Gruß Holger

[ExcelBoomer]

Hi Echo danke für den Tipp. 
Allerdings muss ich immer wenn der Report erscheint bestimmt Daten auslesen. Also bräuchte ich eine Formel um verschiedene Datensätze in der Datei zu finden. 
Gibts vllt einen Trick wie ich die automatisch so umformatieren, dass ich das mit Pivots lösen kann? Die Werte der verschiedenen Jahre stehen ja leider nebeneinander... 

Am "einfachsten" wäre allerdings eine Formel dafür. Hoffe jemand kennt da zufällig einen Kniff

[Ralf A]

...Du kannst doch direkt aus der Tabelle eine Pivottable machen... und darin mit Slicern (Datenschnitten) arbeiten... da brauchst Du keine Formel mehr.

[Fred11]

Hallo Excelboomer,

was heißt die SUMMENPRODUKT-Formel  von steve1da funktioniert nicht ?
An der Dateigröße liegt es wohl eher nicht, dass diese Formel nicht funktioniert.

Die Suchbegriffe müssen schon auch exakt so in deiner Tabelle vorkommen.
"Germany" z.B. taucht in deiner Beispieldatei ja gar nirgendwo auf.

Und wenn in der Matrix mit den Werten, die du auslesen möchtest auch Texte vorkommen können (was in deiner Beispieldatei mit n/a der Fall ist) dann funktioniert die SUMMENPRODUKT-Formel tatsächlich nicht; sie liefert dann einen Fehlerwert.

Alternative Formel(n):

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
1	Land	Wert	2019	2020	2021	2022		Suchkriterien
2	DEU	Einw	5	6	7	8		Land	AB
3	FRA	GDP	4	5	6	8		Wert	Einw
4	AB	Einw	4	66	4	7		Jahr	2021
5	XYZ	WE1	2	2	7	5
6	ABX1	Einw	2	2	9	6		Ergebnis	4
7	MMM	GDP	2	3	9	4		Ergebnis	4
8								Ergebnis	4

Zelle	Formel
I6	{=INDEX($C$2:$F$7;VERGLEICH($I$2&$I$3;$A$2:$A$7&$B$2:$B$7;0);VERGLEICH(I4;$C$1:$F$1;0))}
I7	=INDEX($C$2:$F$7;VERWEIS(2;1/($A$2:$A$7&$B$2:$B$7=$I$2&$I$3);ZEILE($A$2:$A$7))-ZEILE($A$1);VERGLEICH(I4;$C$1:$F$1;0))
I8	=SUMMENPRODUKT((A2:A7=I2)*(B2:B7=I3)*(C1:F1=I4)*C2:F7)

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Gruß
Fred