Versicherungslaufzeiten bei Verlängerung

[gowaldi]

Hallo zusammen,
 
ich wollte mir eine kleine Übersicht über Versicherung Verträge machen mit den dazugehörigen Kündigungsfristen und Verlängerungen
Allerdings komme ich bei der Formel nicht zurecht.
Ich habe mal eine Tabelle beigefügt.
 
Ich möchte gerne, dass Excel mir unter „Neue Vertragsende. Verlängerung!“  beim Datum Eingabe alles neu berechnet.
 
Kann mir da wer helfen?
 
Danke!!

[steve1da]

Hola,

und was wie berechnet werden soll dürfen wir uns ausdenken?
EDATUM() kennst du ja bereits.
Gruß,
steve1da

[NobX]

Hallo,

wie steve1da geschrieben hat:

PHP-Code:

=EDATUM($D12;I12) 


s. grüne Markierung in der Tabelle. - Das hast mutlich gemeint.
Wenn Du das Datum mit der Vertragslaufzeit erfasst, erscheint der letzte Termin für die Kündigung, vorausgesetzt die (Kündigungs-) Frist ist richtig eingetragen.

Grüße

Norbert

[gowaldi]

Hallo steve1da, NobX
 
Die reingestellte Tabelle rechnet ja schon richtig! (denke ich) aber nur bis Vertragsende!
 
Was wenn der Vertrag verlängert wird bzw. Automatisch verlängert wird, wie kann ich den das berechnen ohne Änderungen in der Spalte D10 (Versicherungsbeginn) und E10 (Vertragsende).
 
Für den Berechnung der neuen (Vertragende G10) müssen zusätzliche formell eingebaut werden.
 
Ich möchte gerne in der Spalte G10 (neue Vertragende Eingeben) im Datumsformat „gelb markiert“,
und alles neu berechnet wird, also der (Status H10) und (J10 Kündigung)
 
Gruß
gowaldi

[WillWissen]

Hi,

so?

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G	H	I	J
10	14.07.2019	13.07.2021	24 Monate	13.07.2022	Neues Vertragsende eingeben	3 Monate	13.04.2022
11	14.09.2019	13.09.2020	12 Monate		Neues Vertragsende eingeben	3 Monate	13.06.2020

Zelle	Formel
J10	=WENN(UND(ISTZAHL(E10);G10="");EDATUM(E10;-I10);WENN(ISTZAHL(G10);EDATUM(G10;-I10);""))
J11	=WENN(UND(ISTZAHL(E11);G11="");EDATUM(E11;-I11);WENN(ISTZAHL(G11);EDATUM(G11;-I11);""))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[gowaldi]

Hallo WillWissen,

Genau so, Danke dir.

hast du noch eine Idee wie kann ich der  Prüfung in der Spalte  H10 erweitern um den neuen Laufzeit.

Gruß
gowaldi

[WillWissen]

Moin,

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G	H
10	14.07.2019	13.07.2021	24 Monate	13.07.2022	OK
11	14.09.2019	13.09.2020	12 Monate		Neues Vertragsende eingeben
12	14.09.2019	13.09.2020	12 Monate		Neues Vertragsende eingeben
13	15.09.2019	14.09.2020	12 Monate	15.08.2021	OK
14	16.09.2019	15.09.2020	12 Monate		Neues Vertragsende eingeben
15	17.09.2019	16.09.2020	12 Monate	30.07.2021	OK

Zelle	Formel
H10	=WENN(D10="";"";WENN(E10="";"";WENN(UND(HEUTE()>=D10;HEUTE()<=E10);"Ok";WENN(UND(HEUTE()>=D10;HEUTE()<=G10);"OK";"Neues Vertragsende eingeben"))))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[gowaldi]

Hallo WillWissen,
 
Deine Formel ist Perfekt Danke dafür,
ich habe noch eine bitte, wie kann ich die verbleibende tage bis zum Vertragende berechnen?
Hab zurzeit folgende Formel in L10

=WENNFEHLER(WENN(DATEDIF(HEUTE();E10;"y")=0;"";DATEDIF(HEUTE();E10;"y")&" Jahr"&WENN(DATEDIF(HEUTE();E10;"y")<>1;"e";""))&"  "&WENN(DATEDIF(HEUTE();E10;"ym")=0;"";DATEDIF(HEUTE();E10;"ym")&" Monat"&WENN(DATEDIF(HEUTE();E10;"ym")<>1;"e";"")&"  ")&WENN(TAG(E10)-TAG(HEUTE())+(TAG(HEUTE())>TAG(E10))*TAG(DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;))=0;"";TAG(E10)-TAG(HEUTE())+(TAG(HEUTE())>TAG(E10))*TAG(DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;))&" Tag"&WENN(TAG(E10)-TAG(HEUTE())+(TAG(HEUTE())>TAG(E10))*TAG(DATUM(JAHR(HEUTE());MONAT(HEUTE())+1;))<>1;"e";""));"")
 
Start Datum D10 14.09.2019 Vertragende E10 13.09.2021 Ergebnis 1 Monat 15 Tage
Wie kann ich Spalte G10 bei Neuen Vertragende dazu berechnen lassen?
Kannst du mir helfen?
 
Danke
Gruß
gowaldi

[WillWissen]

Hi,

das, was du hier betreibst, nenne ich "Salamitaktik". Komm halt mit deinen Fragen an einem Stück rüber - Salamitaktik mögen die wenigsten Helfer.

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G	H	I
10	14.09.2019	13.09.2021	24 Monate	13.07.2022	Ok	0 Jahr(e), 11 Monat(e), 14Tag(e)
11	14.09.2020	13.09.2021	12 Monate		Ok	0 Jahr(e), 1 Monat(e), 15Tag(e)
12	14.09.2019	13.09.2020	12 Monate		Neues Vertragsende eingeben	Versicherung beendet
13	15.09.2019	14.09.2020	12 Monate	15.08.2021	OK	0 Jahr(e), 0 Monat(e), 17Tag(e)
14	16.09.2019	15.09.2020	12 Monate		Neues Vertragsende eingeben	Versicherung beendet
15	17.09.2019	16.09.2020	12 Monate	30.07.2021	OK	0 Jahr(e), 0 Monat(e), 1Tag(e)

Zelle	Formel
I10	=WENNFEHLER(WENN(ISTZAHL(G10);DATEDIF(HEUTE();G10;"y")&" Jahr(e)"&", "&DATEDIF(HEUTE();G10;"ym")&" Monat(e)"&", "&DATEDIF(HEUTE();G10;"md")&"Tag(e)";DATEDIF(HEUTE();E10;"y")&" Jahr(e)"&", "&DATEDIF(HEUTE();E10;"ym")&" Monat(e)"&", "&DATEDIF(HEUTE();E10;"md")&"Tag(e)");"Versicherung beendet")

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[gowaldi]

Hallo WillWissen,

Hat alles super geklappt  

Danke für deine Hilfe 

Gruß
gowaldi