Verweisfunktion unter Bedingungen

[Webinho]

Hallo liebe Forengemeinde,

ich bin eben beim googlen auf das Board hier gestoßen und bestimmt gibt es hier jemanden der mir helfen kann, da ich was excel betrifft doch noch relativ unerfahren bin.
Folgendes Problem:

Ich habe eine Tabelle mit mehreren Tausend Zeilen(Produkten) und dazugehörigen Eigenschaften(Preis, EAN, etc.).
Die Produkte sind zu Teilen Variantenprodukte, d.h. sie unterscheiden sich beispielsweise in der Farbe. Viele der restlichen Eigenschaften sind aber diesselben.

Mein Ziel wäre es nun, eine Schaltfläche zu bekommen, in die man eine Artikelnummer(Spalte A) eingibt und als Ausgabe alle Artikel, welche die selbe Eigenschaften (im Beispiel Spalte B) besitzen bekommt. Zusätzlich sollte zu jedem der ausgegeben Artikel jeweils die Eigenschaft aus Spalte C wiedergegeben werden (Im Beispiel: EAN aus Spalte C).

Möglicherweise habe ich mich etwas verschwurbelt ausgedrückt, beim Ansehen der Datei wird es bestimmt ersichtlich:
Beispiel zur Datei: Ich möchte bspws. in ein Schaltfeld "5" eingeben und als Ausgabe
1 - 12345
2 - 12346
3 - 12347
4 - 12348
5 - 12349
6 - 12350

erhalten.

[BoskoBiati]

Hallo,

das wäre auch ohne VBA realisierbar, nur befürchte ich, dass Deine Artikelnummern in realiter anders aussehen und eine Gruppierung nicht so einfach möglich ist.

[Webinho]

Stimmt. Alle mehr oder weniger nach dem Verfahren "ABC123456", sprich drei buchstaben und einige Ziffern. Die Spalte B ist aber bei denjenigen Artikeln welche ich gerne gruppiert dargestellt hätte immer diesselbe, und auf diese müsste es ja eigentlich ankommen, oder?

[BoskoBiati]

Hallo,

dann stelle mal eine Mustertabelle vor!

[Rabe]

Hi,

mit diversen Hilfsspalten bekommst Du die Suchbegriffe raus.

Leider habe ich das VERWEIS() noch nicht richtig verstanden, darum werden die Artikelnummern rechts nicht richtig aufgezählt:

Tabelle1

	A	B	C	D	E	F	G	H	I	J	K
1	Artikelnummer	Bezeichnung	EAN	Hilfsspalte 1		Hilfsspalte 2		Abfrage Artikel		Artikelnummer	EAN
2	ABC12345	Super Teil	12345	ABC12345		Super Teil		ABC12345		ABC12359	12359
3	ABC12346	Super Teil	12346	ABC12346						ABC12359	12359
4	ABC12347	Super Teil	12347	ABC12347						ABC12359	12359
5	ABC12348	Super Teil	12348	ABC12348						ABC12359	12359
6	ABC12349	Super Teil	12349	ABC12349						ABC12359	12359
7	ABC12350	Super Teil	12350	ABC12350						ABC12359	12359
8	ABC12351	Klasse Ding	12351	ABC12351						ABC12359	12359
9	ABC12352	Klasse Ding	12352	ABC12352						ABC12359	12359
10	ABC12353	Klasse Ding	12353	ABC12353						ABC12359	12359
11	ABC12354	Klasse Ding	12354	ABC12354						ABC12359	12359
12	ABC12355	Klasse Ding	12355	ABC12355						ABC12359	12359
13	ABC12356	Klasse Ding	12356	ABC12356						ABC12359	12359
14	ABC12357	Klasse Ding	12357	ABC12357						ABC12359	12359
15	ABC12358	Auch schön	12358	ABC12358						ABC12359	12359
16	ABC12359	Auch schön	12359	ABC12359						ABC12359	12359
17										0	12359

verwendete Formeln
Zelle	Formel	Bereich	N/A
F2	=SVERWEIS(H2;A2: D16;2;0)
D2: D16	=A2
J2:J16	=VERWEIS($F$2;$B2:$D$16)
J17	=VERWEIS($F$2;$B$16:$D17)
K2:K17	=SVERWEIS($J$2;$A$2:$D$16;3;0)

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.07 einschl. 64 Bit

[BoskoBiati]

Hallo Ralf,

wenn, dann so:

Arbeitsblatt mit dem Namen 'Tabelle1'
	F	G	H
2	3	1	12345
3		2	12346
4		3	12347
5		4	12348
6		5	12349
7		6	12350

Zelle	Formel
G2	=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE($B:$B)/($B:$B=SVERWEIS($F$2;$A:$C;SPALTE(B$1);0));ZEILE(A1)));"")
H2	=WENNFEHLER(INDEX(C:C;AGGREGAT(15;6;ZEILE($B:$B)/($B:$B=SVERWEIS($F$2;$A:$C;SPALTE(B$1);0));ZEILE(B1)));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Webinho]

Hallo Edgar.

Tausend Dank, das sieht im Ergebnis genauso aus wie ich es mir gewünscht habe - mit einer Einschränkung: Wir benutzen excel2003 und das kennt die wennfehler funktion nicht. Hast du eine Idee wie ich das umstellen könnte damit es passt?

[BoskoBiati]

Hallo,

2003 kennt auch die Aggregat-Funktion nicht. Also alles für den Mülleimer!

ungetestet:

Code:

=WENN(ISTFEHLER(INDEX(A:A;KKLEINSTE(WENN($B:$B=SVERWEIS($F$2;$A:$C;SPALTE(B$1);0);ZEILE($B:$B));ZEILE(A1))));"";INDEX(A:A;KKLEINSTE(WENN($B:$B=SVERWEIS($F$2;$A:$C;SPALTE(B$1);0);ZEILE($B:$B));ZEILE(A1))))

Matrixformel! Mit STRG+SHIFT+ENTER abschließen!

[Webinho]

Hallo Edgar,

ich finde es super wie schnell du hier immer antwortest und wie hilfsbereit du bist. Danke danke danke!

Leider klappt es mit der Formel nicht. Gebe ich jetzt eine beliebige Artikelnummer in F2 ein, kommt in G2 stets als Ergebnis "Artikelnummer".

[BoskoBiati]

Hallo,

Arbeitsblatt mit dem Namen 'Tabelle1'
	F	G	H
2	3	1	12345
3		2	12346
4		3	12347
5		4	12348
6		5	12349

Zelle	Formel
G2	{=WENN(ISTFEHLER(INDEX(A:A;KKLEINSTE(WENN($B:$B=SVERWEIS($F$2;$A:$C;SPALTE($B$1);0);ZEILE($B:$B));ZEILE(A1))));"";INDEX(A:A;KKLEINSTE(WENN($B:$B=SVERWEIS($F$2;$A:$C;SPALTE($B$1);0);ZEILE($B:$B));ZEILE(A1))))}
H2	{=WENN(ISTFEHLER(INDEX(C:C;KKLEINSTE(WENN($B:$B=SVERWEIS($F$2;$A:$C;SPALTE($B$1);0);ZEILE($B:$B));ZEILE(B1))));"";INDEX(C:C;KKLEINSTE(WENN($B:$B=SVERWEIS($F$2;$A:$C;SPALTE($B$1);0);ZEILE($B:$B));ZEILE(B1))))}

Achtung, Matrixformel enthalten!

Die geschweiften Klammern{} werden nicht eingegeben.

Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg