Clever-Excel-Forum › Office-Anwendungen › Excel v
Textreihenfolge einer Zelle umkehren

Thema geschlossen 
Baumstrukturmodus
Textreihenfolge einer Zelle umkehren
Thomas1989 Offline
pausiert
Registriert seit: 22.05.2016
Version(en): Office for Mac 2011
#1
07.06.2016, 15:39
Hallo Leute,

Ich hab in einer Spalte den Institutnamen, Abteilung, Stadt und das Land, wie folgt etwa:

Karolinska Inst, Dept Cell & Mol Biol, Stockholm, Sweden

Ich brauch aber nur den Institutnamen und das Land. Also nur den Text vor dem ersten Komma und nach dem letzten Komma. Den Institutnamen kann ich leicht extrahieren mit der Text-In-Spalte-Funktion, aber hat jemand eine Idee wie ich das Land extrahieren kann? Das Problem ist, dass der Inhalt der über 50.000 Zeilen sehr uneinheitlich ist. Dh. das viele Zeilen noch zusätzliche Wörter und somit mehr Kommas aufweisen als das obige Beispiel. Wie die folgende Zeile:

Maastricht Univ, Dept Human Movement Sci, NUTRIM Sch Nutr & Translat Res Metab, Med Ctr, NL-6200 MD Maastricht, Netherlands

Aber prinzipiell bleibt die Logik, dass ganz vorne der Institutname und ganz hinten der Ländername steht. 

Ist es möglich, dass man z.B. die Textreihenfolge in der Spalte umkehrt, sodass ich wieder mit der Text-in-Spalte-Fkt den Ländernamen herausbekomme? Oder hat jemand eine alternative Idee?

Danke im Voraus!

VG
Thomas


Angehängte Dateien
.xlsx   Beispiel1.xlsx (Größe: 860,26 KB / Downloads: 6)
Suchen
Top
steve1da Offline
Benutzer
Registriert seit: 16.04.2014
Version(en): xl2016/365
#2
07.06.2016, 15:46
Hola,


Code:
=LINKS(A2;SUCHEN(",";A2)-1)


und


Code:
=TEIL(A2;VERWEIS(9^9;FINDEN(",";A2;SPALTE($1:$1)))+2;99)

Gruß,
steve1da
[-] Folgende(r) 1 Nutzer sagt Danke an steve1da für diesen Beitrag:
  • Thomas1989
Suchen
Top
WillWissen Offline
CEF-Moderator
Registriert seit: 10.04.2014
Version(en): Microsoft 365, mtl. Kanal
#3
07.06.2016, 15:50
Hi Thomas,

Tabelle1

ABCD
7Maastricht Univ, Dept Human Biol, NUTRIM Sch Nutr & Translat Res Metab, Med Ctr, NL-6200 MD Maastricht, NetherlandsMaastricht UnivNetherlands
8Karolinska Inst, Dept Cell & Mol Biol, Stockholm, SwedenKarolinska InstSweden
9Maastricht Univ, Med Ctr, Cardiovasc Res Inst Maastricht, Dept Genet & Cell Biol Mol Cell Biol, NL-6200 MD Maastricht, NetherlandsMaastricht UnivNetherlands
10Maastricht Univ, Med Ctr, Cardiovasc Res Inst Maastricht, Dept Genet & Cell Biol Mol Cell Biol, NL-6200 MD Maastricht, NetherlandsMaastricht UnivNetherlands
11Univ Aachen, Inst Mol Cardiovasc Res IMCAR, Univ Klinikum Aachen, Aachen, GermanyUniv AachenGermany
12Leibniz Inst Wissensmedien, Schleichstr 6, D-72076 Tubingen, GermanyLeibniz Inst WissensmedienGermany
13Leibniz Inst Wissensmedien, Schleichstr 6, D-72076 Tubingen, GermanyLeibniz Inst WissensmedienGermany
14Leibniz Inst Wissensmedien, Schleichstr 6, D-72076 Tubingen, GermanyLeibniz Inst WissensmedienGermany
Formeln der Tabelle
ZelleFormel
C7=LINKS(A7;SUCHEN(",";A7)-1)
D7=TEIL(A7;FINDEN("#";WECHSELN(A7;" ";"#";LÄNGE(A7)-LÄNGE(WECHSELN(A7;" ";""))))+1;99)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
[-] Folgende(r) 1 Nutzer sagt Danke an WillWissen für diesen Beitrag:
  • Thomas1989
Suchen
Top
Thomas1989 Offline
pausiert
ThreadStarter
Registriert seit: 22.05.2016
Version(en): Office for Mac 2011
#4
Star  07.06.2016, 15:59
Wow, funktioniert einwandfrei ! Danke! :19:
Suchen
Top
Thomas1989 Offline
pausiert
ThreadStarter
Registriert seit: 22.05.2016
Version(en): Office for Mac 2011
#5
08.06.2016, 18:59
Bei der weiteren Datenaufbereitung ist mir aufgefallen, dass der Stadtname auch recht wichtig ist. 
Der Stadtname befindet sich immer zwischen dem vorletzten und letztem Komma, wie zb.:

Fraunhofer Inst Mol Biol & Appl Ecol IME, Aachen, Germany

Kann man also die folgende Funktion umändern um den Stadtnamen zu extrahieren?

 =TEIL(A2;VERWEIS(9^9;FINDEN(",";A2;SPALTE($1:$1)))+2:99)

VG
Thomas
Suchen
Top
WillWissen Offline
CEF-Moderator
Registriert seit: 10.04.2014
Version(en): Microsoft 365, mtl. Kanal
#6
08.06.2016, 19:19
Hi Thomas,

so:

Tabelle1

ABCD
6Maastricht Univ, Dept Human Biol, NUTRIM Sch Nutr & Translat Res Metab, Med Ctr, NL-6200 MD Maastricht, NetherlandsMaastricht UnivMaastricht,Netherlands
7Maastricht Univ, Dept Human Biol, NUTRIM Sch Nutr & Translat Res Metab, Med Ctr, NL-6200 MD Maastricht, NetherlandsMaastricht UnivMaastricht,Netherlands
8Karolinska Inst, Dept Cell & Mol Biol, Stockholm, SwedenKarolinska InstStockholm,Sweden
9Maastricht Univ, Med Ctr, Cardiovasc Res Inst Maastricht, Dept Genet & Cell Biol Mol Cell Biol, NL-6200 MD Maastricht, NetherlandsMaastricht UnivMaastricht,Netherlands
10Maastricht Univ, Med Ctr, Cardiovasc Res Inst Maastricht, Dept Genet & Cell Biol Mol Cell Biol, NL-6200 MD Maastricht, NetherlandsMaastricht UnivMaastricht,Netherlands
11Univ Aachen, Inst Mol Cardiovasc Res IMCAR, Univ Klinikum Aachen, Aachen, GermanyUniv AachenAachen,Germany
Formeln der Tabelle
ZelleFormel
B6=LINKS(A6;SUCHEN(",";A6)-1)
C6=LINKS(TEIL(A6;FINDEN("##";WECHSELN(A6;" ";"##";LÄNGE(A6)-LÄNGE(WECHSELN(A6;" ";))-1))+1;999);FINDEN(" ";TEIL(A6;FINDEN("##";WECHSELN(A6;" ";"##";LÄNGE(A6)-LÄNGE(WECHSELN(A6;" ";))-1))+1;999))-1)
D6=TEIL(A6;FINDEN("#";WECHSELN(A6;" ";"#";LÄNGE(A6)-LÄNGE(WECHSELN(A6;" ";""))))+1;99)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Die Formeln findest du u.a. hier:  http://www.herber.de/excelformeln und bitte suchen .../formeln.html?welcher=301
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
[-] Folgende(r) 1 Nutzer sagt Danke an WillWissen für diesen Beitrag:
  • Thomas1989
Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#7
09.06.2016, 07:47
Hallo,

mit PLZ:

[html]
Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCD
6Maastricht Univ, Dept Human Biol, NUTRIM Sch Nutr & Translat Res Metab, Med Ctr, NL-6200 MD Maastricht, NetherlandsMaastricht UnivNL-6200 MD MaastrichtNetherlands
7Maastricht Univ, Dept Human Biol, NUTRIM Sch Nutr & Translat Res Metab, Med Ctr, NL-6200 MD Maastricht, NetherlandsMaastricht UnivNL-6200 MD MaastrichtNetherlands
8Karolinska Inst, Dept Cell & Mol Biol, Stockholm, SwedenKarolinska InstStockholmSweden
9Maastricht Univ, Med Ctr, Cardiovasc Res Inst Maastricht, Dept Genet & Cell Biol Mol Cell Biol, NL-6200 MD Maastricht, NetherlandsMaastricht UnivNL-6200 MD MaastrichtNetherlands
10Maastricht Univ, Med Ctr, Cardiovasc Res Inst Maastricht, Dept Genet & Cell Biol Mol Cell Biol, NL-6200 MD Maastricht, NetherlandsMaastricht UnivNL-6200 MD MaastrichtNetherlands
11Univ Aachen, Inst Mol Cardiovasc Res IMCAR, Univ Klinikum Aachen, Aachen, GermanyUniv AachenAachenGermany

ZelleFormel
B6=LINKS(A6;SUCHEN(",";A6)-1)
C6=TEIL(WECHSELN(A6;", "&D6;"");VERWEIS(9^9;FINDEN(",";WECHSELN(A6;", "&D6;"");SPALTE($1:$1)))+2;99)
D6=TEIL(A6;VERWEIS(9^9;FINDEN(",";A6;SPALTE($1:$1)))+2;99)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
[/html]
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#8
09.06.2016, 09:45 (Dieser Beitrag wurde zuletzt bearbeitet: 09.06.2016, 09:45 von BoskoBiati.)
Hallo Günter,

Deine Formeln versagen in einem solchen Fall:

[html]
Arbeitsblatt mit dem Namen 'Tabelle2'
 ABCD
11Univ Prag, Inst Mol Cardiovasc Res IMCAR, Univ Klinikum Prag, Prag, Czech RepublicUniv PragCzechRepublic

ZelleFormel
B11=LINKS(A11;SUCHEN(",";A11)-1)
C11=LINKS(TEIL(A11;FINDEN("##";WECHSELN(A11;" ";"##";LÄNGE(A11)-LÄNGE(WECHSELN(A11;" ";))-1))+1;999);FINDEN(" ";TEIL(A11;FINDEN("##";WECHSELN(A11;" ";"##";LÄNGE(A11)-LÄNGE(WECHSELN(A11;" ";))-1))+1;999))-1)
D11=TEIL(A11;FINDEN("#";WECHSELN(A11;" ";"#";LÄNGE(A11)-LÄNGE(WECHSELN(A11;" ";""))))+1;99)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
[/html]

oder auch hier:

[html]
Arbeitsblatt mit dem Namen 'Tabelle2'
 ABCD
10Den Haag Univ, Med Ctr, Cardiovasc Res Inst Maastricht, Dept Genet & Cell Biol Mol Cell Biol, NL-6200 Den Haag, NetherlandsDen Haag UnivHaag,Netherlands
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
[/html]
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
WillWissen Offline
CEF-Moderator
Registriert seit: 10.04.2014
Version(en): Microsoft 365, mtl. Kanal
#9
09.06.2016, 16:28
Hi Edgar,

auf Herz und Nieren getestet und deine Lösung für gut befunden! :32: 

@ Thomas

Du solltest Edgars Lösung nehmen  - seine Formeln zeigen dir das Ergebnis korrekt an.
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Suchen
Top
Thema geschlossen 


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste