Variable Länge einer Wertereihe gleicher Zahlen

[sheady]

Hallo zusammen,

ich habe mich in diesem Forum angemeldet, weil mich ein Problem umtreibt, dass ich nicht selbst gelöst bekomme. Ich hoffe der Betreff ist nicht all zu verwirrend.

Und zwar möchte ich, wie im anhängenden Bild zu sehen, eine Wertereihe erstellen, die immer eine bestimmte Anzahl gleicher Werte aneinander reiht.
Im Beispiel habe ich z.B. den Wert 2,4 und möchte, dass dieser 10x in einer Spalte wiederholt wird, bevor dann 10x der Wert 2,8 und abschließend 5x der Wert 3,2 angezeigt wird. Das ganze soll so funktionieren, dass ich sowohl die Werte, als auch deren Anzahl einfach aus den Bezügen variieren kann. z.B. dass der Wert 2,4 nicht 10 sondern 15x wiederholt wird, bevor die anderen Werte folgen.

Ist das mit einer ausgefuchsten Formel machbar oder nur mit Makros?

Ich freue mich sehr über jeden Tipp!

Gruß

[BoskoBiati]

Hi,

z.B. so:

	A	B	C
1	2,8	10	2,8
2	2,4	8	2,8
3	2	5	2,8
4			2,8
5			2,8

Zelle	Formel
C1	=A1
C2	=WENN(ZÄHLENWENN($C$1:C1;C1)>=SVERWEIS(C1;A:B;2;0);INDEX(A:A;VERGLEICH(C1;A:A;0)+1);C1)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[sheady]

Sensationell, danke schön!

Derart um die Ecke zu denken, habe ich einfach nicht drauf ;)

[Jockel]

Hallo, ich würde noch ne Fehlerabfrage umzuschreiben..:

=WENN(ZEILE()>SUMME(B:B);"";"Formel"))

[sheady]

direkt eingebaut und klappt wunderbar,

danke jockel 

[lupo1]

Boskos Tabelle lasse ich bei A:B gleich.

C1: 1
C2: =C1+B1 runterkopieren
D1: =INDEX(A:A;VERGLEICH(ZEILE();C:C))

Diese Hilfsspalten-Lösung ist ab ca. mehr als 1000 Ergebniszeilen vorzuziehen, da bei Bosko

ZÄHLENWENN das Modell mit ca. n^2/2 Berechnungen sehr stresst und
SVERWEIS und
VERGLEICH beide nicht binär suchend unterwegs sind und ebenfalls jeweils n^2/4  Berechnungen brauchen.

Zusammen also n^2 Berechnungen (genauer: n*(n-1)), also 999.000 bei 1000 Zeilen.

Meine Lösung braucht ca. nur log2(n/2)*n Berechnungen, also ~ 9.000, also 1% (bei 10.000 Ergebnis-Zeilen nur 0,012%, usw.)

Das ist aber nur wichtig für Leute, die Wert auf Tabellen fast ohne Rechenzeit legen. ;) Die anderen vergessen diese Lösung bitte sofort. Weil Hilfszellen eben uncool sind und Rechner rechnen sollen, statt zu warten. ;) Und weil mein Modell zu arbeitgeberfreundlich ist.

[sheady]

da es bei mir tatsächlich um mehrere tausend zeilen geht, habe ich deinen vorschlag mal umgesetzt. bei meinem arbeitsrechner ist die reduzierte rechenzeit tatsächlich spürbar. danke!