Unterstützung bei Freitext-Auswertung

[markomania95]

Moin zusammen,

ich würde mich nicht als Excel-Newbie bezeichnen aber derzeit hänge ich an einem Problem, bei dem ich nicht weiter komme und sehr gerne Unterstützung annehme.
Ich habe einen DB-Auszug mit zwei Freitext-Feldern.
Aus dem ersten Feld (ActionLog) benötige ich einen Abgleich mit einer bestehenden Tabelle (Serial) - sprich: beinhaltet dieser Freitext eine Seriennummer aus Tab_Serial -> Wenn ja - dann soll er mir nur die Serial ausgeben.
Der zweite Freitext (Description) beinhaltet Standort-Daten, welche am besten in Spalten extrahiert werden sollen. Leider scheint die normale "Text in Spalten" Funktion nicht zu funktionieren, auch wenn ich bestimmte Trennzeichen einsetze - ein Teil des Freitexts ist verschwunden.

Ich habe euch mal eine Testdatei mit hochgeladen, in der der Status Quo sowie das Zielformat dargestellt sind. Anmerkungen und Hilfestellungen nehme ich sehr gerne entgegen :)

Vielen Dank im Voraus und Gruß

[Elex]

Hallo

Blatt Report 1 in C2 die Formel.

Code:

=VERWEIS(2;1/ISTZAHL(SUCHEN(Tab_Serials[Serials];[@ActionLog]));Tab_Serials[Serials])

Für dein zweites Anliegen wird es aufwendiger. Ist den wenigstens der Aufbau des Inhaltes immer gleich? Anzahl und Reihenfolge der Eigenschaften.

Code:

Hardware order: new Notebook Small WIN10
Lieferadresse:
Stadt: Testhausen
Straße: Musterstraße 5
Gebäude:Testhaus
Stockwerk: 1
Raum: 111
Anmerkung: XXX

Gruß Elex

[markomania95]

Hi Elex, 

danke für die Formel - die hat schon mal geklapt 

Code:

=VERWEIS(2;1/ISTZAHL(SUCHEN(Tab_Serials[Serials];[@ActionLog]));Tab_Serials[Serials])

Für dein zweites Anliegen wird es aufwendiger. Ist den wenigstens der Aufbau des Inhaltes immer gleich? Anzahl und Reihenfolge der Eigenschaften.

 Jein - es gibt unterschiedliche, ich nenne sie mal, Templates, in denen ein User im Frontend die geforderten Informationen eingibt. Diese Informationen werden dann als Freitext in der Description gefüllt (Leider lässt sich das auch nicht anpassen)
Wenn du die beiden Reiter zw. Report 1 und 2 vergleichst, wirst du feststellen, dass dort auch mehr/weniger Felder sind.

Code:

"Lieferadresse:
Stadt:
Teststadt
Straße:
Teststraße 1
Gebäude:
Testgebäude
Stockwerk:
1
Raum:
Testgebäude WAP1
Ist der Monitor für das Homeoffice?:
Nein
Anmerkung:"

Code:

"Hardware order: new Notebook Small WIN10
Lieferadresse:
Stadt: Testhausen
Straße: Musterstraße 5
Gebäude:Testhaus
Stockwerk: 1
Raum: 111
Anmerkung: XXX"

Aber innerhalb eines Templates sind Anzahl und Reihenfolge der Attribute immer gleich (Die Anzahl der Zeichen allerdings nicht - das war auch schon ein Gedanke).
Ich habe gehofft, dass wenn ich eine Formel passend hätte, dass ich diese für die anderen Templates adaptieren könnte

[BoskoBiati]

Hi,

ich würde nach diesem Muster vorgehen:

Code:

=TEIL([@Description];SUCHEN("Stadt";[@Description])+7;SUCHEN("Straße";[@Description])-SUCHEN("Stadt";[@Description])-7)

Muß halt für jeden Begriff angepasst werden.

[shift-del]

Moin

Hier noch eine Lösung mit spilled arrays. Dann kann man aber keine Tabelle verwenden.

Arbeitsblatt mit dem Namen 'Tabelle1'

A

B

C

D

E

F

G

H

I

J

K

L

M

N

1

Status

ActionLog

Used Serial

Summary

Description

Hilfsspalte

Stadt

Straße

Gebäude

Stockwerk

Raum

Ist der Monitor für das Homeoffice?

Anmerkung

Hardware order

2

Resolved

11.05.2022 12:56:03  HP 27" Dieses Ticket wurde vom Serviceanforderungssystem erstellt. Customer: XXX Submitter: XXX 11.05.2022 12:57:09  HP 27" 11.05.2022 15:36:36  Versandschein wurde beantragt. 12.05.2022 10:27:24  Hardware mit der SN CNK119293X wurde erfolgreich versendet.

CNK119293X

Monitor für XXX

Lieferadresse: Stadt: Teststadt Straße: Teststraße 1 Gebäude: Testgebäude Stockwerk: 1 Raum: Testgebäude WAP1 Ist der Monitor für das Homeoffice?: Nein Anmerkung:

Lieferadresse:Stadt:Teststadt:Straße:Teststraße 1:Gebäude:Testgebäude:Stockwerk:1:Raum:Testgebäude WAP1:Ist der Monitor für das Homeoffice?:Nein:Anmerkung:

Teststadt

Teststraße 1

Testgebäude

1

Testgebäude WAP1

Nein

Zelle	Formel
C2	=VERWEIS(42;1/ZÄHLENWENNS(B2;"*"&Tab_Serials[Serials]&"*");Tab_Serials[Serials])
F2	=WECHSELN(WECHSELN(WECHSELN(E2;": ";ZEICHEN(10));ZEICHEN(10);":");"::";":")
G2	=WENNFEHLER(XMLFILTERN("<y><z>"&WECHSELN(F2;":";"</z><z>")&"</z></y>";"//z[.='"&G$1:N$1&"']/following-sibling::z[1]");"")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg