WENN SVERWEIS

[Andyle]

Hallo an alle!

Ich habe folgende Tabelle (tbl_Termine)

Datum        Uhrzeit       Was


Datum ab Übermorgen
=WENN(ZÄHLENWENN(Termine;">="&HEUTE()+2)<>0;KGRÖSSTE(Termine;ZÄHLENWENN(Termine;">="&HEUTE()+2));"")

Uhrzeit zum ermittelten Datum
=WENNFEHLER(WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0));"--")

Was zum ermittelten Datum
=WENNFEHLER(WENN(SVERWEIS(C37;Tbl_Termine;3;0)<>0;SVERWEIS(C37;Tbl_Termine;3;0));"kein Termin")

Jetzt zum Problem:
Ist keine Uhrzeit eingetragen, kommt der Fehler "FALSCH"

Ist kein Was eingetragen, kommt der Fehler "FALSCH"

Ist das zu ermittelnde Datum leer kommt wie vorgesehen bei Uhrzeit und Was "--"  (Richtig)

Wo ist mein Denkfehler?

Vielen Dank

[steve1da]

Hola,
hier mal zur Uhrzeit und FALSCH, das gilt dann analog für das Was und FALSCH.
Deine Formel, ohne Wennfehler:

Code:

=WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0))

Hier ist kein SONST gesetzt, nur das WENN und das DANN. Ist kein SONST gesetzt und das WENN ist nicht erfüllt kommt immer FALSCH, völlig egal ob Wennfehler() drum herum steht oder nicht.
Also, setze "" als SONST in deine Wenn-Formel und alles ist gut.
Gruß,
steve1da

[Andyle]

So hatte ich es bereits!

Uhrzeit
=WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0);"--")

Steht ein Datum drin kommt -- (Richtig)
Ist C37 (Datum) leer kommt #NV

wenn ich den #NV abfange mit
=WENNFEHLER(WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0));"--")

kommt wieder FALSCH wenn ein Datum da ist aber Uhrzeit nicht eingetragen ist.

[BoskoBiati]

Hi,

zeige mal eine passende Tabelle, damit man das nachvollziehen kann.

[steve1da]

Code:

=WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0);"--")

Dort hast du ein SONST gesetzt, nämlich "--".

Das hast du bei der Wennfehler Formel entfernt und in den Wert_Wenn_Fehler Teil gesetzt. Jetzt hast du in der Wenn-Formel kein SONST mehr.
Du kannst nicht einfach Parameter verändern und hoffen dass alles gleich bleibt.

Code:

=WENNFEHLER(WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0);"");"--")

[Andyle]

Tabelle hat wie oben beschrieben folgenden Aufbau:

Datum            Uhrzeit             Was

01.01.2025     11:00              Termin einkaufen



Datum wird mit der Formel ermittelt oder leer
=WENN(ZÄHLENWENN(Termine;">="&HEUTE()+2)<>0;KGRÖSSTE(Termine;ZÄHLENWENN(Termine;">="&HEUTE()+2));"")


Jetzt soll er die Uhrzeit anzeigen zum Datum
=WENNFEHLER(WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0));"--")
(Ist das Datum leer zeigt er -- an was richtig ist)

Ist allerdings ein Datum da und aber die Uhrzeit fehlt in der Zeile, zeigt er FALSCH an.

Es soll aber nicht FALSCH sondern -- anzeigen, wenn keine Uhrzeit neben dem Datum eingetragen ist.

[steve1da]

Den Aufbau hast du schon beschrieben, ebenso die Formeln.
Warum FALSCH kommt hab ich dir gezeigt.
Wie die Formel korrekt lautet hab ich ebenfalls geschrieben.

Wenn du nicht liest was ich schreibe kann ich dir leider nicht helfen.

[Andyle]

Die Formel mit sonst lautet

=WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0);"--")

Wenn allerdings zu dieser Formel

=WENN(ZÄHLENWENN(Termine;">="&HEUTE()+2)<>0;KGRÖSSTE(Termine;ZÄHLENWENN(Termine;">="&HEUTE()+2));"")

kein Datum gefunden wird, kommt #NV

wenn ich jetzt den #NV abfange

=WENNFEHLER(WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0));"--")

kommt FALSCH und nicht --

Also funzt Dein Vorschlag nicht!

[BoskoBiati]

Hallo,

wärst Du vielleicht mal in der Lage, eine Musterdatei einzustellen, damit man sieht, wo Dein Problem liegt?

[Andyle]

Man sieht manchmal den Wald vor lauter Bäumen nicht!

=WENNFEHLER(WENN(SVERWEIS(C37;Tbl_Termine;2;0)<>0;SVERWEIS(C37;Tbl_Termine;2;0);"--");"--")

funzt!

Danke für den Hinweis!