Wenn Dann formel

[DJHeartFeelings]

Anbei eine Tabelle. Die Frage ist, ob ich sich meine Idee mit einer Wenn,Dann Formel umsetzen lässt, was sich, finde ich, aber sehr schwierig gestaltet.

In Spalte "D" gibt es Nummern, welche Per Dropdown ausgewählt werden können. Meistens nicht mehr als 4
Ganz Rechts ist die Legende, welche Nummer was bedeutet und Neben der Legende die Zeit, wieviel wir für jedes Ziel zur Verfügung haben pro Monat
In Spalte "C" Trägt der Mitarbeiter jeweils ein, wieviel Zeit er an diesem Tag für das Ziel gebraucht hat.

Jetzt würde ich gerne, dass ganz Recchts die Zeit, welche noch zur Verfügung steht immer runter gerechnet wird. D.H. wenn er Ziel 1 eingibt, soll die angegebene Zeit in "C" bei Ziel 1 abgezogen werden, wenn der Mitarbeiter aber Ziel 2 angibt in "D" soll die Zeit von "C" aber bei Ziel 2 abgezogen werden.

versteht ihr in etwa was ich meine?

[HKindler]

Hi,

ich kann deine zur Verfügung stehende Zeit nur in einem Prosa-Text sehen. Da ich aber keine Lust habe, deine Tabelle auf etwas vernünftiges (= etwas maschinengerechtes) statt etwas schön buntes umzustellen, hier nur eine Anregung: Schreib dir irgendwo den Ausgangswert für jede der 4 Nummern hin, z.B. in K9:K12. Dann schreibst du in die Nachbarzelle (=Restzeit) =K9-SUMMEWENNS(C:C;D:D;H9). Damit hast du die verbleibende Zeit.

[Stephan]

Hallo,

hab dir mal deinen Wunsch etwas (amateurhaft) bearbeitet. Spalte E kannst du ausblenden oder auch ans Ende kopieren.
Die Werte in den Spalten O müssen erhalten bleiben.

Gruß Stephan

[HKindler]

Hi,

deine Formeln in Spalte O lassen sich "etwas" vereinfachen.

Du hast:
O9: =WENN(F9="";"";WENN(F9=$J$9;SUMMEWENN($F$9:F9;$J$9;$E$9:E9);WENN(F9=$J$10;SUMMEWENN($F$9:F9;$J$10;$E$9:E9);WENN(F9=$J$11;SUMMEWENN($F$9:F9;$J$11;$E$9:E9)))))

Besser:
O9: WENN(F9="";"";SUMMEWENN($F$9:F9;F9;$E$9:E9))
Diese Formel ist immer noch ungeschickt, da sie exponentiell rechnet, also immer alles ab Zeile 9 bis zur aktuellen Zeile durch geht, statt einfach das letzte Ergebnis zu nehmen und damit weiter zu rechnen.
O9: =WENN(F9="";"";E9+XVERWEIS(F9;F$8:F8;E$8:E8;0;0;-1))

Die Formel in Spalte E schreibt dir den Buchstaben "0". Besser wäre es, die Zahl 0 zuschreiben, und gleichzeitig zu prüfen, ob in B und C etwas steht:
E9: =WENN((B9="")+(C9="");0;(C9-B9)*24*60)

Spalte D ginge auch einfacher:
D9: =WENN(F9="";"";XVERWEIS(F9;J$9:J$12;$M$9:$M$12;;0;2)-O9)
oder ohne deine Hilfsspalte O:
D9: =WENN(F9="";"";XVERWEIS(F9;F$8:F8;D$8:D8;XVERWEIS(F9;$J$9:$J$12;$M$9:$M$12;;0;2);0;-1))-E9

Voraussetzung für beide Formeln:

1. du löscht J12:M12 komplett, so das J13:M13 eine Zeile nach oben wandert. Verbundene Zellen haben in Listen nicht, aber auch gar nichts verloren.
   
2. Deine Nummern sind in der Liste aufsteigend sortiert. Wenn nicht, musst du die letzte 2 beim Verweis durch eine 1 ersetzen.
   

Damit sollte deine Liste schon mal besser laufen. Problematisch ist jetzt nur noch: wie willst du deine FLS-Restminuten zurücksetzen? Einmal sind die ja wöchentlich und ein anderes mal monatlich. Und was heißt hier 2*120 Minuten?

Monatlich ein neues Blatt, ist ebenso ungeschickt. Es ist eher die Ausnahme, als die Regel, dass ein Monatswechsel mit einem Wochenwechsel übereinstimmt. Dann wird es mit den wöchentlichen Zeiten schwierig.

Außerdem ist es schlecht Formeln auf Vorrat zu halten. Das ist eigentlich überflüssig. Es gibt ja "Intelligente Tabellen".

[DJHeartFeelings]

Danke für die Infos, ich versuche damit mal zu arbeiten.
Das, was ich euch aktuell geschickt habe, so sah meine Tabelle bisher aus und unten habe ich für jeden Monat ein Tabellenblatt. Natürlich wird dann alles in Minuten abgerechnet und nicht in 2x120 oder Stunden.
Das Ganze ist auch nur für die Mitarbeiter als Veranschaulichung, was sie noch dokumentieren können und wird jeden Monat wieder auf 0 gesetzt, also den Anfangswert, es soll also nichts übernommen werden.
Wenn, Dann Formeln habe ich auch super in unserer Haushaltskasse umsetzen können, aber da ging es nicht um verschiedene Werte.
Ich versuch mal mein Glück und danke nochmal für eure Mühe und Hilfen