Vergleich zweier Zeilen

[PatBA]

Hallo zusammen,
ich habe mal wieder ein Excel Problem.

Zur Erklärung:
in den Zellen C5:T5 und in den Zellen C7:T7 stehen Werte, die ich gerne pro Tag Vergleichen würde.
Sobald der erste Wert in der Zeile 7 kleiner ist als der in Zeile 5, soll Excel in der Zelle A7 das Datum aus der Zeile 4 ausgeben.

Kann mir jemand weiterhelfen, bin am verzweifeln. 
Vielen Dank vorab.

[NobX]

Hallo,

wenn ich Dich richtig verstanden habe, kannst Du das mit einer Matrix - Formel lösen - in Zelle A7 wenn das Datum in A4 steht:

PHP-Code:

{=WENN(ODER(C7:T7<C5:T5);A4;"")} 


Achtung: Matrix Formel, - die geschwungenen Klammern bitte mit der Tastenkombination "STRG + Shift + Enter" eingeben.

Grüße

Norbert

[PatBA]

Vielleicht muss ich mich besser ausdrücken.

Die Formel soll das Datum aus Zeile 4 ausspucken, bei dem der erste Wert aus Zeile 7 kleiner ist als in Zeile 5.

[Cadmus]

Eine Beispieldatei mit dem gewünschten Beispiel-Ergebniswert, ist hilfreicher als ein Bild. Ist doch kein Photoshop-Forum.

[Fred11]

Hallo PatBA,

zum Beispiel so (Formel in A7):
=AGGREGAT(15;6;$C$4:$T$4/($C$7:$T$7<$C$5:$T$5);1)

oder:
=INDEX($C$4:$T$4;VERGLEICH(WAHR;$C$7:$T$7<$C$5:$T$5;0))
in älteren Excel-Versionen (bis Excel 2019) evtl. als Matrixformel mit Strg+Shift+Enter eingeben

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I
4			03.05.2019	04.05.2019	05.05.2019	06.05.2019	07.05.2019	08.05.2019	09.05.2019
5		Werte A	8	9	11	15	16	18	22
6
7	07.05.2019	Werte B	22	20	19	18	10	9	5
8	07.05.2019

Zelle	Formel
A7	=INDEX($C$4:$T$4;VERGLEICH(WAHR;$C$7:$T$7<$C$5:$T$5;0))
A8	=AGGREGAT(15;6;$C$4:$T$4/($C$7:$T$7<$C$5:$T$5);1)

Verwendete Systemkomponenten: [Windows (64-bit) NT 10.00] / MS Excel 2021

Diese Tabelle wurde mit Tab2Html (v2.7.1) erstellt. ©Gerd alias Bamberg

Gruß
Fred

[PatBA]

funktioniert perfekt.
Vielen Dank