Verschachtelte SVERWEIS für Staffelpreise mit Feldnamen

[basejumper]

Hey zusammen,

hoffe mir kann jemand helfen.

Ich habe eine Preisliste mit Staffelpreisen je Menge.

Meine Formel funktioniert soweit im Schritt 1 (siehe Anhang)

Wenn ich den Tabellenbereich aber als Tabelle erstelle (STRG+T),
dann funktionert die Formel nicht mehr.

Wie muss die Formel umgestellt werden?

Besten Dank für eure Unterstützung.

Gruß
basejumper

[rate mit]

Hallo...


=VERWEIS(B21;INDEX(B17:G113;VERGLEICH(A21;A17:A113;0);)*VORZEICHEN(B16:K16<>"Preis")-0,000000000001;INDEX(B17:G113;VERGLEICH(A21;A17:A113;0);)*VORZEICHEN(B16:K16="Preis2"))

[shift-del]

Moin basejumper

Das ist ja auch ein Missbrauch der Tabellenfunktion.
Datensatzliste statt Kreuztabelle.

Materialnummer - ab Stück - Preis

[BoskoBiati]

Hi,

sehen wir mal davon ab, dass der Tabellenaufbau ungünstig ist, dann dürfen die Bereiche in der Formel nur die tatsächliche Tabelle umfassen. Außerdem werden die Namen direkt angesprochen, daher kannst Du nicht Preis als Suchkriterium nutzen:

Code:

=VERWEIS(B21;INDEX(Tabelle3[[ab Stück]:[Preis3]];VERGLEICH(A21;Tabelle3[Materialnummer];0);)*(LINKS(Tabelle3[[#Kopfzeilen];[ab Stück]:[Preis3]];5)<>"Preis")-1%%%;INDEX(Tabelle3[[ab Stück]:[Preis3]];VERGLEICH(A21;Tabelle3[Materialnummer];0);)*(LINKS(Tabelle3[[#Kopfzeilen];[ab Stück]:[Preis3]];5)="Preis"))

Das unsinnige VORZEICHEN habe ich mal rausgenommen!

[LCohen]

Wenn man gleich den gesamten Wert der Position statt nur den Preis haben möchte:

MN ab Stück1 ab Stück2 ab Stück3 Preis0 Preis1 Preis2 Preis3
815 0 100 1000 leer 1,2 1,1 0,99
816 0 200 2000 leer 2,4 2,2 1,99

D21: =LET(x;VERGLEICH(A21;Tabelle3[MNR]);
SUMME(WENNFEHLER(EXP(LN(B21-
INDEX(Tabelle3[[ab Stück1]:[ab Stück3]];x;)));)*(
INDEX(Tabelle3[[Preis1]:[Preis3]];x;)-
INDEX(Tabelle3[[Preis0]:[Preis2]];x;))))
ergibt 1272

mit A21: 816
mit B21: 560