Wenn Arbeitstag..dann

[Schubi]

Hallo,
leider habe ich (Excel-Anfänger) schon etliche fehlerhafte Versuche hinter mir, und würde mich über einen Lösungvorschlag sehr freuen.

Habe eine Datei zur Zeiterfassung angelegt.
Von Mo bis Do ist eine Soll-Arbeitszeit von 8,5 Stunden am Fr von 6 Stunden vereinbart.

In Zelle A6  =WOCHENTAG(B6)wird der Tag aufgrund der Zelle B6 mit den Wochentagsabkürzungen Mo, Di, Mi, Do, Fr ausgegeben.
Ich möchte gerne, dass Excel in der Zelle I6 automatisch die Soll-Arbeitszeit aufgrund von Zelle A6 automatisch einträgt.Also Mo bis Do 8,5 Stunden am Fr 6 Stunden.

I6=(WENN(A6=(Mo,Di,Mi,Do);8,5;6))  ????




Vielen Dank

[Jockel]

Hallo, zuerst würde ich WOCHENTAG(datum;2) nehmen, und dann so tun..:

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B	C	D	E
6	06.03.2015	5	6	6	6
7	07.03.2015	6	0	0	6
8	08.03.2015	7	0	0	0
9	09.03.2015	1	8,5	8,5	8,5
10	10.03.2015	2	8,5	8,5	8,5
11	11.03.2015	3	8,5	8,5	8,5
12	12.03.2015	4	8,5	8,5	8,5
13	13.03.2015	5	6	6	6
14	14.03.2015	6	0	0	6
15	15.03.2015	7	0	0	0
16	16.03.2015	1	8,5	8,5	8,5
17	17.03.2015	2	8,5	8,5	8,5

Zelle	Formel
B6	=WOCHENTAG(A6;2)
C6	=WAHL(B6;8,5;8,5;8,5;8,5;6;;)
D6	=WENN(B6<5;8,5;WENN(B6=5;6;0))
E6	=VERWEIS(B6;{1;5;7};{8,5;6;0})

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hallo,

diese Thema ist schon sooft durchgekaut worden, wenn man googelt findet man tausende von Lösungen!
1. Wochentag ergibt keine Texte, die man auswerten kann, sondern dahinter stecken Zahlen
2. muß man den Wochentag nicht berechnen, den kann man ja direkt aus dem Datum ermitteln:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
3	1	Mo 02.03.15	8	8	8
4	2	Di 03.03.15	8	8	8
5	3	Mi 04.03.15	8	8	8
6	4	Do 05.03.15	8	8	8
7	5	Fr 06.03.15	6,5	6,5	6,5
8	6	Sa 07.03.15	8	8	8

Zelle	Format	Wert
B3	TTT TT.MM.JJ;@	02.03.2015

Zelle	Formel
A3	=WOCHENTAG(B3;2)
C3	=WENN(WOCHENTAG(B3;2)<>5;8;6,5)
D3	=WENN(REST(B3;7)<6;8;6,5)
E3	=8-(REST(B3;7)=6)*1,5

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo Edgar, ich lehne mich mal ganz weit aus dem Fenster, aber ich denke (das ist bei mir immer Glücksache), dass der TE am Wochenende keine 8 als Ergebnis haben will (auch keine 8,5). Steht zwar nicht explizit in der Anfrage, aber ich wäre schon sehr verwundert, wenn das so wär... ... weil es auch wenig Sinn machen würde, oder?

Aber vielleicht hat der TE auch nur Zellen belegt mit Mo-Fr, aber auch das würde mich wundern....

[BoskoBiati]

Hi Jörg,

Zitat TE:

In Zelle A6  =WOCHENTAG(B6)wird der Tag aufgrund der Zelle B6 mit den Wochentagsabkürzungen Mo, Di, Mi, Do, Fr ausgegeben.

[RPP63]

Hi!

Mein Vorschlag (mal ein wenig abseits der üblichen Lösungsvorschläge):

	A	B	C	D
1	01.03.2015	So	6
2	02.03.2015	Mo	0	8
3	03.03.2015	Di	1	8
4	04.03.2015	Mi	2	8
5	05.03.2015	Do	3	8
6	06.03.2015	Fr	4	6,5
7	07.03.2015	Sa	5
8	08.03.2015	So	6
9	09.03.2015	Mo	0	8

Zelle	Format	Wert
B1	TTT	01.03.2015
D1	Standard;;;	0

Zelle	Formel
B1	=A1
C1	=WOCHENTAG(A1;3)
D1	=(C1<4)*8+(C1=4)*6,5

Gruß Ralf

[Jockel]

Hi Jörg,

Zitat TE:
In Zelle A6  =WOCHENTAG(B6)wird der Tag aufgrund der Zelle B6 mit den Wochentagsabkürzungen Mo, Di, Mi, Do, Fr ausgegeben.

Hallo Edgar, wer lesen kann... ES war schon spät gestern oder früh heute - egal. Also mir gefallen diese Vorschläge am meisten..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F
1	02. Mrz	Mo	8,5	8,5	8,5	8,5
2	03. Mrz	Di	8,5	8,5	8,5	8,5
3	04. Mrz	Mi	8,5	8,5	8,5	8,5
4	05. Mrz	Do	8,5	8,5	8,5	8,5
5	06. Mrz	Fr	6	6	6	6

Zelle	Formel
C1	=VERWEIS(B1;{1;6};{8,5;6})
D1	=8,5-(REST(A1;7)=6)*2,5
E1	=(B1<6)*8,5+(B1=6)*6
F1	=WAHL((B1=6)+1;8,5;6)

Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Freund einer excellenten Power Query-Abfrage

[Rabe]

Hi,

Also mir gefallen diese Vorschläge am meisten..:

Ich habe noch etwas damit gespielt.

da stimmt noch was nicht:

Tabelle1

	A	B	C	D	E	F
1	Mo	02.03.2015	8,5	8,5	8,5	8,5
2	Di	03.03.2015	8,5	8,5	8,5	8,5
3	Mi	04.03.2015	8,5	8,5	8,5	8,5
4	Do	05.03.2015	8,5	8,5	8,5	8,5
5	Fr	06.03.2015	6,0	6,0	6,0	6,0
6	Sa	07.03.2015	6,0	0	0	8,5
7	So	08.03.2015	6,0	0	0	8,5
8	Mo	09.03.2015	8,5	8,5	8,5	8,5

verwendete Formeln
Zelle	Formel	Bereich	N/A
A1:A8	=B1
C1:C8	=VERWEIS(WOCHENTAG(B1;2);{1;5};{8,5;6})
D1: D8	=8,5-(REST(B1;7)=6)*2,5-(REST(B1;7)<=1)*8,5
E1:E8	=(WOCHENTAG(B1;2)<5)*8,5+(WOCHENTAG(B1;2)=5)*6
F1:F8	=WAHL((WOCHENTAG(B1;2)=5)+1;8,5;6)

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 18.24 einschl. 64 Bit

[Jockel]

Hallo Ralf, offenbar wollte der TE nur Mo-Fr...

[WillWissen]

Hi Jörg,

Hallo Ralf, offenbar wollte der TE nur Mo-Fr...

Dann hätte ich auch noch einen (die bisherigen Verweise berücksichtigten nicht das WE):


Tabelle4

	B	C
1	Mo, 02 Mrz 15	8,5
2	Di, 03 Mrz 15	8,5
3	Mi, 04 Mrz 15	8,5
4	Do, 05 Mrz 15	8,5
5	Fr, 06 Mrz 15	6
6	Sa, 07 Mrz 15
7	So, 08 Mrz 15
8	Mo, 09 Mrz 15	8,5
9	Di, 10 Mrz 15	8,5
10	Mi, 11 Mrz 15	8,5
11	Do, 12 Mrz 15	8,5
12	Fr, 13 Mrz 15	6

Formeln der Tabelle

Zelle Formel C1 =SVERWEIS(WOCHENTAG(B1;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C2 =SVERWEIS(WOCHENTAG(B2;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C3 =SVERWEIS(WOCHENTAG(B3;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C4 =SVERWEIS(WOCHENTAG(B4;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C5 =SVERWEIS(WOCHENTAG(B5;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C6 =SVERWEIS(WOCHENTAG(B6;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C7 =SVERWEIS(WOCHENTAG(B7;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C8 =SVERWEIS(WOCHENTAG(B8;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C9 =SVERWEIS(WOCHENTAG(B9;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C10 =SVERWEIS(WOCHENTAG(B10;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C11 =SVERWEIS(WOCHENTAG(B11;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2) C12 =SVERWEIS(WOCHENTAG(B12;2);{1.8,5;2.8,5;3.8,5;4.8,5;5.6;6."";7.""};2)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8