Vergleich 2 Zellen

[Chris_EDNC]

Hallo Excel-Profis :)

Ich habe ein Problemchen, an dem ich mir grad die Zaehne ausbeisse:

Gegeben:
2 Zellen. In denen laeuft je eine Berechnung und erzeugen je nach Parameter versch. Ergebisse.
Finale Ausgabe in einer dritten Zelle, hier soll wenn
Zelle1<500 der Wert von Zelle1 stehen (z.B. 450).
Zelle1>=500 und Zelle2>=500 der Wert von Zelle2 stehen (z.B. 700).
Zelle1>=500 und Zelle2<500 ein fester Wert von 500 stehen.

Wie bekomme ich sowas hin (keine Makros)?

Vielen Dank schonmal! :)


Chris

[Jockel]

Hi Chris, meinst du so..?

PHP-Code:

=WENN(A14<500;A14;WENN(UND(A14>=500;B14>=500);B14;WENN(UND(A14>=500;B14<500);500;""))) 


Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B	C
14	450	850	450
15	505	700	700
16	505	300	500

Zelle	Formel
C14	=WENN(A14<500;A14;WENN(UND(A14>=500;B14>=500);B14;WENN(UND(A14>=500;B14<500);500;"")))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[shift-del]

Hallo

Und für diejenigen mit ganz aktuellen Excel-Versionen (>=16.0.6528.1011):

Code:

=WENNS(A14<500;A14;B14>=500;B14;WAHR;500)

[BoskoBiati]

Hallo,

ohne WENN(S):

Code:

=(F11<500)*F11+(F11>=500)*((G11>=500)*G11+(G11<500)*500)
=(F11<500)*F11+(F11>=500)*MAX(G11;500)
=MAX(F11;(F11>=500)*MAX(G11;500))

[shift-del]

Hallo Edgar

Deine letzte Variante ist bisher die beste. Nicht nur weil sie die kürzeste ist sondern auch weil sie nur 3 Zellbezüge und 3 Funktionen/Operatoren beinhaltet.

[Chris_EDNC]

Super, es geht!!! :)
Ich habe Jockels Loesung genommen. Die von Edgar habe ich nicht verstanden... ;)

Vielen Dank nochmals!


Chris

[WillWissen]

Hallo zusammen,

@Edgar

Dein letzter Vorschlag rechnet nicht korrekt:

Tabelle3

	A	B	C	G	H
1				Edgar III	Formel ergibt:
2	505	300	505	505	=MAX(A2;(A2>=500)*MAX(B2;500))
3					=MAX(505;(WAHR(1))*500))
4					=MAX(505;500)=505

Formeln der Tabelle

Zelle Formel C2 =MAX(A2;(A2>=500)*MAX(B2;500)) G2 =MAX(A2;(A2>=500)*MAX(B2;500)) H2 =FORMELTEXT(G2)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[BoskoBiati]

Hallo Günter,

dann ist wohl gestern beim Testen was schiefgelaufen. Die kürzeste Version ist wohl doch mit WENN:

Code:

=WENN(A5<500;A5;MAX(B5;500))