Summe Daten mit mehreren Bedingungen

[GaDi]

Hallo,

ich möchte die Summe Preis für verschieden Artikel und jeden Artikel selber mit verschieden Ausstattungen (A,B,C) bilden die unsortiert in einer Tabelle stehen. Die Artikelnummern sollen automatisch aufsteigen sortiert sein. Die Ausgangstabelle von 2000 Zeilen kann nicht vorab sortiert werden.

Danke.

[shift-del]

Moin

Verwende eine Pivot-Tabelle.

[{Boris}]

Hi,

mit xl365 geht:

=LET(a;SORTIEREN(EINDEUTIG(B5:C17));b;INDEX(a;;1);c;INDEX(a;;2);d;SUMMEWENNS(D5:D17;B5:B17;b;C5:C17;c);e;SUMME(d);f;VSTACK(d;e);WENNFEHLER(WAHL({1.2.3};b;c;f);""))

[GaDi]

Hi,

Die Pivot Tabelle ist eine Idee nur die aktualisiert sich nicht von alleine. Ist eine Fehlerquelle die ich ausschließen will.

---

Hi Boris

Wenn ich noch mehr Daten/Spalten dazufügen will. An welcher Stelle erweitere ich die Formel?

LG GaDi

[{Boris}]

Hi,

hast Du denn inzwischen bereits auf xl365 umgerüstet? Gemäß Deinen Angaben nutzt Du noch xl2013.
Falls ja: Gib mal bitte ein konkretes Beispiel - mit einer Beispielmappe (kein Bild).

---

Hi,

kurz zur Erläuterung der Formel (hab sie noch etwas geändert):

=LET(
a;SORTIEREN(EINDEUTIG(B5:C17)); <= Variable a: Eindeutige und sortierte Einträge aus den Spalten B und C
b;INDEX(a;;1); <= Variable b: Die erste Spalte aus a - also die Artikelnummern der eindeutigen Liste
c;INDEX(a;;2); <= Variable c: Die zweite Spalte aus a - also die Art aus der eindeutigen Liste
d;SUMMEWENNS(D5:D17;B5:B17;b;C5:C17;c); <= Variable d: Summe aus der Spalte D mit 2 Bedingungen: Artikelnummer = b und Art = c
WENNFEHLER(WAHL({1.2.3};b;c;VSTACK(d;SUMME(d)));"")) <= Ausgabe aller 3 Matrizen aus b, c und d, wobei unter d mit VSTACK noch die Gesamtsumme angehängt wird


Ohne Kommentare:

=LET(
a;SORTIEREN(EINDEUTIG(B5:C17));
b;INDEX(a;;1);
c;INDEX(a;;2);
d;SUMMEWENNS(D5:D17;B5:B17;b;C5:C17;c);
WENNFEHLER(WAHL({1.2.3};b;c;VSTACK(d;SUMME(d)));""))

[GaDi]

Hi Boris

ich habe eine kleine Daten Datei erstellt. Im TabellenBlatt Ergebnis ist die die Struktur die am Ende herauskommen soll.
Danke schon einmal.

Ich habe die Möglichkeit auf 365 zu arbeiten.

GaDi

[{Boris}]

Hi,

=LET(a;SORTIEREN(EINDEUTIG(SPALTENAUSWÄHLEN(C2:I21;1;4;7)));Code;INDEX(a;;1);Region;INDEX(a;;2);Währung;INDEX(a;;3);Gewicht;SUMMEWENNS(D2:D21;C2:C21;Code;F2:F21;Region);Stück;SUMMEWENNS(G2:G21;C2:C21;Code;F2:F21;Region);Warenwert;SUMMEWENNS(H2:H21;C2:C21;Code;F2:F21;Region);WAHL({1.2.3.4.5.6};Code;Region;Gewicht;Stück;Warenwert;Währung))

Die Funktion SPALTENAUSWÄHLEN ist bisher nur in der Beta-Variante vorhanden.

Alternativ mit HSTACK (weiß grad nicht, ob die auch nur in der Beta vorhanden ist):

=LET(a;SORTIEREN(EINDEUTIG(HSTACK(C2:C21;F2:F21;I2:I21)));Code;INDEX(a;;1);Region;INDEX(a;;2);Währung;INDEX(a;;3);Gewicht;SUMMEWENNS(D2:D21;C2:C21;Code;F2:F21;Region);Stück;SUMMEWENNS(G2:G21;C2:C21;Code;F2:F21;Region);Warenwert;SUMMEWENNS(H2:H21;C2:C21;Code;F2:F21;Region);WAHL({1.2.3.4.5.6};Code;Region;Gewicht;Stück;Warenwert;Währung))

---

Hi,

ich hatte die Gesamtsummen unten vergessen - der Vollständigkeit halber daher hier nochmal die gesamte Formel in der logischen Umbruch-Ansicht:

=LET(
a;SORTIEREN(EINDEUTIG(SPALTENAUSWÄHLEN(C2:I21;1;4;7)));
Code;INDEX(a;;1);
Region;INDEX(a;;2);
Währung;INDEX(a;;3);
Gewicht;SUMMEWENNS(D2:D21;C2:C21;Code;F2:F21;Region);
Stück;SUMMEWENNS(G2:G21;C2:C21;Code;F2:F21;Region);
Warenwert;SUMMEWENNS(H2:H21;C2:C21;Code;F2:F21;Region);
WENNFEHLER(WAHL({1.2.3.4.5.6};Code;Region;VSTACK(Gewicht;SUMME(Gewicht));VSTACK(Stück;SUMME(Stück));VSTACK(Warenwert;SUMME(Warenwert));Währung);""))

[EDIT]: Ich hatte die Formel der Einfachheit halber in das selbe Blatt wie die Daten gepackt - wenn sie bei Dir im anderen Blatt stehen soll, dann musst Du bei den einzelnen Bezügen natürlich den Blattnamen ergänzen.