WENNS_Funktion (?)

[LCohen]

Danke RPP63 für die Korrektur zu Standard;-Standard;!
______________________________________________
OT:
Ohne jetzt selbst recherchiert zu haben: Hat jmd. schon mal ein überzeugendes Beispiel für WENNS gesehen?

Da WENNS 127 Bedingungen testen kann (aufgrund maximal 255 möglicher Argumente in einer Excel-Funktion), ist sie ggü maximal 64mal geschachteltem WENN ein wenig im Vorteil. Aber so etwas kommt selten vor. Mit LAMBDA ist letztere Einschränkung nicht mehr da, vermute ich.

Eher ist es in der Realität doch so, dass es einen "Entscheidungsbaum" anstelle einer "Bedingungssequenz" gibt.

[RPP63]

Hat jmd. schon mal ein überzeugendes Beispiel für WENNS gesehen?

Ich jedenfalls nicht!
Ich kam bisher auch noch nicht auf die Idee, dass mir WENNS() die Arbeit erleichtern könnte.

Wenn ich mir alleine mal das bekloppte Beispiel auf der Hilfeseite anschaue:

	D	E	F	G
1	Wochentag		Tagesnummer	Tag_Wenns
2	Sonntag		3	Dienstag
3	Montag
4	Dienstag
5	Mittwoch
6	Donnerstag
7	Freitag
8	Samstag

Zelle	Formel
G2	=WENNS(F2=1;D2;F2=2;D3;F2=3;D4;F2=4;D5;F2=5;D6;F2=6;D7;F2=7;D8)

Wenn schon Hilfsspalte mit den Wochentagen, dann würde ich doch eher mit INDEX arbeiten:

	D	E	F	G
1	Wochentag		Tagesnummer	Tag_Index
2	Sonntag		3	Dienstag
3	Montag
4	Dienstag
5	Mittwoch
6	Donnerstag
7	Freitag
8	Samstag

Zelle	Formel
G2	=INDEX(D2:D8;F2)

Oder gleich auf die Hilfstabelle verzichten und in Kenntnis der Excel-Zeitrechnung:

	F	G
1	Tagesnummer	Tag_RPP
2	3	Dienstag

Zelle	Formel
G2	=TEXT(F2;"TTTT")

Oder das andere Beispiel …
Da nehme ich doch lieber einen Vergleich.
Da es keine Note E gibt, musste ich ein wenig basteln:

	A	B	C
1	Note	Buchstabe	RPP
2	93	A	A
3	89	B	B
4	71	C	C
5	60	D	D
6	59	F	F
7	57	F	F

Zelle	Formel
B2	=WENNS(A2>89;"A";A2>79;"B";A2>69;"C";A2>59;"D";WAHR;"F")
C2	=ZEICHEN(71-VERGLEICH(A2;{0.59,9.60.70.80.90}))

Gruß Ralf

[BoskoBiati]

Hi,

oder auch so für die Noten:

Code:

=ZEICHEN(64+MIN(6;9-(A7-10)/10))

[HKindler]

Hi,

also ich verwende WENNS gerne und häufig. Und zwar immer dann, wenn ich damit Verschachtelungen vermeiden kann. Ich persönlich finde

Code:

=WENNS(A1<0;"negativ";A1=0;"Null";A1<10;"einstellig";A1<20;"klein";A1<60;"mittel";A1<100;"groß";WAHR;"riesig")

übersichtlicher als

Code:

=WENN(A1<0;"negativ";WENN(A1=0;"Null";WENN(A1<10;"einstellig";WENN(A1<20;"klein";WENN(A1<60;"mittel";WENN(A1<100;"groß";"riesig"))))))

Allein schon das lästige Aufpassen auf die Anzahl der Klammern...

Natürlich kann man in diesem einfachen Fall noch besser mit z.B. SVERWEIS arbeiten. Aber wenn die Bedingungen komplizierter werden, reicht ein einfacher SVERWEIS eben nicht mehr aus.

Und natürlich muss man WENNS nicht verwenden. Verschachtelte WENN reichen ebenfalls i.d.R. aus. Aber mit der Argumentation müsste man eigentlich konsequenterweise auch auf MAX(xx) [hier reicht KGRÖSSTE(xx;1)] oder MIN(xx) [KKLEINSTE(xx;1)] oder WENNFEHLER(xx;yy) [WENN(ISTFEHLER(xx);yy;xx)] oder ISOKALENDERWOCHE(xx) [KALENDERWOCHE(xx,21)] oder jede Menge anderer Funktionen verzichten.

[BoskoBiati]

Hi Helmut,

was aber sehr häufig vergessen wird ist der VERWEIS, der z.B. für Deine Beispiele sehr gut funktionieren würde.

[HKindler]

Hi Edgar,

Da möchte ich mich einmal selbst zitieren:

Natürlich kann man in diesem einfachen Fall noch besser mit z.B. SVERWEIS arbeiten. Aber wenn die Bedingungen komplizierter werden, reicht ein einfacher SVERWEIS eben nicht mehr aus.

Ich erweitere mein Beispiel:

Code:

=WENNS(A1<0;"negativ";A1=0;"Null";A1<10;"einstellig";A1<20;"klein";(A1<60)*(B1="Rot");"mittel, rot";A1<60;"mittel, andere Farbe";A1<100;"groß";WAHR;"riesig")

Mach das jetzt mal mit einem SVERWEIS

[BoskoBiati]

Hi,

wer lesen kann...

VERWEIS hatte ich geschrieben!

[HKindler]

Hi Edgar,

und wo genau ist jetzt der (qualitative) Unterschied zum SVERWEIS?

Und im Übrigen sagt die MS-Hilfe zum VERWEIS: 

Tipps: Ziehen Sie eine der neueren Nachschlagefunktionen in Betracht, je nachdem, welche Office Sie verwenden.

• Verwenden Sie SVERWEIS, um eine Zeile oder Spalte oder mehrere Zeilen und Spalten (z. B. eine Tabelle) zu durchsuchen. SVERWEIS ist eine stark verbesserte Version von VERWEIS. Schauen Sie sich dieses Video zur Verwendung von SVERWEIS an.
  
• Wenn Sie mit Microsoft 365 verwenden, verwenden Sie XVERWEIS . Dies ist nicht nur schneller, sondern ermöglicht ihnen auch die Suche in eine beliebige Richtung (nach oben, unten, links, rechts).
  

Fazit: VERWEIS selbst besser nicht verwenden.

[BoskoBiati]

Hi,

allem zum Trotz ist der VERWEIS hier gut zu brauchen:

Code:

=VERWEIS(A1;{-999;0;1;10;20;60;100};{"negativ";"Null";"einstellig";"klein";"mittel";"groß";"riesig"})

[LCohen]

Nochmal zurück zu WENNS.

Das kann nur sequenziell auswerten. Allerdings könnte man natürlich auch gleiche Auswirkungen an dafür opportunen Stellen in der WENNS-Sequenz erzeugen oder die Hierarchie durch geeignete Sortierung erbringen:

WENNS A1>5 ... B1>9 ... B1>1 ... A1>1 ... B1>6 ... B1>3 ...

Verschachtele ich hingegen WENN, kann ich ohne allzuviel Reihenfolgebeachtung hierarchisch auswerten. 

Alles immer abhängig vom jeweiligen Problem.