Vorgang innerhalb eines Datumsbereichs finden

[LuckyJoe]

Hallo zusammen,

ich stehe gerade auf dem Schlauch und je länger ich übeerlege, desto länger wird meine Formel
Darum: bitte kurze Hilfe für eine Formel:
Ich erfasse nach Datum sortiert Ausgaben (B2:D22) und möchte am Ende eines Monats prüfen, ob ganz bestimmte Ausgaben erfasst wurden, die ich schon mal vergesse (in meinem Beispiel Steuerberater- und Telefon-Kosten).
Dazu habe ich einen Tabellenbereich (G1-H4), wo ich bei H1 den Monat des Jahres eintrage.
Darunter (H2:H4) sind die 3 Vorgänge eingetragen. In G2:G4 soll mit einer Formel signalisiert werden, ob für den eingetragenen Monat der Vorgang erfasst wurde.
Mit den eingetragenen Formeln funktioniert das zwar, aber ich bin überzeugt, dass es eine einfachere Formel gibt. Wahrscheinlich sehe ich mal wieder den Baum vor lauter Wäldern nicht
Kann mir jemand helfen?

	B	C	D	E	F	G	H
1	Datum	Vorgang	Betrag			Monat:	2024-02
2	03.01.2024	Sonstiger Betriebsbedarf	-99,99			ja	Steuerberaterkosten
3	05.01.2024	Werbekosten	-142,80			nein	Telefonkosten Festnetz
4	05.01.2024	Steuerberaterkosten	-150,00			ja	Telefonkosten Handy
5	07.01.2024	Bürobedarf	-75,50
6	09.01.2024	Telefonkosten Handy	-94,85
7	10.01.2024	Telefonkosten Festnetz	-69,88
8	22.01.2024	Software	-174,97
9	25.01.2024	Sonstiger Betriebsbedarf	-8,98
10	29.01.2024	Kfz-Tiefgaragen-Miete	-50,00
11	30.01.2024	Kfz-Tanken	-67,00
12	05.02.2024	Steuerberaterkosten	-150,00
13	06.02.2024	Postwertzeichen/Versandkosten	-10,49
14	07.02.2024	Kfz-Parken	-12,50
15	08.02.2024	Telefonkosten Handy	-94,85
16	11.02.2024	Bürobedarf	-13,97
17	13.02.2024	Kfz-Tanken	-67,00
18	14.02.2024	Bewirtungskosten	-55,30
19	07.03.2024	Telefonkosten Festnetz	-94,85
20	08.03.2024	Software	-113,05
21	09.03.2024	Telefonkosten Handy	-96,12
22	12.03.2024	Kfz-Tanken	-67,00

Zelle	Formel
G2	=WENN(ZÄHLENWENNS($B$2:$B$22; ">=" & DATUM(2024;$H$1;1); $B$2:$B$22; "<" & DATUM(2024;$H$1+1;1);$C$2:$C$22; "=" & $H2)>0;"ja";"nein")
G3	=WENN(ZÄHLENWENNS($B$2:$B$22; ">=" & DATUM(2024;$H$1;1); $B$2:$B$22; "<" & DATUM(2024;$H$1+1;1);$C$2:$C$22; "=" & $H3)>0;"ja";"nein")
G4	=WENN(ZÄHLENWENNS($B$2:$B$22; ">=" & DATUM(2024;$H$1;1); $B$2:$B$22; "<" & DATUM(2024;$H$1+1;1);$C$2:$C$22; "=" & $H4)>0;"ja";"nein")

  Vorgang innerhalb Datumsbereich finden.xlsx (Größe: 16,59 KB / Downloads: 11)

[shift-del]

Moin

ZÄHLENWENNS() ist schon der richtige Ansatz. Ich hätte nur das WENN() weggelassen.

Alternativ mit einer Hilfsspalte.

Arbeitsblatt mit dem Namen 'Tabelle1'
	E	F	G	H
1	Hilfsspalte		Monat:	2024-02
2	2024-01Sonstiger Betriebsbedarf		WAHR	Steuerberaterkosten
3	2024-01Werbekosten		FALSCH	Telefonkosten Festnetz
4	2024-01Steuerberaterkosten		WAHR	Telefonkosten Handy
5	2024-01Bürobedarf

Zelle	Formel
E2	=TEXT(B2;"JJJJ-MM")&C2
G2	=ZÄHLENWENNS($E$2:$E$22;"2024-"&TEXT($H$1;"00")&H2)>0

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hi,

ohne Hilfsspalte wäre die Formel nur wenig zu verbessern:

Code:

=WENN(ZÄHLENWENNS($B$2:$B$22;">=1."&$H$1&".2024";$B$2:$B$22;"<"&MONATSENDE("1."&$H$1&".2024";0);$C$2:$C$22;$H2);"ja";"nein")

mit SUMMENPRODUKT:

Code:

=WAHL(SUMMENPRODUKT((C2:C25=H2)*(MONAT(B2:B25)=$H$1))+1;"nein";"ja")

[maninweb]

Hallo,

eine weitere Möglichkeit, wobei ich ggf. dann für das Jahr eine weitere Zelle anlegen würde.
Wenn es sich eh nur auf 2024 kann man ja die Prüfung auf das Jahr weglassen.

PHP-Code:

=WENN(SUMME(($C$2:$C$22=$H2)*(MONAT($B$2:$B$22)=$H$1)*(JAHR($B$2:$B$22)=2024))>0;"ja";"nein") 


Gruß

[RPP63]

Moin!
*gelöscht*
Gruß Ralf

[LuckyJoe]

Vielen Dank an alle, die sich mit meinem Problem auseinandergesetzt haben, und für eure schnellen Antworten
In der Kürze liegt die Würze, darum habe ich mich für BoskoBiati's Lösung entschieden:

Code:

=WAHL(SUMMENPRODUKT((C2:C25=H2)*(MONAT(B2:B25)=$H$1))+1;"nein";"ja")

[RPP63]

In der Kürze liegt die Würze, darum habe ich mich für BoskoBiati's Lösung entschieden:

Aber nicht kürzer als nötig!
A few dollars more:
=SUMME((MONAT(B$2:B$22)=H$1)*(C$2:C$22=H2))
Im Format
"ja";;"nein"

Gruß Ralf

[LuckyJoe]

Hallo Ralf,
super, geht noch kürzer 
Ich musste jedoch noch eine "WENN"-Funktion einbauen, da es auch zu doppelten Einträgen kommen kann: wenn z.B. ein Vorgang bei Lastschrifteinzug zum Monatsende doch nicht eingezogen wurde und daher im Folgemonat am Monatsanfang UND am Monatsende eingezogen wird.