SummeWenn unter der Bedingung dass

[Sascha1990]

Hallo,
ich müsste für die Arbeit folgendes Problem lösen:

Es geht um eine Kundenliste, die unter anderem folgende Spalten enthält:

Kunden
Umsatz

Der Kunde ist durch ein Kürzel identifiziert.

L3-K steht für KAM
L3-W steht für Großhandel

Nun soll einmal der summierte Umsatz der 10 Umsatzstärksten aufgelistet werden. Einmal für Großhandel und einmal für KAM. Also TOP 10 KAM und Top 10 GH

Bsp.
Kundenspalte: B12:B131 zB. L3-K Müller Hans

Ich habe schon etlich viele Ansätze probiert. Gerade bin ich bei dem Ansatz

=SUMMEWENN(LINKS(B12:B131)="L3-K*;KGRÖSSTE(U12:U131;ZEILE(INDIREKT(1:10))))

das da etwas fehlt, sehe ich, aber ich komme nicht weiter. Die Idee war, dass wenn im Bereich B12-B131 zu Beginn der jeweiligen Zelle ein L3-K vorkommt, dann soll es summiert werden unter der Bedingung, dass der Wert zu den 10 größten Umsätzen gehört, die in der Umsatzspalte zu finden ist.

Ich bin um jede Hilfe dankbar, da ich einen Zeitrahmen habe, um die Aufgabe zu lösen.

Angehängt ist ein Beispiel für einen möglichen Aufbau

Vielen Dank
Praktikant Sascha

[steve1da]

Hola,

Code:

=KGRÖSSTE(WENN(LINKS($B$1:$B$23;4)="L3-K";$C$1:$C$23);ZEILE(A1))

bzw.

Code:

=KGRÖSSTE(WENN(LINKS($B$1:$B$23;4)="L3-W";$C$1:$C$23);ZEILE(A1))

Die Formeln mit Strg-Shift-Enter abschließen und 10 Zeilen nach unten kopieren.

Gruß,
steve1da

[neopa]

Hallo Sascha,

... das geht z.B. mit folgender Matrixfunktion(alität)sformel, die im Gegensatz zu einer echten Matrixformel keines spez. Formelabschlusses bedarf.

=SUMMENPRODUKT(AGGREGAT(14;6;U12:U131/(LINKS(B12:B131;4)="L3-K");ZEILE(A1:INDEX(A:A;MIN(10;ZÄHLENWENN(B12:B131;"L3-K"&"*"))))))

Die Formel würde etwas einfacher, wenn immer gewährleistet wäre, dass es auch mind. 10 Kunden gibt.

Dann reicht:

=SUMMENPRODUKT(AGGREGAT(14;6;U12:U131/(LINKS(B12:B131;4)="L3-K");ZEILE(A1:A10)))

[Sascha1990]

Ich danke euch, die Formeln haben prima funktioniert. Darauf wäre ich nicht selbst gekommen, aber für das nächste mal weiß ich nun Bescheid. Letztendlich habe ich diese Formel benutzt:

=SUMMENPRODUKT(AGGREGAT(14;6;U12:U131/(LINKS(B12:B131;4)="L3-K");ZEILE(A1:INDEX(A:A;MIN(10;ZÄHLENWENN(B12:B131;"L3-K"&"*"))))))