Userform Textbox Hintergrundfarbe wechseln

[Andyle]

Hallo, sicher werden schon einige bei Ihrer Vorbereitung für die Silvesterparty sein.

Ich probiere es dennoch eventuell einen Denkanstoß zu erhalten.

Ich habe eine Userform in der Artikel eingelesen werden.

Es geht um die TextBox8.

Diese soll beim starten Backcolor weiß sein. Klickt man rein soll diese grün werden. (Funzt soweit auch mit der Enter-Funktion)

wenn allerdings nichts reingeschrieben bzw. gescannt wird und man zu einer anderen TextBox geht soll die TextBox8 wieder in den Startzustand versetzt werden.

Code für Enter: der auch funktioniert

Code:

'Textbox8 inhalt löschen, wenn klick
Private Sub TextBox8_Enter()
With Me.TextBox8
If Not IsNumeric(.Value) Then
.Value = ""
.BackColor = mkGruen
.ForeColor = RGB(255, 255, 255)
End If
End With
End Sub

Hier der fesamte Code der Userform:

Code:

Option Explicit
Option Compare Text


'Speichern Schaltfläche Ereignisroutine
Private Sub CommandButton3_Click()
  Dim lZeile As Long
  Dim Artikel As String
 
  If Sheets("cache").Range("C36") <> "" Then
Artikel = """" & TextBox1.Value & """"
Else
Artikel = ""
End If
 
  If MsgBox("Soll dieser Artikel " & Artikel & " wirklich geändert werden?", vbYesNo + vbQuestion, "Eintrag bearbeiten") = vbYes Then
 
    'Neuer Barcode-Barcodeprüfung
    If TextBox8.Value <> "" And searchInColD(TextBox8.Value) Then
    MsgBox "Dieser Barcode ist im System bereit vorhanden.", vbCritical + vbOKOnly, "Barcodeprüfung"
    TextBox8.Value = ""
    Exit Sub
    ElseIf TextBox8.Value = "hier scannen ..." Then
    TextBox8.Value = ""
    End If
   
   
    'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
    If ListBox1.ListIndex = -1 Then Exit Sub
   
    'Wir müssen prüfen, ob die ID Spalte auch gefüllt ist!!
    If Trim(CStr(TextBox1.Text)) = "" Then
        'Meldung ausgeben
        MsgBox "Sie müssen mindestens einen Namen eingeben!", vbCritical + vbOKOnly, "FEHLER!"
        'Abbrechen des Speicherroutine
        Exit Sub
    End If
    'Ausbauoption: Prüfen ob die ID in Tabelle1 Spalte 1 schon vorhanden ist!
   
    'Zum Speichern benötigen wir die Zeilennummer des ausgewählten Datensatzes
    lZeile = 6 'Start in Zeile 2, Zeile 1 sind ja die Überschriftrn
    'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
    Do While Trim(CStr(sh1.Cells(lZeile, 3).Value)) <> ""
   
        'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
        If ListBox1.Text = Trim(CStr(sh1.Cells(lZeile, 3).Value)) Then
           
            'Eintrag gefunden, TextBoxen in die Zellen schreiben
            sh1.Cells(lZeile, 3).Value = Trim(CStr(TextBox1.Text))

            sh1.Cells(lZeile, 4).Value = TextBox2.Text                  'EK-Preis
            sh1.Cells(lZeile, 4).Value = Format(TextBox2.Value, "#,##0.00 €")
           
            sh1.Cells(lZeile, 5).Value = TextBox3.Text                  'VK-Preis
            sh1.Cells(lZeile, 5).Value = Format(TextBox3.Value, "#,##0.00 €")
           
            sh1.Cells(lZeile, 6).Value = TextBox4.Text                  'MwSt
            sh1.Cells(lZeile, 6).Value = Format(TextBox4.Value, "00") / 100
           
            sh1.Cells(lZeile, 7).Value = TextBox5.Text                  'Soll
            sh1.Cells(lZeile, 8).Value = TextBox6.Text                  'Ist
           
            If TextBox8.Text <> "" Then
            sh1.Cells(lZeile, 2).Value = TextBox8.Text                  'neuer Barcode
            Else
            sh1.Cells(lZeile, 2).Value = TextBox7.Text                  'alter Barcode
            End If
           
            'Die ListBox muss nun neu geladen werden
            'allerdings nur wenn sich der Name (ID) geändert hat
            If ListBox1.Text <> Trim(CStr(TextBox1.Text)) Then
                Call UserForm_Initialize
                If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
            End If
           
            Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
           
        End If
   
        lZeile = lZeile + 1 'Nächste Zeile bearbeiten
    Loop
   
    Unload Me
   
    MsgBox "Die Daten wurden erfolgreich geändert!", vbInformation, "Daten ändern"
   
    End If
   
End Sub

'Beenden Schaltfläche Ereignisroutine
Private Sub CommandButton4_Click()
    Unload Me
End Sub



'Klick auf die ListBox Ereignisroutine
Private Sub ListBox1_Click()
  Dim lZeile As Long
    'Wenn der Benutzer einen Namen anklickt, suchen wir
    'diesen in der Tabelle1 heraus und tragen die Daten
    'in die TextBoxen ein.
   
    'Wir löschen standardmäßig alle bisherigen TextBoxen-Inhalte
    TextBox1 = ""
    TextBox2 = ""
    TextBox3 = ""
    TextBox4 = ""
    TextBox5 = ""
    TextBox6 = ""
    TextBox7 = ""
'    TextBox8 = ""
   
    'Nur wenn ein Eintrag selektiert/markiert ist
    If ListBox1.ListIndex >= 0 Then
   
        lZeile = 6 'Start in Zeile 2, Zeile 1 sind ja die Überschriftrn
        'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
        Do While Trim(CStr(sh1.Cells(lZeile, 3).Value)) <> ""
       
            'Wenn wir den Namen aus der ListBox1 in der Tabelle1 Spalte 1
            'gefunden haben, übertragen wir die anderen Spalteninhalte
            'in die TextBoxen!
            If ListBox1.Text = Trim(CStr(sh1.Cells(lZeile, 3).Value)) Then
           
                'TextBoxen füllen
                TextBox1 = Trim(CStr(sh1.Cells(lZeile, 3).Value))   'Artikelname
               
                TextBox2 = sh1.Cells(lZeile, 4).Value               'EK-Preis
                TextBox2 = Format(TextBox2.Value, "#,##0.00") 'Format(TextBox2.Value, "###0.00")
               
                TextBox3 = sh1.Cells(lZeile, 5).Value               'VK-Preis
                TextBox3 = Format(TextBox3.Value, "#,##0.00") 'Format(TextBox3.Value, "###0.00")
               
'                TextBox4 = sh1.Cells(lZeile, 6).Value               'MwSt
                TextBox4 = Format(sh1.Cells(lZeile, 6).Value, "") * 100
               
                TextBox5 = sh1.Cells(lZeile, 7).Value               'Soll
                TextBox6 = sh1.Cells(lZeile, 8).Value               'Ist
               
                TextBox7 = sh1.Cells(lZeile, 2).Value               'Barcode
               
                TextBox8 = sh1.Cells(lZeile, 2).Value               'Barcode neu
               
                TextBox8.Value = "hier scannen ..."
               
           
                Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
           
            End If
       
            lZeile = lZeile + 1 'Nächste Zeile bearbeiten
       
        Loop
       
    End If
   
End Sub



Private Sub UserForm_Activate()
    'Wenn die Eingabemaske angezeigt wird, markieren wir den ersten Namen
    'jedoch nur wenn auch Einträge in der Liste stehen
    If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
End Sub

'Startroutine, wird ausgeführt bevor die Eingabemaske angezeigt wird
Private Sub UserForm_Initialize()
  Dim lZeile As Long
 
    'Alle TextBoxen leer machen
    TextBox1 = ""
    TextBox2 = ""
    TextBox3 = ""
    TextBox4 = ""
    TextBox5 = ""
    TextBox6 = ""
    TextBox7 = ""
    TextBox8.ForeColor = RGB(78, 99, 109)
   
   
    'In dieser Routine laden wir alle vorhandenen
    'Einträge in die ListBox1
    ListBox1.Clear 'Zuerst einmal die Liste leeren
   
    lZeile = 6 'Start in Zeile 2, Zeile 1 sind ja die Überschriftrn
    'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
    Do While Trim(CStr(sh1.Cells(lZeile, 3).Value)) <> ""
       
        'Aktuelle Zeile in die ListBox eintragen
        ListBox1.AddItem Trim(CStr(sh1.Cells(lZeile, 3).Value))
       
        lZeile = lZeile + 1 'Nächste Zeile bearbeiten
       
    Loop
   
End Sub

'Löschen Schaltfläche Ereignisroutine
Private Sub CommandButton2_Click()
  Dim lZeile As Long
  Dim Artikel As String
 
  If Sheets("cache").Range("C36") <> "" Then
Artikel = """" & Sheets("cache").Range("C36").Value & """"
Else
Artikel = ""
End If
 
  If MsgBox("Soll dieser Artikel " & Artikel & " wirklich gelöscht werden?" + vbCr + vbCr + "Dieses ist nicht rückgängig zu machen!", vbYesNo + vbQuestion, "Eintrag löschen") = vbYes Then
 
    'Wenn kein Datensatz in der ListBox markiert wurde, wird die Routine beendet
    If ListBox1.ListIndex = -1 Then Exit Sub
 
    'Zum Löschen benötigen wir die Zeilennummer des ausgewählten Datensatzes
    lZeile = 6 'Start in Zeile 2, Zeile 1 sind ja die Überschriftrn
    'Schleife solange etwas in der ersten Spalte in Tabelle 1 drin steht
    Do While Trim(CStr(sh1.Cells(lZeile, 3).Value)) <> ""
   
        'Datensatz ID Spalte mit selektiertem Eintrag der ListBox vergleichen
        If ListBox1.Text = Trim(CStr(sh1.Cells(lZeile, 3).Value)) Then
           
            'Eintrag gefunden, die ganze Zeile wird nun gelöscht
            sh1.Rows(CStr(lZeile & ":" & lZeile)).Delete
           
            'Die ListBox muss nun neu geladen werden!
            Call UserForm_Initialize
            If ListBox1.ListCount > 0 Then ListBox1.ListIndex = 0
           
            Exit Do 'Vorzeitiges Ende, da der Datensatz schon gefunden ist
           
        End If
   
        lZeile = lZeile + 1 'Nächste Zeile bearbeiten
    Loop
   
    End If
   
End Sub


'Textbox8 inhalt löschen, wenn klick
Private Sub TextBox8_Enter()
With Me.TextBox8
If Not IsNumeric(.Value) Then
.Value = ""
.BackColor = mkGruen
.ForeColor = RGB(255, 255, 255)
End If
End With
End Sub



'Prüfung Neuer barcode vorhanden
Function searchInColD(searchWhat As String) As Boolean

Dim rg As Range
Dim sRg As Range

Set rg = Columns("B")
Set sRg = rg.Find(searchWhat)
If sRg Is Nothing Then
searchInColD = False
Else
searchInColD = True
End If

End Function

Ich danke Euch!
Und einen guten Rutsch für Alle!

[Isabell]

Hallo, es wäre schon schön gewesen, wenn du anstelle der Bilder die Datei eingestllt hättest. Dann könnte man seine Vorschläge gleich mal testen, ohne alles nachbauen zu müssen.

[Andyle]

Hier die Datei!

[knobbi38]

Hallo,

dafür kannst du das Textbox Exit Event nutzen.

[Andyle]

---

---

Vielen Dank, hab es hinbekommen!

[Andyle]

Ich habe es jetzt wie folgt gelöst:

Private Sub TextBox8_Enter()
TextBox8.Value = ""
TextBox8.BackColor = mkGruen
TextBox8.ForeColor = RGB(255, 255, 255)
End Sub

Private Sub TextBox8_Exit(ByVal Cancel As MSForms.ReturnBoolean)
If TextBox8 = "" Then
TextBox8.Value = "hier scannen ..."
TextBox8.BackColor = RGB(255, 255, 255)
TextBox8.ForeColor = mkGrau4
End If
End Sub

[Crazy Tom]

moin,

echt Wahnsinn

 auf das mkGruen und mkGrau4 hätte man natürlich kommen können 

mfg Tom