Urlaubstage berechnen

[mizzy]

Guten Tag!

Schön, dass es dieses Forum gibt, werde eure Hilfe direkt in Anspruch nehmen.  :)

Es geht um die Berechnung von Urlaubstagen anhand eines Anfangsdatums und eines Enddatums. Es gibt zwei Urlaubstage pro Monat (bei 5 Arbeitstage pro Woche). Arbeitet jemand 4 Tage in der Woche, gibt es anteilig weniger Urlaubstage. Fängt jemand vor dem 15. an bekommt dieser 2 Urlaubtage für den Monat. Fängt der Mitarbeiter nach dem 15. an bekommt er einen Urlaubstag. Zusätzlich werden Urlaubstage bei Schwerbehinderung mit einberechnet (5 Tage pro Jahr).

Dies sind die Variablen.
H2=Anfangsdatum
I2=Enddatum
29=war eine Notlösung, soll die Durchschnittstage der Monate anzeigen -> das ist der Knackpunkt: Ich bräuchte eine Formel, die ausgibt, dass wenn jemand vor dem 15. angefangen hat 2 Tage bekommt und wer danach angefangen hat nur einen Tag bekommt. Auch für den letzten Monat gibt es entweder einen oder zwei Tage. Für alle anderen Monate immer 2 Urlaubstage.
U2=Schwerbehinderung (ja oder nein)
31=gleiche Notlösung wie oben
0,416666=5 Extratage bei Schwerbehinderung / gesamtes Jahr

Meine bisherige Formel lautete:
=(DATEDIF(H2;I2;"d")/(30)*(2)*(K2)/(5))+(SUMME(WENN(U2="ja";(DATEDIF(H2;I2;"d")/(31)*(0,41666)))))

So ist es doch recht ungenau, da ich von Durchschnittswerten ausgehe (die Monate haben im Durchschnitt 30 Tage)...Wie kann ich es genauer berechnen? Alle Monate bekommen zwei Urlaubstage, Startmonat und Endmonat je nach Anfangs-und Enddatum ein oder zwei Tage.

Vielen Dank für eure Hilfe!!

Liebe Grüße,
mizzy

[shift-del]

Hallo mizzy

Fängt jemand vor dem 15. an
Fängt der Mitarbeiter nach dem 15. an

Hoffentlich fängt jetzt kein Mitarbeiter am 15. an.

Was steht in K2?

Zeige bitte eine Beispielmappe mit mehreren Kalenderdaten, die an der Praxis orientiert sind.

[BoskoBiati]

Hallo,

für den Normalfall dürfte das reichen:

Code:

=DATEDIF(MONATSENDE(A8;0);B8-TAG(B8)+1;"M")*2+2+(TAG(A8)<15)+(TAG(B8)>=15)

Wenn das Enddatum in einem anderen Jahr liegt als das Anfangsdatum muß das Ganze ganz anders aufgezogen werden! Eine Mustertabelle wäre da hilfreich!

[mizzy]

Erst einmal vielen Dank für die Antworten. Da ist mir ja glatt entfallen, dass natürlich auch jemand am 15. anfangen kann.

Ich habe jetzt mal ein Beispiel angefügt. Das Enddatum kann auch im darauffolgenden Jahr liegen.

Viele Grüße,

mizzy

[BoskoBiati]

Hallo,

vielleicht passt das:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Eintritt	Austritt	Tage in der Woche	Schwerbehinderung	Urlaubsanspruch Ergebnis
2	26.10.16	31.01.17	4	ja	5
3	08.08.16	31.01.17	5	nein	10
4	14.05.16	31.01.17	5	nein	16
5	11.12.15	31.01.17	5	nein	24

Zelle	Formel
E2	=WENNFEHLER(AUFRUNDEN((DATEDIF(MAX(--("1.1."&JAHR(HEUTE()));MONATSENDE(A2;0));MIN(--("31.12."&JAHR(HEUTE()))+1;B2-TAG(B2)+1);"M")*(24+(D2="Ja")*5)/12+(JAHR(A2)=JAHR(HEUTE()))*(12+(TAG(A2)<15)*12+(D2="Ja")*5)/12+(JAHR(B2)=JAHR(HEUTE()))*(12+(TAG(B2)<15)*12+(D2="Ja")*5)/12)*C2/5;0);"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[lupo1]

E5: =AUFRUNDEN((1+(D5="ja")*5/24)*C5/5*(JAHR(B5)*24+MONAT(B5)*2-(TAG(B5)<16)-JAHR(A5)*24-MONAT(A5)*2+2-(TAG(A5)>15));) ergibt bei mir 28 Tage statt 24

[BoskoBiati]

Hallo lupo,

ich weiß nicht was Du berechnest, ich berechne Urlaub nur für das laufende Jahr.

[lupo1]

Für welches denn (es könnte auch 2017 gefragt sein)?

Eintritt und Austritt haben nichts mit dem Urlaubsjahr zu tun. Und JAHR(HEUTE()) muss nicht unbedingt der Ausgangspunkt sein. Ok, eben eingebastelt, da nicht ganz unsinnig:

E5: =AUFRUNDEN((1+(D5="ja")*5/24)*C5/5*MAX(;MIN(
JAHR(HEUTE())*24+24;JAHR(B5)*24+MONAT(B5)*2-(TAG(B5)<16))-MAX(
JAHR(HEUTE())*24;(JAHR(A5)*24+MONAT(A5)*2-2+(TAG(A5)>15))));) mit 167 statt 284 Zeichen

statt =AUFRUNDEN((1+(D5="ja")*5/24)*C5/5*(JAHR(B5)*24+MONAT(B5)*2-(TAG(B5)<16)-JAHR(A5)*24-MONAT(A5)*2+2-(TAG(A5)>15));)

[BoskoBiati]

Hallo,

Urlaub für 2015 ist mittlerweile verfallen und Urlaubskarteien werden generell nur für das laufende Kalenderjahr geführt. Urlaub im Vorgriff auf das nächste Jahr gibt es sowieso nicht.

[lupo1]

2015: Urlaub verfällt gesetzlich zum 31.3. des Folgejahres (vermute ich), und individuell ist das möglicherweise änderbar.
2017: Nicht alle planen den Urlaub erst am 1.1.2017. Einfach schon aus betrieblichen Gründen. Und ein Arbeitsende kann auch schon in 2016 bekannt sein.
(Formel angepasst, statt JAHR(HEUTE()) könnte man auch eine Zelle mit dem Jahr referenzieren)

Wieviele Tage hat ein Monat? http://xxcl.de/0028.htm